code.vuplus.com Git - vuplus_openembedded/blob - packages/gcc/gcc-cross_3.3.3.bb

   1 SECTION = "devel"
   2 require gcc_${PV}.bb
   3 inherit cross
   4
   5 FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/gcc-${PV}"
   6
   7 DEPENDS = "virtual/${TARGET_PREFIX}binutils virtual/${TARGET_PREFIX}libc-for-gcc"
   8 PROVIDES = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++"
   9
  10 # Files for these are defined in the main gcc.oe
  11 PACKAGES = "libgcc libstdc++ libg2c"
  12 INHIBIT_PACKAGE_STRIP = "1"
  13
  14 EXTRA_OECONF_PATHS = "--with-local-prefix=${CROSS_DIR}/${TARGET_SYS} \
  15                 --with-gxx-include-dir=${CROSS_DIR}/${TARGET_SYS}/include/c++"
  16
  17 export CPPFLAGS = ""
  18 export CXXFLAGS = ""
  19 export CFLAGS = ""
  20 export LDFLAGS = ""
  21
  22 do_configure () {
  23         export CC="${BUILD_CC}"
  24         export AR="${TARGET_SYS}-ar"
  25         export RANLIB="${TARGET_SYS}-ranlib"
  26         export LD="${TARGET_SYS}-ld"
  27         export NM="${TARGET_SYS}-nm"
  28         rm -f ${CROSS_DIR}/lib/gcc-lib/${TARGET_SYS}/${PV}/libgcc_eh.a
  29         (cd ${S} && gnu-configize) || die "failure running gnu-configize"
  30         oe_runconf
  31 }
  32
  33 do_compile_prepend () {
  34         export CC="${BUILD_CC}"
  35         export AR_FOR_TARGET="${TARGET_SYS}-ar"
  36         export RANLIB_FOR_TARGET="${TARGET_SYS}-ranlib"
  37         export LD_FOR_TARGET="${TARGET_SYS}-ld"
  38         export NM_FOR_TARGET="${TARGET_SYS}-nm"
  39         export CC_FOR_TARGET="${CCACHE} ${TARGET_SYS}-gcc"
  40 }
  41
  42 do_stage_append () {
  43         for d in info man share/doc share/locale ; do
  44                 rm -rf ${CROSS_DIR}/$d
  45         done
  46
  47         # Fix a few include links so cross builds are happier
  48         if [ ! -e ${STAGING_INCDIR}/c++ ]; then
  49                 mkdir -p ${STAGING_INCDIR}
  50                 rm -f ${STAGING_INCDIR}/c++
  51                 ln -sf ${CROSS_DIR}/${TARGET_SYS}/include/c++ \
  52                         ${STAGING_INCDIR}/
  53         fi
  54
  55         # We use libiberty from binutils
  56         rm -f ${CROSS_DIR}/lib/libiberty.a
  57
  58         # We probably don't need these
  59         rmdir ${CROSS_DIR}/include || :
  60
  61         # We don't really need to keep this around
  62         rm -rf ${CROSS_DIR}/share
  63 }
  64
  65 python do_package() {
  66         if bb.data.getVar('DEBIAN_NAMES', d, 1):
  67                 bb.data.setVar('PKG_libgcc', 'libgcc1', d)
  68         bb.build.exec_func('package_do_package', d)
  69 }
  70
  71 do_install () {
  72         oe_runmake 'DESTDIR=${D}' install
  73
  74         # Move libgcc_s into /lib
  75         mkdir -p ${D}${base_libdir}
  76         if [ "${BUILD_SYS}" == "${TARGET_SYS}" ]; then
  77                 # native builds drop one pathname component
  78                 mv -f ${D}${prefix}/lib/libgcc_s.so.* ${D}${base_libdir}
  79         else
  80                 mv -f ${D}${prefix}/*/lib/libgcc_s.so.* ${D}${base_libdir}
  81         fi
  82
  83         # Move libstdc++ and libg2c into libdir (resetting our prefix to /usr
  84         TGT_LIBDIR=`echo ${libdir} | sed -e 's,${CROSS_DIR},/usr,'`
  85         mkdir -p ${D}${TGT_LIBDIR}
  86         mv -f ${D}${prefix}/*/lib/libstdc++.so.* ${D}${TGT_LIBDIR}
  87         mv -f ${D}${prefix}/*/lib/libg2c.so.* ${D}${TGT_LIBDIR}
  88
  89         # Manually run the target stripper since we won't get it run by
  90         # the packaging.
  91         ${TARGET_PREFIX}strip ${D}${TGT_LIBDIR}/libstdc++.so.*
  92         ${TARGET_PREFIX}strip ${D}${TGT_LIBDIR}/libg2c.so.*
  93         ${TARGET_PREFIX}strip ${D}${base_libdir}/libgcc_s.so.*
  94 }