code.vuplus.com Git - vuplus_openembedded/blob - libopie/libopie2_cvs.oe

   1 DESCRIPTION = "Base libraries for the Open Palmtop Integrated Environment"
   2 HOMEPAGE = "http://opie.handhelds.org"
   3 SECTION = "opie/libs"
   4 MAINTAINER = "Michael Lauer <mickey@Vanille.de>"
   5 LICENSE = "LGPL"
   6 DEPENDS = "libqpe-opie sqlite libpcap-0.7.2 virtual/kernel"
   7 PROVIDES = "libopiecore2 libopiedb2 libopiemm2 libopiesecurity2 libopienet2 libopiepim2 libopieui2 "
   8 PV = "1.1.5-cvs-${CVSDATE}"
   9 PR = "r2"
  10
  11 SRC_URI = "cvs://anoncvs:anoncvs@cvs.handhelds.org/cvs;module=opie/libopie2 \
  12            file://include.pro"
  13 S = "${WORKDIR}/libopie2"
  14
  15 inherit opie
  16
  17 export QTDIR = "${STAGING_LIBDIR}/.."
  18 export OPIEDIR = "${STAGING_LIBDIR}/.."
  19
  20 #FIXME: Add machine specific bits here. Best use oe_machinstall and read from a given file
  21
  22 EXTRA_QMAKEVARS_POST = 'DEFINES+=OPIE_NEW_MALLOC \
  23                         DEFINES+="OPIE_SOUND_FRAGMENT_SHIFT=16" \
  24                         DEFINES+=OPIE_NO_ERASE_RECT_HACKFIX \
  25                         LIBS+=-L${S} LIBS+="-Wl,-rpath-link,${S}"'
  26
  27 EXTRA_QMAKEVARS_PRE = 'ENABLE_SQL_PIM_BACKEND=y'
  28
  29 # uclibc doesn't have backtrace()
  30 python __anonymous () {
  31     import oe, re
  32     if (re.match('.*uclibc$', oe.data.getVar('TARGET_OS', d, 1)) != None):
  33         oe.data.setVar("EXTRA_QMAKEVARS_POST_append", " DEFINES+=OPIE_NO_BACKTRACE ", d)
  34 }
  35
  36 do_compile() {
  37         install -d ${STAGING_INCDIR}/opie2
  38         for i in `find . -name "*.h"`
  39         do
  40                 install -m 0644 $i ${STAGING_INCDIR}/opie2/`basename $i`
  41         done
  42         oe_runmake MOC=${STAGING_BINDIR}/moc UIC=${STAGING_BINDIR}/uic DESTDIR=${S}
  43 }
  44
  45 LIBS = "core2 ui2 db2 mm2 net2 pim2 security2"
  46
  47 # need some special case for uic-created header files here
  48 do_stage() {
  49         for f in ${LIBS}
  50         do
  51                 oe_libinstall -so libopie$f ${STAGING_LIBDIR}/
  52         done
  53
  54         install -m 0644 ${WORKDIR}/include.pro ${OPIEDIR}/
  55         install -m 0644 opiepim/ui/opimrecurrencebase.h ${STAGING_INCDIR}/opie2/
  56         install -m 0644 opieui/otimepickerbase.h ${STAGING_INCDIR}/opie2/
  57         install -m 0644 opiepim/core/opimtemplatebase.h ${STAGING_INCDIR}/opie2/
  58 }
  59
  60 do_install() {
  61         install -d ${D}/${palmtopdir}/lib
  62         for f in ${LIBS}
  63         do
  64                 oe_libinstall -so libopie$f ${D}/${palmtopdir}/lib
  65         done
  66 }
  67
  68 PACKAGES = "libopiecore2 libopiedb2 libopiesecurity2 libopiemm2 libopienet2 libopiepim2 libopieui2"
  69 FILES_libopiecore2 = "${palmtopdir}/lib/libopiecore2.so*"
  70 FILES_libopiedb2 = "${palmtopdir}/lib/libopiedb2.so*"
  71 FILES_libopiemm2 = "${palmtopdir}/lib/libopiemm2.so*"
  72 FILES_libopienet2 = "${palmtopdir}/lib/libopienet2.so*"
  73 FILES_libopiepim2 = "${palmtopdir}/lib/libopiepim2.so*"
  74 FILES_libopieui2 = "${palmtopdir}/lib/libopieui2.so*"
  75 FILES_libopiesecurity2 = "${palmtopdir}/lib/libopiesecurity2.so*"
  76
  77 #FIXME: Add individual package descriptions and dependencies