code.vuplus.com Git - vuplus_openembedded/blob - packages/dbus-java/dbus-java_2.4.bb

   1 DESCRIPTION = "A pure Java D-Bus Implementation"
   2 DESCRIPTION_dbus-java-viewer = "${DESCRIPTION} (DBusViewer Binary)"
   3 DESCRIPTION_dbus-java-bin = "${DESCRIPTION} (Binaries)"
   4 AUTHOR = "Matthew Johnson <dbus@matthew.ath.cx>"
   5 HOMEPAGE = "http://dbus.freedesktop.org/doc/dbus-java"
   6 SECTION = "libs"
   7 LICENSE = "GPLv2 AFL"
   8 DEPENDS = "libmatthew docbook-utils-native docbook-sgml-dtd-4.1-native fastjar-native"
   9 RDEPENDS_dbus-java-viewer = "java2-runtime libunixsocket-java ${JPN}"
  10 RDEPENDS_dbus-java-bin = "java2-runtime libunixsocket-java ${JPN}"
  11 RSUGGESTS_libdbus-java = "libunixsocket-java dbus"
  12 PR = "r1"
  13
  14 SRC_URI = "http://dbus.freedesktop.org/releases/dbus-java/dbus-java-${PV}.tar.gz"
  15
  16 S = "${WORKDIR}/dbus-java-${PV}"
  17
  18 inherit java-library
  19
  20 # jamvm-native unfortunately contains non-generificed java/lang/reflect classes
  21 # which are accessed in this package. Work around this by setting the bootclasspath
  22 # explicitly.
  23 JCFLAGS = "-bootclasspath ${STAGING_DATADIR}/classpath/glibj.zip"
  24
  25 do_compile () {
  26   # run target .binclasses first to fix a brokenness in the Makefile
  27     oe_runmake \
  28         JCFLAGS="-source 1.5 ${JCFLAGS}" \
  29         JAVAC="javac" \
  30         JARPREFIX="${STAGING_DATADIR_JAVA}" \
  31         JAVAUNIXJARDIR="${STAGING_DATADIR_JAVA}" \
  32         CLASSPATH="${S}/classes" \
  33         JAR="fastjar" \
  34         .binclasses
  35     oe_runmake \
  36         JCFLAGS="-source 1.5 ${JCFLAGS}" \
  37         JAVAC="javac" \
  38         JARPREFIX="${STAGING_DATADIR_JAVA}" \
  39         JAVAUNIXJARDIR="${STAGING_DATADIR_JAVA}" \
  40         CLASSPATH="${S}/classes" \
  41         JAR="fastjar" \
  42         all
  43   # Generated shell scripts will have staging paths inside them.
  44     rm bin/*
  45   # Generate them again with target paths.
  46     oe_runmake \
  47         JAVAC="oefatal \"No Java compilation expected here.\"" \
  48         JAR="oefatal \"No jar invocation expected here.\"" \
  49         JARPREFIX=${datadir_java} \
  50         JAVAUNIXPATH=${datadir_java} \
  51         all
  52   # Trigger generation of all documentation files to prevent this
  53   # being happen at the target 'install-man' in do_install.
  54     oe_runmake \
  55         JAVAC="oefatal \"No Java compilation expected here.\"" \
  56         JAR="oefatal \"No jar invocation expected here.\"" \
  57         JARPREFIX=${datadir_java} \
  58         JAVAUNIXPATH=${datadir_java} \
  59         CreateInterface.1 ListDBus.1 DBusDaemon.1 DBusViewer.1 changelog AUTHORS COPYING README INSTALL DBusCall.1
  60 }
  61
  62 do_install () {
  63     oe_jarinstall ${JPN}-${PV}.jar ${JPN}.jar
  64     oe_jarinstall dbus-java-viewer-${PV}.jar dbus-java-viewer.jar
  65     oe_jarinstall dbus-java-bin-${PV}.jar dbus-java-bin.jar
  66     install -d ${D}${bindir}
  67     install bin/DBusViewer ${D}${bindir}
  68     install bin/DBusCall ${D}${bindir}
  69     install bin/CreateInterface ${D}${bindir}
  70     install bin/ListDBus ${D}${bindir}
  71     install bin/DBusDaemon ${D}${bindir}
  72     oe_runmake \
  73         JAVAC="oefatal \"No Java compilation expected here.\"" \
  74         JAR="oefatal \"No jar invocation expected here.\"" \
  75         MANPREFIX=${D}${mandir} \
  76         DOCPREFIX=${D}${docdir}/${JPN} \
  77         install-man
  78 }
  79
  80 do_stage () {
  81     oe_jarinstall -s ${JPN}-${PV}.jar ${JPN}.jar
  82 }
  83
  84 PACKAGE_ARCH = "all"
  85 # ${JPN} must be last otherwise it would pick up dbus-viewer*.jar
  86 # and dbus-bin*.jar
  87 PACKAGES = "dbus-java-viewer dbus-java-viewer-doc dbus-java-bin dbus-java-bin-doc ${JPN}"
  88
  89 FILES_dbus-java-viewer = "${datadir}/java/dbus-java-viewer*.jar ${bindir}/DBusViewer"
  90 FILES_dbus-java-viewer-doc = "${mandir}/DBusViewer*"
  91 FILES_dbus-java-bin = "${datadir}/java/dbus-java-bin*.jar ${bindir}"
  92 FILES_dbus-java-bin-doc = "${mandir} ${docdir}/${JPN}"