code.vuplus.com Git - vuplus_openembedded/blob - packages/classpath/classpath.inc

   1 DESCRIPTION = "GNU Classpath standard Java libraries"
   2 HOMEPAGE = "http://www.gnu.org/software/classpath/"
   3 SECTION = "libs"
   4 PRIORITY = "optional"
   5 LICENSE = "Classpath"
   6 PBN = "classpath"
   7
   8 DEPENDS = "virtual/javac-native fastjar-native zip-native"
   9 RPROVIDES = ""
  10
  11 RDEPENDS_${PN} = "${PBN}-common (>= ${PV})"
  12 RDEPENDS_${PN}-examples = "java2-runtime ${PN}-awt"
  13 RDEPENDS_${PN}-tools = "java2-runtime"
  14
  15 RPROVIDES_${PN} = "${PBN}"
  16 RPROVIDES_${PN}-common = "${PBN}-common"
  17 RPROVIDES_${PN}-gtk = "${PBN}-awt"
  18
  19 SRC_URI = "${GNU_MIRROR}/classpath/classpath-${PV}.tar.gz"
  20
  21
  22 S = "${WORKDIR}/${PBN}-${PV}"
  23
  24 export JAVA = "java"
  25
  26 EXTRA_OECONF = "\
  27   --with-glibj \
  28   --with-ecj=javac \
  29   --with-fastjar=fastjar \
  30   --includedir=${includedir}/classpath \
  31   --with-vm=java \
  32   "
  33
  34 inherit autotools
  35
  36 do_configure_prepend () {
  37
  38         cp ${STAGING_DATADIR_NATIVE}/gettext/config.rpath ${S}
  39 }
  40
  41
  42 do_stage() {
  43         install -d ${STAGING_INCDIR}/classpath
  44         install -m 0644 include/jni* ${STAGING_INCDIR}/classpath
  45         install -m 0644 include/jni_md.h ${STAGING_INCDIR}/classpath/
  46
  47         install -d ${STAGING_DATADIR}/classpath
  48         install -m 0644 lib/glibj.zip ${STAGING_DATADIR}/classpath
  49 }
  50
  51 do_install() {
  52         autotools_do_install
  53         mv ${D}${libdir}/security ${D}${libdir}/${PBN}
  54 }
  55
  56 # Defines the packages that this classpath recipe creates.
  57 # This allows the classpath-minimal variants to override this
  58 # again.
  59 CPPACKAGES = "${PBN}-common ${PN}-examples \
  60              ${PN}-tools ${PN}-tools-doc \
  61              ${PN}-gtk ${PN}-gconf"
  62
  63 PACKAGES =+ "${CPPACKAGES}"
  64
  65 FILES_${PN}-dev += "${libdir}/${PBN}/*.la ${incdir}/${PBN}"
  66
  67 FILES_${PBN}-common = "${datadir}/${PBN}/glibj.zip ${libdir}/logging.properties ${libdir}/${PBN}/security"
  68 FILES_${PN}-examples = "${datadir}/${PBN}/examples"
  69
  70 FILES_${PN}-tools = "${datadir}/${PBN}/tools.zip ${bindir}"
  71 FILES_${PN}-tools-doc = "${mandir}"
  72
  73 FILES_${PN}-dbg += "${libdir}/${PBN}/.debug"
  74 FILES_${PN}-doc = "${infodir}"
  75
  76 # gcjwebplugin - not built yet
  77 #FILES_${PN}-gcjwebplugin = "${libdir}/${PBN}/libgcjwebplugin.so"
  78 FILES_${PN}-gtk = "${libdir}/${PBN}/libgtkpeer.so ${libdir}/${PBN}/libjawt.so"
  79 FILES_${PN}-gconf = "${libdir}/${PBN}/libgconfpeer.so"
  80 FILES_${PN} = "${libdir}/${PBN}/lib*so*"
  81