code.vuplus.com Git - vuplus_openembedded/blob - packages/alsa/alsa-lib_1.0.13.bb

   1 DESCRIPTION = "Alsa sound library"
   2 HOMEPAGE = "http://www.alsa-project.org"
   3 SECTION = "libs/multimedia"
   4 LICENSE = "GPL"
   5 PR = "r4"
   6
   7 # configure.in sets -D__arm__ on the command line for any arm system
   8 # (not just those with the ARM instruction set), this should be removed,
   9 # (or replaced by a permitted #define).
  10 #FIXME: remove the following
  11 ARM_INSTRUCTION_SET = "arm"
  12
  13 SRC_URI = "ftp://ftp.alsa-project.org/pub/lib/alsa-lib-${PV}.tar.bz2 \
  14            file://fix-tstamp-declaration.patch;patch=1"
  15
  16 inherit autotools pkgconfig
  17
  18 EXTRA_OECONF = "--with-cards=pdaudiocf --with-oss=yes"
  19
  20 do_stage() {
  21         oe_libinstall -so -C src libasound ${STAGING_LIBDIR}/
  22         install -d ${STAGING_INCDIR}/alsa/sound
  23         install -m 0644 include/*.h ${STAGING_INCDIR}/alsa/
  24         install -m 0644 include/sound/ainstr*.h ${STAGING_INCDIR}/alsa/sound/
  25         install -d ${STAGING_DATADIR}/aclocal
  26         install -m 0644 utils/alsa.m4 ${STAGING_DATADIR}/aclocal/
  27 }
  28
  29 PACKAGES =+ "alsa-server libasound alsa-conf-base alsa-conf alsa-doc alsa-dev"
  30 FILES_${PN}-dbg += "${libdir}/alsa-lib/*/.debu*"
  31 FILES_libasound = "${libdir}/libasound.so.*"
  32 FILES_alsa-server = "${bindir}/*"
  33 FILES_alsa-conf = "${datadir}/alsa/"
  34 FILES_alsa-dev += "${libdir}/pkgconfig/ /usr/include/ ${datadir}/aclocal/*"
  35 FILES_alsa-conf-base = "\
  36 ${datadir}/alsa/alsa.conf \
  37 ${datadir}/alsa/cards/aliases.conf \
  38 ${datadir}/alsa/pcm/default.conf \
  39 ${datadir}/alsa/pcm/dmix.conf \
  40 ${datadir}/alsa/pcm/dsnoop.conf"
  41
  42 RDEPENDS_libasound = "alsa-conf-base"