code.vuplus.com Git - vuplus_openembedded/blob - packages/binutils/binutils_2.15.94.0.1.bb

   1 DESCRIPTION = "A GNU collection of binary utilities"
   2 HOMEPAGE = "http://www.gnu.org/software/binutils/"
   3 SECTION = "devel"
   4 LICENSE = "GPL"
   5 PR = "r3"
   6
   7 inherit autotools gettext
   8
   9 PACKAGES = "${PN} ${PN}-dev ${PN}-doc ${PN}-symlinks"
  10
  11 FILES_${PN} = " \
  12         ${bindir}/${TARGET_PREFIX}* \
  13         ${libdir}/lib*-*.so \
  14         ${prefix}/${TARGET_SYS}/bin/*"
  15
  16 FILES_${PN}-dev = " \
  17         ${includedir} \
  18         ${libdir}/*.a \
  19         ${libdir}/*.la \
  20         ${libdir}/libbfd.so \
  21         ${libdir}/libopcodes.so"
  22
  23 FILES_${PN}-symlinks = " \
  24         ${bindir}/addr2line \
  25         ${bindir}/ar \
  26         ${bindir}/as \
  27         ${bindir}/c++filt \
  28         ${bindir}/gprof \
  29         ${bindir}/ld \
  30         ${bindir}/nm \
  31         ${bindir}/objcopy \
  32         ${bindir}/objdump \
  33         ${bindir}/ranlib \
  34         ${bindir}/readelf \
  35         ${bindir}/size \
  36         ${bindir}/strings \
  37         ${bindir}/strip"
  38
  39 SRC_URI = \
  40     "http://ftp.kernel.org/pub/linux/devel/binutils/binutils-${PV}.tar.bz2 \
  41      file://ld_makefile.patch;patch=1 \
  42      file://better_file_error.patch;patch=1 \
  43      file://signed_char_fix.patch;patch=1 \
  44      file://objdump_fix.patch;patch=1 \
  45      file://binutils-100_cflags_for_build.patch;patch=1 \
  46      file://binutils-2.15.91.0.1-uclibc-100-conf.patch;patch=1 \
  47      file://binutils-2.15.90.0.3-uclibc-200-build_modules.patch;patch=1 \
  48      file://binutils-2.15-allow-gcc-4.0.patch;patch=1"
  49 S = "${WORKDIR}/binutils-${PV}"
  50 B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
  51
  52 EXTRA_OECONF = "--program-prefix=${TARGET_PREFIX} \
  53                 --enable-shared"
  54
  55 # This is necessary due to a bug in the binutils Makefiles
  56 EXTRA_OEMAKE = "configure-build-libiberty all"
  57
  58 export AR = "${HOST_PREFIX}ar"
  59 export AS = "${HOST_PREFIX}as"
  60 export LD = "${HOST_PREFIX}ld"
  61 export NM = "${HOST_PREFIX}nm"
  62 export RANLIB = "${HOST_PREFIX}ranlib"
  63 export OBJCOPY = "${HOST_PREFIX}objcopy"
  64 export OBJDUMP = "${HOST_PREFIX}objdump"
  65
  66 export AR_FOR_TARGET = "${TARGET_PREFIX}ar"
  67 export AS_FOR_TARGET = "${TARGET_PREFIX}as"
  68 export LD_FOR_TARGET = "${TARGET_PREFIX}ld"
  69 export NM_FOR_TARGET = "${TARGET_PREFIX}nm"
  70 export RANLIB_FOR_TARGET = "${TARGET_PREFIX}ranlib"
  71
  72 export CC_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
  73 export CXX_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
  74
  75 export CC_FOR_BUILD = "${BUILD_CC}"
  76 export CPP_FOR_BUILD = "${BUILD_CPP}"
  77 export CFLAGS_FOR_BUILD = "${BUILD_CFLAGS}"
  78
  79 export CC = "${CCACHE} ${HOST_PREFIX}gcc ${HOST_CC_ARCH}"
  80
  81 do_configure () {
  82         (cd ${S}; gnu-configize) || die "Failed to run gnu-configize"
  83         oe_runconf
  84 }
  85
  86 do_stage () {
  87         oe_libinstall -so -a -C opcodes libopcodes ${STAGING_LIBDIR}/
  88         oe_libinstall -a -C libiberty libiberty ${STAGING_LIBDIR}/
  89         oe_libinstall -so -a -C bfd libbfd ${STAGING_LIBDIR}/
  90         install -m 0644 ${S}/include/dis-asm.h ${STAGING_INCDIR}/
  91         install -m 0644 ${S}/include/symcat.h ${STAGING_INCDIR}/
  92         install -m 0644 ${S}/include/libiberty.h ${STAGING_INCDIR}/
  93         install -m 0644 ${S}/include/ansidecl.h ${STAGING_INCDIR}/
  94         install -m 0644 ${S}/include/bfdlink.h ${STAGING_INCDIR}/
  95         install -m 0644 bfd/bfd.h ${STAGING_INCDIR}/
  96 }
  97
  98 do_install () {
  99         autotools_do_install
 100
 101         # We don't really need these, so we'll remove them...
 102         rm -rf ${D}${libdir}/ldscripts
 103
 104         # Fix the /usr/${TARGET_SYS}/bin/* links
 105         for l in ${D}${prefix}/${TARGET_SYS}/bin/*; do
 106                 rm -f $l
 107                 ln -sf `echo ${prefix}/${TARGET_SYS}/bin \
 108                         | tr -s / \
 109                         | sed -e 's,^/,,' -e 's,[^/]*,..,g'`${bindir}/${TARGET_PREFIX}`basename $l` $l
 110         done
 111
 112         # Install the libiberty header
 113         install -d ${D}${includedir}
 114         install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
 115         install -m 644 ${S}/include/libiberty.h ${D}${includedir}
 116
 117         cd ${D}${bindir}
 118
 119         # Symlinks for ease of running these on the native target
 120         for p in ${TARGET_SYS}-* ; do
 121                 ln -sf $p `echo $p | sed -e s,${TARGET_SYS}-,,`
 122         done
 123 }