code.vuplus.com Git - vuplus_openembedded/blob - packages/avetanabt/avetanabt_20060413.bb

   1 DESCRIPTION = "avetanaBT: Bluetooth API implementation for Java (JSR-82)"
   2 SECTION = "devel"
   3 DEPENDS = "findutils-native virtual/javac-native kaffeh-native fastjar-native bluez-libs classpath"
   4 LICENSE = "GPL"
   5 HOMEPAGE = "http://sourceforge.net/projects/avetanabt/"
   6
   7 FILE_PR = "r0"
   8
   9 SRC_URI = "${SOURCEFORGE_MIRROR}/avetanabt/avetanaBluetooth-${PV}.tgz"
  10
  11 S = "${WORKDIR}/avetanabt"
  12
  13 FILES_${PN} = "${libdir}/libavetanaBT.so ${datadir}/avetanabt/avetanaBT.jar"
  14
  15 do_compile() {
  16
  17   # doing nearly the same as in Makefile written...
  18
  19   # clean build directory
  20   mkdir -p build
  21   rm -fr build/*
  22
  23   # generate classes
  24   ${STAGING_BINDIR_NATIVE}/find {de,javax,com} -iname *.java > file.list
  25   ${STAGING_BINDIR_NATIVE}/javac -verbose -bootclasspath ${STAGING_DATADIR_NATIVE}/kaffeh/rt.jar -d build @file.list
  26
  27   # create own version.xml (add version information available at runtime)
  28   head -n 4 version.xml >> build/version.xml
  29   echo "    <build value=\"cvs${SRCDATE}\" date=\"${SRCDATE}\" time=\"${@time.strftime('%H:%M',time.gmtime())}\"/>" >> build/version.xml
  30   tail -n 3 version.xml >> build/version.xml
  31
  32   # move classes into jar archive
  33   # jar -> fastjar
  34   ${STAGING_BINDIR_NATIVE}/fastjar -v -cf avetanaBT.jar -C build de -C build javax -C build com -C build version.xml
  35
  36   # JNI generated header file - de_avetana_bluetooth_stack_BlueZ.h
  37   # javah -> kaffeh
  38   ${STAGING_BINDIR_NATIVE}/kaffeh -jni -classpath avetanaBT.jar:${STAGING_DATADIR_NATIVE}/kaffeh/rt.jar -d c de.avetana.bluetooth.stack.BlueZ
  39
  40   # Native language (C) library - libavetanaBT.so
  41   ${CXX} ${CXXFLAGS}  -shared -lbluetooth -I${STAGING_INCDIR}/classpath c/BlueZ.cpp -o libavetanaBT.so ${LDFLAGS}
  42
  43 }
  44
  45 do_stage() {
  46
  47   install -d ${STAGING_DATADIR_NATIVE}/avetanabt
  48   install avetanaBT.jar ${STAGING_DATADIR_NATIVE}/avetanabt/
  49
  50 }
  51
  52 do_install() {
  53
  54   install -d ${D}${libdir}
  55   install -m 0755 libavetanaBT.so ${D}${libdir}/
  56
  57   install -d ${D}${datadir}/avetanabt
  58   install avetanaBT.jar ${D}${datadir}/avetanabt/
  59
  60 }