code.vuplus.com Git - vuplus_openembedded/blob - packages/connman/connman.inc

   1 DESCRIPTION = "The Moblin Connection Manager"
   2 HOMEPAGE = "http://www.moblin.org/projects/projects_connman.php"
   3 SECTION = "libs/network"
   4 LICENSE = "GPL"
   5 # we need to define the depends here, the dynamic stuff is too late
   6 DEPENDS  = "wpa-supplicant dbus glib-2.0 ppp busybox dhclient resolvconf bluez4"
   7
   8 EXTRA_OECONF += "\
   9     ac_cv_path_WPASUPPLICANT=/usr/sbin/wpa_supplicant \
  10     ac_cv_path_DHCLIENT=/sbin/dhclient \
  11     ac_cv_path_UDHCPC=/sbin/udhcpc \
  12     ac_cv_path_RESOLVCONF=/sbin/resolvconf \
  13     ac_cv_path_PPPD=/usr/sbin/pppd \
  14 "
  15
  16 INITSCRIPT_NAME = "connman"
  17 INITSCRIPT_PARAMS = "defaults 22"
  18
  19 PARALLEL_MAKE = ""
  20
  21 inherit autotools pkgconfig update-rc.d
  22
  23 do_configure_append() {
  24         ln -sf . include/connman
  25 }
  26
  27 do_install_append() {
  28     install -m 0755 ${WORKDIR}/connman ${D}${sysconfdir}/init.d/connman
  29 }
  30
  31 do_stage() {
  32         autotools_stage_all
  33 }
  34
  35 python populate_packages_prepend() {
  36         depmap = dict( pppd="ppp", udhcp="busybox connman-scripts", dhclient="dhclient", wifi="wpa-supplicant", resolvconf="resolvconf", bluetooth="bluez4" )
  37         packages = []
  38         hook = lambda file,pkg,b,c,d:packages.append((file,pkg))
  39         plugin_dir = bb.data.expand('${libdir}/connman/plugins/', d)
  40         plugin_name = bb.data.expand('${PN}-plugin-%s', d)
  41         do_split_packages(d, plugin_dir, '^(.*).so$', plugin_name, '${PN} plugin for %s', extra_depends='', hook=hook )
  42         for (file, package) in packages:
  43                 plugintype = package.split( '-' )[-1]
  44                 if plugintype in depmap:
  45                         rdepends = bb.data.getVar( "RDEPENDS_%s" % package, d )
  46                         bb.note( "Adding rdependency on %s to package %s" % ( depmap[plugintype], package ) )
  47                         bb.data.setVar("RDEPENDS_%s" % package, depmap[plugintype], d)
  48 }
  49
  50 PACKAGES_DYNAMIC = "${PN}-plugin-*"
  51
  52 PACKAGES += "${PN}-scripts"
  53
  54 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*.so.* \
  55             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
  56             ${base_bindir}/* ${base_sbindir}/* ${base_libdir}/*.so* ${datadir}/${PN} \
  57             ${datadir}/pixmaps ${datadir}/applications \
  58             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
  59             ${libdir}/bonobo/servers \
  60             ${datadir}/dbus-1/system-services/*"
  61
  62 FILES_${PN}-scripts += "${libdir}/connman/scripts"
  63 FILES_${PN}-dbg += "${libdir}/connman/*/.debug"
  64 FILES_${PN}-dev += "${libdir}/connman/*/*.la"
  65