code.vuplus.com Git - vuplus_openembedded/blob - packages/dsplink/ti-dmai_1.20.bb

   1 DESCRIPTION = "Davinci (and OMAP) Multimedia Application Interface"
   2 DEPENDS = "virtual/kernel ti-codec-engine ti-codec-combos"
   3 LICENCE = "unknown"
   4
   5 require ti-paths.inc
   6
   7 # https://www-a.ti.com/downloads/sds_support/applications_packages/dmai/dmai_1_20_00_06/dmai_setuplinux_1_20_00_06.bin
   8 # Install the above link and put the dmai_1_20_00_06.tar.gz file in the same directory as this recipe
   9 SRC_URI = "file://dmai_1_20_00_06.tar.gz \
  10            file://dmai-update-cpu-name.patch;patch=1 \
  11            file://dmai-update-fb-display.patch;patch=1 \
  12            file://dmai-update-v4l2-display.patch;patch=1 \
  13            file://dmai-do-not-panic-on-mixer-failure.patch;patch=1 \
  14            file://dmai-support-32bit-align.patch;patch=1 \
  15            file://dmai-built-with-angstrom.patch;patch=1 \
  16            file://loadmodules-ti-dmai-apps.sh \
  17            file://unloadmodules-ti-dmai-apps.sh \
  18    "
  19
  20 S = "${WORKDIR}/dmai_1_20_00_06"
  21 # Yes, the xdc stuff still breaks with a '.' in PWD
  22 PV = "120"
  23 PR = "r12"
  24
  25 TARGET = "all"
  26 TARGET_neuros-osd2 = " dm6446_al dm6446_db"
  27 TARGET_beagleboard = " o3530_al"
  28 TARGET_omap3evm = " o3530_al"
  29
  30 export CE_INSTALL_DIR="${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/ti-codec-engine"
  31 export FC_INSTALL_DIR="${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/ti-codec-engine/cetools"
  32 export CODEC_INSTALL_DIR="${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/ti-codec-combos"
  33
  34 do_compile_prepend_omap3evm() {
  35
  36 #temp removal of sources that fail to build on evm3530
  37         if [ -e packages/ti/sdo/dmai/linux/omap3530/Resize.c ]; then
  38                 rm packages/ti/sdo/dmai/linux/omap3530/Resize.c
  39         fi
  40
  41         if [ -e packages/ti/sdo/dmai/linux/omap3530/Framecopy_accel.c ]; then
  42                 rm packages/ti/sdo/dmai/linux/omap3530/Framecopy_accel.c
  43         fi
  44 }
  45
  46 do_compile() {
  47         cd packages/ti/sdo/dmai
  48         oe_runmake clean
  49         oe_runmake ${TARGET} C_FLAGS="-O2 -I${STAGING_INCDIR}"
  50         cd apps
  51         oe_runmake clean
  52         oe_runmake ${TARGET}
  53 }
  54
  55 do_install () {
  56         install -d ${D}/${datadir}/ti-dmai/apps
  57
  58         export EXEC_DIR="${D}/${datadir}/ti-dmai/apps"
  59         oe_runmake install
  60
  61     #test app module un/load scripts
  62         install ${WORKDIR}/loadmodules-ti-dmai-apps.sh ${D}/${datadir}/ti-dmai
  63         install ${WORKDIR}/unloadmodules-ti-dmai-apps.sh ${D}/${datadir}/ti-dmai
  64 }
  65
  66 do_stage () {
  67         install -d ${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/ti-dmai
  68         cp -pPrf ${S}/* ${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/ti-dmai
  69 }
  70
  71 PACKAGES =+ "ti-dmai-apps"
  72
  73 FILES_ti-dmai-apps = "${datadir}/ti-dmai/*"
  74
  75 pkg_postinst_ti-dmai-apps () {
  76         ln -sf /usr/share/ti-codec-combos/* $D/usr/share/ti-dmai/apps
  77 }
  78
  79 INHIBIT_PACKAGE_STRIP = "1"
  80
  81 PACKAGE_ARCH = "${MACHINE_ARCH}"
  82
  83 #add run-time dependencies - note for kernel module we can only use RRECOMMENDS, since modules might be built into the kernel
  84 # and for now we make codecs RRECOMMENDS as well, since not everyone will have them
  85 #RDEPENDS_ti-dmai-apps += "ti-codec-combos"
  86 RRECOMMENDS_ti-dmai-apps += "ti-cmem-module ti-lpm-module ti-dsplink-module ti-codec-combos"
  87