code.vuplus.com Git - vuplus_openembedded/blob - packages/base-files/base-files_3.0.14.bb

   1 DESCRIPTION = "Miscellaneous files for the base system."
   2 SECTION = "base"
   3 PRIORITY = "required"
   4 PR = "r76"
   5 LICENSE = "GPL"
   6
   7 SRC_URI = " \
   8            file://nsswitch.conf \
   9            file://motd \
  10            file://inputrc \
  11            file://host.conf \
  12            file://profile \
  13            file://fstab \
  14            file://filesystems \
  15            file://issue.net \
  16            file://issue \
  17            file://usbd \
  18            file://share/dot.bashrc \
  19            file://share/dot.profile \
  20            file://licenses/BSD \
  21            file://licenses/GPL-2 \
  22            file://licenses/LGPL-2 \
  23            file://licenses/LGPL-2.1 \
  24            file://licenses/Artistic "
  25 S = "${WORKDIR}"
  26
  27 docdir_append = "/${P}"
  28 dirs1777 = "/tmp ${localstatedir}/volatile/lock ${localstatedir}/volatile/tmp"
  29 dirs2775 = "/home ${prefix}/src ${localstatedir}/local"
  30 dirs755 = "/bin /boot /dev ${sysconfdir} ${sysconfdir}/default \
  31            ${sysconfdir}/skel /lib /mnt /proc /home/root /sbin \
  32            ${prefix} ${bindir} ${docdir} /usr/games ${includedir} \
  33            ${libdir} ${sbindir} ${datadir} \
  34            ${datadir}/common-licenses ${datadir}/dict ${infodir} \
  35            ${mandir} ${datadir}/misc ${localstatedir} \
  36            ${localstatedir}/backups ${localstatedir}/lib \
  37            /sys ${localstatedir}/lib/misc ${localstatedir}/spool \
  38            ${localstatedir}/volatile ${localstatedir}/volatile/cache \
  39            ${localstatedir}/volatile/lock/subsys \
  40            ${localstatedir}/volatile/log \
  41            ${localstatedir}/volatile/run \
  42            /mnt /media /media/card /media/cf /media/net /media/ram \
  43            /media/union /media/realroot /media/hdd \
  44            /media/mmc1"
  45 volatiles = "cache run log lock tmp"
  46 conffiles = "${sysconfdir}/debian_version ${sysconfdir}/host.conf \
  47              ${sysconfdir}/inputrc ${sysconfdir}/issue /${sysconfdir}/issue.net \
  48              ${sysconfdir}/nsswitch.conf ${sysconfdir}/profile \
  49              ${sysconfdir}/default"
  50
  51 #
  52 # set standard hostname, might be a candidate for a DISTRO variable? :M:
  53 #
  54 hostname = "openembedded"
  55 hostname_slugos = "nslu2"
  56 hostname_mnci = "MNCI"
  57 hostname_rt3000 = "MNRT"
  58 hostname_jlime = "JLime"
  59
  60 do_install () {
  61         for d in ${dirs755}; do
  62                 install -m 0755 -d ${D}$d
  63         done
  64         for d in ${dirs1777}; do
  65                 install -m 1777 -d ${D}$d
  66         done
  67         for d in ${dirs2775}; do
  68                 install -m 2755 -d ${D}$d
  69         done
  70         for d in ${volatiles}; do
  71                 ln -sf volatile/$d ${D}/${localstatedir}/$d
  72         done
  73         for d in card cf net ram; do
  74                 ln -sf /media/$d ${D}/mnt/$d
  75         done
  76
  77         if [ -n "${MACHINE}" -a "${hostname}" = "openembedded" ]; then
  78                 echo ${MACHINE} > ${D}${sysconfdir}/hostname
  79         else
  80                 echo ${hostname} > ${D}${sysconfdir}/hostname
  81         fi
  82
  83         install -m 644 ${WORKDIR}/issue*  ${D}${sysconfdir}
  84
  85         if [ -n "${DISTRO_NAME}" ]; then
  86                 echo -n "${DISTRO_NAME} " >> ${D}${sysconfdir}/issue
  87                 echo -n "${DISTRO_NAME} " >> ${D}${sysconfdir}/issue.net
  88                 if [ -n "${DISTRO_VERSION}" ]; then
  89                         echo -n "${DISTRO_VERSION} " >> ${D}${sysconfdir}/issue
  90                         echo -n "${DISTRO_VERSION} " >> ${D}${sysconfdir}/issue.net
  91                 fi
  92                 echo "\n \l" >> ${D}${sysconfdir}/issue
  93                 echo >> ${D}${sysconfdir}/issue
  94                 echo "%h"    >> ${D}${sysconfdir}/issue.net
  95                 echo >> ${D}${sysconfdir}/issue.net
  96         else
  97                install -m 0644 ${WORKDIR}/issue ${D}${sysconfdir}/issue
  98                install -m 0644 ${WORKDIR}/issue.net ${D}${sysconfdir}/issue.net
  99         fi
 100
 101         install -m 0644 ${WORKDIR}/fstab ${D}${sysconfdir}/fstab
 102         install -m 0644 ${WORKDIR}/filesystems ${D}${sysconfdir}/filesystems
 103         install -m 0644 ${WORKDIR}/usbd ${D}${sysconfdir}/default/usbd
 104         install -m 0644 ${WORKDIR}/profile ${D}${sysconfdir}/profile
 105         install -m 0755 ${WORKDIR}/share/dot.profile ${D}${sysconfdir}/skel/.profile
 106         install -m 0755 ${WORKDIR}/share/dot.bashrc ${D}${sysconfdir}/skel/.bashrc
 107         install -m 0644 ${WORKDIR}/inputrc ${D}${sysconfdir}/inputrc
 108         install -m 0644 ${WORKDIR}/nsswitch.conf ${D}${sysconfdir}/nsswitch.conf
 109         install -m 0644 ${WORKDIR}/host.conf ${D}${sysconfdir}/host.conf
 110         install -m 0644 ${WORKDIR}/motd ${D}${sysconfdir}/motd
 111
 112         for license in BSD GPL-2 LGPL-2 LGPL-2.1 Artistic; do
 113                 install -m 0644 ${WORKDIR}/licenses/$license ${D}${datadir}/common-licenses/
 114         done
 115
 116         ln -sf /proc/mounts ${D}${sysconfdir}/mtab
 117 }
 118
 119
 120 do_install_append_mnci () {
 121         rmdir ${D}/tmp
 122         ln -s var/tmp ${D}/tmp
 123 }
 124
 125 do_install_append_nylon() {
 126         printf "" "" >${D}${sysconfdir}/resolv.conf
 127         rm -r ${D}/mnt/*
 128         rm -r ${D}/media
 129         rm -rf ${D}/tmp
 130         ln -sf /var/tmp ${D}/tmp
 131 }
 132
 133 do_install_append_slugos() {
 134         printf "" "" >${D}${sysconfdir}/resolv.conf
 135         rm -r ${D}/mnt/*
 136         rmdir ${D}/home/root
 137         install -m 0755 -d ${D}/root
 138         ln -s ../root ${D}/home/root
 139 }
 140
 141 do_install_append_netbook-pro () {
 142         mkdir -p ${D}/initrd
 143 }
 144
 145 PACKAGES = "${PN}-doc ${PN}"
 146 FILES_${PN} = "/*"
 147 FILES_${PN}-doc = "${docdir} ${datadir}/common-licenses"
 148
 149 # M&N specific packaging
 150 PACKAGE_ARCH_mnci = "mnci"
 151 PACKAGE_ARCH_rt3000 = "rt3000"
 152
 153 PACKAGE_ARCH = "${MACHINE_ARCH}"
 154
 155 # Unslung distribution specific packaging
 156
 157 PACKAGES_unslung = "${PN}-unslung"
 158 PACKAGE_ARCH_${PN}-unslung = "nslu2"
 159 RDEPENDS_${PN}-unslung = "nslu2-linksys-ramdisk"
 160 RPROVIDES_${PN}-unslung = "${PN}"
 161
 162 FILES_${PN}-unslung = ""
 163
 164 CONFFILES_${PN} = "${sysconfdir}/fstab ${sysconfdir}/hostname"
 165 CONFFILES_${PN}_nylon = "${sysconfdir}/resolv.conf ${sysconfdir}/fstab ${sysconfdir}/hostname"
 166 CONFFILES_${PN}_slugos = "${sysconfdir}/resolv.conf ${sysconfdir}/fstab ${sysconfdir}/hostname"
 167