code.vuplus.com Git - vuplus_openembedded/blob - packages/e2fsprogs/e2fsprogs_1.38.bb

   1 require e2fsprogs.inc
   2
   3 PR = "r19"
   4
   5 SRC_URI += "file://no-hardlinks.patch;patch=1 \
   6             file://mkinstalldirs.patch;patch=1 \
   7            "
   8
   9 TARGET_CC_ARCH += "${LDFLAGS}"
  10
  11 do_compile_prepend () {
  12         find ./ -print|xargs chmod u=rwX
  13         ( cd util; ${BUILD_CC} subst.c -o subst )
  14 }
  15
  16 ext2fsheaders = "ext2_ext_attr.h bitops.h ext2_err.h \
  17                  ext2_types.h ext2_fs.h ext2_io.h \
  18                  ext2fs.h"
  19 e2pheaders = "e2p.h"
  20
  21 do_stage () {
  22         oe_libinstall -a -C lib libe2p ${STAGING_LIBDIR}/
  23         oe_libinstall -a -C lib libext2fs ${STAGING_LIBDIR}/
  24         install -d ${STAGING_INCDIR}/e2p
  25         for h in ${e2pheaders}; do
  26                 install -m 0644 lib/e2p/$h ${STAGING_INCDIR}/e2p/ || die "failed to install $h"
  27         done
  28         install -d ${STAGING_INCDIR}/ext2fs
  29         for h in ${ext2fsheaders}; do
  30                 install -m 0644 lib/ext2fs/$h ${STAGING_INCDIR}/ext2fs/ || die "failed to install $h"
  31         done
  32         autotools_stage_all
  33 }
  34
  35 # blkid used to be part of e2fsprogs but is useful outside, add it
  36 # as an RDEPENDS so that anything relying on it being in e2fsprogs
  37 # still works
  38 RDEPENDS_e2fsprogs = "e2fsprogs-blkid e2fsprogs-uuidgen e2fsprogs-badblocks"
  39
  40 PACKAGES =+ "e2fsprogs-blkid e2fsprogs-uuidgen e2fsprogs-e2fsck e2fsprogs-mke2fs e2fsprogs-fsck e2fsprogs-tune2fs e2fsprogs-badblocks"
  41 FILES_e2fsprogs-blkid = "${base_sbindir}/blkid.${PN}"
  42 FILES_e2fsprogs-uuidgen = "${bindir}/uuidgen"
  43 FILES_e2fsprogs-fsck = "${base_sbindir}/fsck.${PN}"
  44 FILES_e2fsprogs-e2fsck = "${base_sbindir}/e2fsck.${PN} ${base_sbindir}/fsck.ext*.${PN}"
  45 FILES_e2fsprogs-mke2fs = "${base_sbindir}/mke2fs.${PN} ${base_sbindir}/mkfs.ext*.${PN}"
  46 FILES_e2fsprogs-tune2fs = "${base_sbindir}/tune2fs ${base_sbindir}/e2label ${base_sbindir}/findfs"
  47 FILES_e2fsprogs-badblocks = "${base_sbindir}/badblocks"
  48
  49 do_install_append () {
  50         mv ${D}${base_sbindir}/fsck ${D}${base_sbindir}/fsck.${PN}
  51         mv ${D}${base_sbindir}/blkid ${D}${base_sbindir}/blkid.${PN}
  52         mv ${D}${base_sbindir}/e2fsck ${D}${base_sbindir}/e2fsck.${PN}
  53         mv ${D}${base_sbindir}/fsck.ext2 ${D}${base_sbindir}/fsck.ext2.${PN}
  54         mv ${D}${base_sbindir}/fsck.ext3 ${D}${base_sbindir}/fsck.ext3.${PN}
  55         mv ${D}${base_sbindir}/mke2fs ${D}${base_sbindir}/mke2fs.${PN}
  56         mv ${D}${base_sbindir}/mkfs.ext2 ${D}${base_sbindir}/mkfs.ext2.${PN}
  57         mv ${D}${base_sbindir}/mkfs.ext3 ${D}${base_sbindir}/mkfs.ext3.${PN}
  58 }
  59
  60 pkg_postinst_e2fsprogs-fsck () {
  61         update-alternatives --install ${base_sbindir}/fsck fsck fsck.${PN} 100
  62 }
  63
  64 pkg_prerm_e2fsprogs-fsck () {
  65         update-alternatives --remove fsck fsck.${PN}
  66 }
  67
  68 pkg_postinst_e2fsprogs-blkid () {
  69     update-alternatives --install ${base_sbindir}/blkid blkid blkid.${PN} 100
  70 }
  71
  72 pkg_prerm_e2fsprogs-blkid () {
  73     update-alternatives --remove blkid blkid.${PN}
  74 }
  75
  76 pkg_postinst_e2fsprogs-e2fsck () {
  77         update-alternatives --install ${base_sbindir}/e2fsck e2fsck e2fsck.${PN} 100
  78         update-alternatives --install ${base_sbindir}/fsck.ext2 fsck.ext2 fsck.ext2.${PN} 100
  79         update-alternatives --install ${base_sbindir}/fsck.ext3 fsck.ext3 fsck.ext3.${PN} 100
  80 }
  81
  82 pkg_prerm_e2fsprogs-e2fsck () {
  83         update-alternatives --remove e2fsck e2fsck.${PN}
  84         update-alternatives --remove fsck.ext2 fsck.ext2.${PN}
  85         update-alternatives --remove fsck.ext3 fsck.ext3.${PN}
  86 }
  87
  88 pkg_postinst_e2fsprogs-mke2fs () {
  89         update-alternatives --install ${base_sbindir}/mke2fs mke2fs mke2fs.${PN} 100
  90         update-alternatives --install ${base_sbindir}/mkfs.ext2 mkfs.ext2 mkfs.ext2.${PN} 100
  91         update-alternatives --install ${base_sbindir}/mkfs.ext3 mkfs.ext3 mkfs.ext3.${PN} 100
  92 }
  93
  94 pkg_prerm_e2fsprogs-mke2fs () {
  95         update-alternatives --remove mke2fs mke2fs.${PN}
  96         update-alternatives --remove mkfs.ext2 mkfs.ext2.${PN}
  97         update-alternatives --remove mkfs.ext3 mkfs.ext3.${PN}
  98 }
  99