code.vuplus.com Git - vuplus_openembedded/blob - conf/machine/include/zaurus-2.6.inc

   1 # Zaurus specific configuration for kernel 2.6
   2 # Additionally, clamshell specific stuff in zaurus-clamshell.inc
   3
   4 TARGET_ARCH = "arm"
   5 PACKAGE_EXTRA_ARCHS = "armv4 armv4t armv5e armv5te"
   6 PACKAGE_EXTRA_ARCHS_collie = ""
   7
   8 MACHINE_KERNEL_VERSION = "2.6"
   9
  10 ERASEBLOCKSIZE = "0x4000"
  11 ERASEBLOCKSIZE_akita = "0x20000"
  12
  13 EXTRA_IMAGECMD_jffs2 = "--little-endian --eraseblock=${ERASEBLOCKSIZE} --pad --faketime -n"
  14 IMAGE_CMD_jffs2 = "mkfs.jffs2 -x lzo --root=${IMAGE_ROOTFS} --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
  15 EXTRA_IMAGEDEPENDS += "zaurus-updater"
  16
  17 SERIAL_CONSOLE = "115200 ttyS0"
  18 SERIAL_CONSOLE_collie = "115200 ttySA0"
  19
  20 PREFERRED_PROVIDER_virtual/kernel = "linux-rp"
  21 PREFERRED_PROVIDER_virtual/xserver = "xserver-kdrive"
  22
  23 PCMCIA_MANAGER ?= "pcmciautils"
  24
  25 MACHINE_FEATURES = "kernel26 apm alsa pcmcia irda usbgadget keyboard touchscreen screen vfat"
  26 MACHINE_FEATURES_append_tosa  = " usbhost wifi "
  27 MACHINE_FEATURES_append_akita = " usbhost "
  28 MACHINE_FEATURES_append_spitz = " usbhost ext2 "
  29
  30 MACHINE_EXTRA_RDEPENDS = "zaurusd"
  31 MACHINE_EXTRA_RRECOMMENDS_c7x0   = "kernel-module-snd-soc-corgi kernel-module-pxa2xx-cs kernel-module-pcmcia"
  32 MACHINE_EXTRA_RRECOMMENDS_akita  = "kernel-module-snd-soc-spitz kernel-module-pxa2xx-cs kernel-module-pcmcia"
  33 MACHINE_EXTRA_RRECOMMENDS_spitz  = "kernel-module-snd-soc-spitz"
  34 MACHINE_EXTRA_RRECOMMENDS_poodle = "kernel-module-snd-soc-poodle kernel-module-pxa2xx-cs kernel-module-pcmcia"
  35 MACHINE_EXTRA_RRECOMMENDS_collie = "kernel-module-locomo-spi kernel-module-sa1100-cs kernel-module-mmc-block \
  36         kernel-module-collie-ts kernel-module-leds-locomo kernel-module-locomokbd kernel-module-mmc-spi \
  37         kernel-module-power"
  38
  39 GUI_MACHINE_CLASS = "bigscreen"
  40 GUI_MACHINE_CLASS_collie = "smallscreen"
  41 GUI_MACHINE_CLASS_poodle = "smallscreen"
  42
  43 KERNEL_IMAGE_MAXSIZE = "1294336"
  44 KERNEL_IMAGE_MAXSIZE_collie = "1048576"
  45
  46 MACHINE_POSTPROCESS_COMMAND = "zaurus_make_installkit"
  47
  48 zaurus_make_installkit () {
  49     cd ${DEPLOY_DIR_IMAGE}
  50     rm -rf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}-installkit/
  51     mkdir ${IMAGE_NAME}-installkit/
  52
  53     # Get the latest kernel using the zImage-<machine>.bin symlink
  54     cp zImage-${MACHINE}.bin ${IMAGE_NAME}-installkit/zImage
  55
  56     if [ "${MACHINE}" = "spitz" ]; then
  57         cp gnu-tar ${IMAGE_NAME}-installkit/
  58         cp ${IMAGE_NAME}.rootfs.tar.gz ${IMAGE_NAME}-installkit/hdimage1.tgz
  59     else
  60         [ -f ${IMAGE_NAME}.rootfs.jffs2 ] && cp ${IMAGE_NAME}.rootfs.jffs2 ${IMAGE_NAME}-installkit/initrd.bin
  61     fi
  62
  63     # All zaurus machines except collie need updater.sh
  64     if [ "${MACHINE}" != "collie" ]; then
  65         cp updater.sh.${MACHINE} ${IMAGE_NAME}-installkit/updater.sh
  66     fi
  67
  68     tar czf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}-installkit.tgz ${IMAGE_NAME}-installkit/
  69     md5sum ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}-installkit.tgz > ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}-installkit.tgz.md5
  70     rm -rf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}-installkit/
  71 }
  72
  73 # Don't include kernels in standard images for Zaurus machines
  74 RDEPENDS_kernel-base = ""
  75 KERNEL_IMAGETYPE = "zImage"