code.vuplus.com Git - vuplus_openembedded/blob - packages/avetanabt/avetanabt_20060413.bb

   1 DESCRIPTION = "avetanaBT: Bluetooth API implementation for Java (JSR-82)"
   2 SECTION = "devel"
   3 DEPENDS = "findutils-native jikes-native kaffeh-native fastjar-native bluez-libs classpath"
   4 LICENSE = "GPL"
   5 HOMEPAGE = "http://sourceforge.net/projects/avetanabt/"
   6
   7 PR = "r0"
   8
   9 SRC_URI = "${SOURCEFORGE_MIRROR}/avetanabt/avetanaBluetooth-${PV}.tgz"
  10
  11 S = "${WORKDIR}/avetanabt"
  12
  13 PACKAGES = "${PN}"
  14 FILES_${PN} = "${libdir}/libavetanaBT.so ${datadir}/avetanabt/avetanaBT.jar"
  15
  16 do_compile() {
  17
  18   # doing nearly the same as in Makefile written...
  19
  20   # clean build directory
  21   mkdir -p build
  22   rm -fr build/*
  23
  24   # generate classes
  25   # javac -> jikes
  26   ${STAGING_BINDIR_NATIVE}/find {de,javax,com} -iname *.java > file.list
  27   ${STAGING_BINDIR_NATIVE}/jikes -verbose --bootclasspath ${STAGING_DIR}/${BUILD_SYS}/share/kaffeh/rt.jar -d build @file.list
  28
  29   # create own version.xml (add version information available at runtime)
  30   head -n 4 version.xml >> build/version.xml
  31   echo "    <build value=\"cvs${SRCDATE}\" date=\"${SRCDATE}\" time=\"${@time.strftime('%H:%M',time.gmtime())}\"/>" >> build/version.xml
  32   tail -n 3 version.xml >> build/version.xml
  33
  34   # move classes into jar archive
  35   # jar -> fastjar
  36   ${STAGING_BINDIR_NATIVE}/fastjar -v -cf avetanaBT.jar -C build de -C build javax -C build com -C build version.xml
  37
  38   # JNI generated header file - de_avetana_bluetooth_stack_BlueZ.h
  39   # javah -> kaffeh
  40   ${STAGING_BINDIR_NATIVE}/kaffeh -jni -classpath avetanaBT.jar:${STAGING_DIR}/${BUILD_SYS}/share/kaffeh/rt.jar -d c de.avetana.bluetooth.stack.BlueZ
  41
  42   # Native language (C) library - libavetanaBT.so
  43   ${CXX} ${CXXFLAGS}  -shared -lbluetooth -I${STAGING_INCDIR}/classpath c/BlueZ.cpp -o libavetanaBT.so ${LDFLAGS}
  44
  45 }
  46
  47 do_stage() {
  48
  49   install -d ${STAGING_DIR}/${BUILD_SYS}/share/avetanabt
  50   install avetanaBT.jar ${STAGING_DIR}/${BUILD_SYS}/share/avetanabt/
  51
  52 }
  53
  54 do_install() {
  55
  56   install -d ${D}${libdir}
  57   install -m 0755 libavetanaBT.so ${D}${libdir}/
  58
  59   install -d ${D}${datadir}/avetanabt
  60   install avetanaBT.jar ${D}${datadir}/avetanabt/
  61
  62 }