code.vuplus.com Git - vuplus_openembedded/blob - packages/dbus/dbus.inc

   1 DESCRIPTION = "A message bus system for inter-process communication"
   2 HOMEPAGE = "http://dbus.freedesktop.org"
   3 SECTION = "base"
   4 LICENSE = "GPL"
   5 DEPENDS = "expat glib-2.0 virtual/libintl libsm libice virtual/libx11"
   6
   7 SRC_URI = "\
   8   http://dbus.freedesktop.org/releases/dbus/dbus-${PV}.tar.gz \
   9   file://cross.patch;patch=1 \
  10   file://tmpdir.patch;patch=1 \
  11   file://fix-install-daemon.patch;patch=1 \
  12   file://0001-Make-the-default-DBus-reply-timeout-configurable.patch;patch=1 \
  13   file://dbus-1.init \
  14 "
  15
  16 S = "${WORKDIR}/dbus-${PV}"
  17
  18 inherit autotools pkgconfig update-rc.d gettext
  19
  20 EXTRA_OECONF = "\
  21   --disable-qt \
  22   --disable-qt3 \
  23   --disable-gtk \
  24   --disable-tests \
  25   --disable-checks \
  26   --disable-xml-docs \
  27   --disable-doxygen-docs \
  28   --with-xml=expat \
  29   --with-x \
  30   --with-dbus-default-reply-timeout=60000 \
  31 "
  32
  33 do_install_append() {
  34         install -d ${D}${sysconfdir}/init.d
  35         install -m 0755 ${WORKDIR}/dbus-1.init ${D}${sysconfdir}/init.d/dbus-1
  36         # the stock install seems to install the libtool wrapper script, so we have to copy this manually :M:
  37         if [ -e bus/.libs/dbus-daemon-launch-helper ]; then
  38                 install -m 0755 bus/.libs/dbus-daemon-launch-helper ${D}${libexecdir}/
  39         fi
  40 }
  41 do_stage() {
  42         oe_libinstall -so -C dbus libdbus-1 ${STAGING_LIBDIR}
  43         autotools_stage_includes
  44         mkdir -p ${STAGING_LIBDIR}/dbus-1.0/include/dbus/
  45         install -m 0644 dbus/dbus-arch-deps.h ${STAGING_LIBDIR}/dbus-1.0/include/dbus/
  46 }
  47
  48 RDEPENDS_${PN}-x11 = "${PN}"
  49 RRECOMMENDS_${PN}-lib = "${PN}"
  50 RCONFLICTS_${PN} = "dbus-1"
  51 RREPLACES_${PN} = "dbus-1"
  52 RPROVIDES_${PN} = "dbus-1"
  53
  54 PACKAGES =+ "${PN}-lib ${PN}-x11"
  55
  56 FILES_${PN} = "\
  57 ${bindir}/dbus-daemon* \
  58 ${bindir}/dbus-uuidgen \
  59 ${bindir}/dbus-cleanup-sockets \
  60 ${bindir}/dbus-send \
  61 ${bindir}/dbus-monitor \
  62 ${libexecdir}/dbus* \
  63 ${sysconfdir} \
  64 ${datadir}/dbus-1/services \
  65 ${datadir}/dbus-1/system-services \
  66 "
  67 FILES_${PN}-lib = "${libdir}/lib*.so.*"
  68 FILES_${PN}-x11 = "\
  69 ${bindir}/dbus-launch \
  70 "
  71 FILES_${PN}-dev += "${libdir}/dbus-1.0/include ${bindir}/dbus-glib-tool ${libdir}/"
  72
  73 pkg_postinst_${PN}() {
  74 #!/bin/sh
  75 # can't do adduser stuff offline
  76 if [ "x$D" != "x" ]; then
  77   exit 1
  78 fi
  79 MESSAGEUSER=messagebus
  80 MESSAGEHOME=/var/run/dbus
  81 mkdir -p $MESSAGEHOME || true
  82 chgrp "$MESSAGEUSER" "$MESSAGEHOME" 2>/dev/null || addgroup "$MESSAGEUSER"
  83 chown "$MESSAGEUSER"."$MESSAGEUSER" "$MESSAGEHOME" 2>/dev/null || adduser --system --home "$MESSAGEHOME" --no-create-home --disabled-password --ingroup "$MESSAGEUSER" "$MESSAGEUSER"
  84 grep -q netdev: /etc/group || addgroup netdev
  85 chmod u+s /usr/libexec/dbus-daemon-launch-helper
  86 }
  87
  88 CONFFILES_${PN} = "${sysconfdir}/dbus-1/system.conf ${sysconfdir}/dbus-1/session.conf"
  89
  90 INITSCRIPT_NAME = "dbus-1"
  91 INITSCRIPT_PARAMS = "defaults"