code.vuplus.com Git - vuplus_openembedded/blob - packages/enigma2/enigma2.bb

   1 DESCRIPTION = "Enigma2 is an experimental, but useful framebuffer-based frontend for DVB functions"
   2 MAINTAINER = "Felix Domke <tmbinc@elitedvb.net>"
   3 DEPENDS = "jpeg libungif libmad libpng libsigc++-1.2 gettext-native \
   4         dreambox-dvbincludes freetype libdvbsi++ python swig-native  \
   5         gstreamer gst-plugins-good gst-plugins-bad gst-plugins-ugly \
   6         libfribidi libxmlccwrap libdreamdvd tuxbox-tuxtxt-32bpp"
   7 RDEPENDS = "python-codecs python-core python-lang python-re python-threading \
   8         python-xml python-fcntl gst-plugin-decodebin python-stringold \
   9         gst-plugin-id3demux gst-plugin-mad gst-plugin-ogg gst-plugin-playbin \
  10         gst-plugin-typefindfunctions gst-plugin-ivorbis gst-plugin-audioconvert \
  11         gst-plugin-wavparse python-netclient gst-plugin-mpegstream gst-plugin-selector \
  12         gst-plugin-flac"
  13
  14 RDEPENDS_append_dm7020 = " gst-plugin-ossaudio"
  15 RDEPENDS_append_dm7025 = " gst-plugin-alsa alsa-conf"
  16 RDEPENDS_append_dm8000 = " gst-plugin-alsa alsa-conf gst-plugin-avi gst-plugin-matroska \
  17         gst-plugin-subparse eglibc-gconv-iso8859-15 gst-plugin-cdxaparse"
  18 RDEPENDS_append_dm800 = " gst-plugin-alsa alsa-conf"
  19
  20 DESCRIPTION_append_enigma2-plugin-extensions-cutlisteditor = "enables you to cut your movies."
  21 DESCRIPTION_append_enigma2-plugin-extensions-graphmultiepg = "shows a graphical timeline EPG."
  22 DESCRIPTION_append_enigma2-plugin-extensions-pictureplayer = "displays photos on the TV."
  23 DESCRIPTION_append_enigma2-plugin-systemplugins-configurationbackup = "backs up your configuration and restores them optionally."
  24 DESCRIPTION_append_enigma2-plugin-systemplugins-frontprocessorupdate = "keeps your frontprocessor up to date."
  25 DESCRIPTION_append_enigma2-plugin-systemplugins-positionersetup = "helps you installing a motorized dish."
  26 DESCRIPTION_append_enigma2-plugin-systemplugins-satelliteequipmentcontrol = "allows you to fine-tune DiSEqC-settings."
  27 DESCRIPTION_append_enigma2-plugin-systemplugins-satfinder = "helps you to align your dish."
  28 DESCRIPTION_append_enigma2-plugin-systemplugins-skinselector = "shows a menu with selectable skins."
  29 DESCRIPTION_append_enigma2-plugin-systemplugins-videomode = "selects advanced video modes"
  30 RDEPENDS_enigma2-plugin-extensions-dvdplayer = "libdreamdvd0"
  31
  32 export LD="${CXX}"
  33
  34 PN = "enigma2"
  35 PR = "r0"
  36 SRCDATE = "20081022"
  37
  38 # if you want experimental, use:
  39 REL_MAJOR="2"
  40 REL_MINOR="5"
  41 TAG = ""
  42
  43 PV = "${REL_MAJOR}.${REL_MINOR}cvs${SRCDATE}"
  44
  45 SRC_URI = "cvs://anonymous@dreamboxupdate.com/cvs;module=enigma2;method=pserver${TAG};date=${SRCDATE} \
  46         file://tuxtxt_caching.patch;patch=1 \
  47         file://enigma2.sh"
  48
  49 SRC_URI_append_dm7025 = " file://enigma2-disable-iframesearch.patch;patch=1;pnum=1"
  50
  51 S = "${WORKDIR}/enigma2"
  52
  53 FILES_${PN} += "${datadir}/fonts"
  54
  55 inherit autotools pkgconfig
  56
  57 bindir = "/usr/bin"
  58 sbindir = "/usr/sbin"
  59
  60 EXTRA_OECONF = "--enable-maintainer-mode --with-target=native --with-libsdl=no"
  61
  62 do_install_append() {
  63         install -m 0755 ${WORKDIR}/enigma2.sh ${D}/usr/bin/
  64 }
  65
  66 python populate_packages_prepend () {
  67         enigma2_plugindir = bb.data.expand('${libdir}/enigma2/python/Plugins', d)
  68
  69         do_split_packages(d, enigma2_plugindir, '(.*?/.*?)/.*', 'enigma2-plugin-%s', '%s ', recursive=True, match_path=True, prepend=True)
  70 }
  71
  72 do_stage_append() {
  73         install -d ${STAGING_INCDIR}/enigma2
  74         install -m 0644 ${WORKDIR}/enigma2/include/*.h ${STAGING_INCDIR}/enigma2
  75         for dir in actions base components driver dvb dvb/lowlevel dvb_ci gdi gui mmi nav python service; do
  76                 install -d ${STAGING_INCDIR}/enigma2/lib/$dir;
  77                 install -m 0644 ${WORKDIR}/enigma2/lib/$dir/*.h ${STAGING_INCDIR}/enigma2/lib/$dir;
  78         done
  79 }