code.vuplus.com Git - vuplus_openembedded/blob - conf/bitbake.conf

   1 ##################################################################
   2 # Standard target filesystem layout.
   3 ##################################################################
   4
   5 # Path prefixes
   6 layout_prefix = "/usr"
   7 layout_exec_prefix = "/usr"
   8 layout_base_prefix = ""
   9
  10 # Base paths
  11 layout_base_bindir = "${layout_base_prefix}/bin"
  12 layout_base_sbindir = "${layout_base_prefix}/sbin"
  13 layout_base_libdir = "${layout_base_prefix}/lib"
  14
  15 # Architecture independent paths
  16 layout_sysconfdir = "${layout_base_prefix}/etc"
  17 layout_localstatedir = "${layout_base_prefix}/var"
  18 layout_servicedir = "${layout_base_prefix}/srv"
  19 layout_sharedstatedir = "${layout_prefix}/com"
  20 layout_datadir = "${layout_prefix}/share"
  21 layout_infodir = "${layout_datadir}/info"
  22 layout_mandir = "${layout_datadir}/man"
  23 layout_docdir = "${layout_datadir}/doc"
  24
  25 # Architecture dependent paths
  26 layout_bindir = "${layout_exec_prefix}/bin"
  27 layout_sbindir = "${layout_exec_prefix}/sbin"
  28 layout_libdir = "${layout_exec_prefix}/lib"
  29 layout_includedir = "${layout_exec_prefix}/include"
  30 layout_libexecdir = "${layout_exec_prefix}/libexec"
  31
  32 ##################################################################
  33 # Standard target filesystem paths.
  34 ##################################################################
  35
  36 # Path prefixes
  37 export base_prefix = ""
  38 export prefix = "${layout_prefix}"
  39 export exec_prefix = "${layout_exec_prefix}"
  40
  41 # Base paths
  42 export base_bindir = "${layout_base_bindir}"
  43 export base_sbindir = "${layout_base_sbindir}"
  44 export base_libdir = "${layout_base_libdir}"
  45
  46 # Architecture independent paths
  47 export datadir = "${layout_datadir}"
  48 export sysconfdir = "${layout_sysconfdir}"
  49 export sharedstatedir = "${layout_sharedstatedir}"
  50 export localstatedir = "${layout_localstatedir}"
  51 export infodir = "${layout_infodir}"
  52 export mandir = "${layout_mandir}"
  53 export docdir = "${layout_docdir}"
  54 export servicedir = "${layout_servicedir}"
  55
  56 # Architecture dependent paths
  57 export bindir = "${layout_bindir}"
  58 export sbindir = "${layout_sbindir}"
  59 export libexecdir = "${layout_libexecdir}"
  60 export libdir = "${layout_libdir}"
  61 export includedir = "${layout_includedir}"
  62 export oldincludedir = "${layout_includedir}"
  63
  64 ##################################################################
  65 # Architecture-dependent build variables.
  66 ##################################################################
  67
  68 BUILD_ARCH = "${@os.uname()[4]}"
  69 BUILD_OS = "${@os.uname()[0].lower()}"
  70 BUILD_VENDOR = ""
  71 BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
  72 BUILD_PREFIX = ""
  73 BUILD_CC_ARCH = ""
  74
  75 HOST_ARCH = "${TARGET_ARCH}"
  76 HOST_OS = "${TARGET_OS}"
  77 HOST_VENDOR = "${TARGET_VENDOR}"
  78 HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
  79 HOST_PREFIX = "${TARGET_PREFIX}"
  80 HOST_CC_ARCH = "${TARGET_CC_ARCH}"
  81
  82 TARGET_ARCH ?= "INVALID"
  83 TARGET_OS = "INVALID"
  84 TARGET_VENDOR = "${BUILD_VENDOR}"
  85 TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}${@['-' + bb.data.getVar('TARGET_OS', d, 1), ''][bb.data.getVar('TARGET_OS', d, 1) == ('' or 'custom')]}"
  86 TARGET_PREFIX = "${TARGET_SYS}-"
  87 TARGET_CC_ARCH = ""
  88
  89 BASE_PACKAGE_ARCH = "${HOST_ARCH}"
  90 PACKAGE_ARCH = "${BASE_PACKAGE_ARCH}"
  91 MACHINE_ARCH = "${@[bb.data.getVar('HOST_ARCH', d, 1), bb.data.getVar('MACHINE', d, 1)][bool(bb.data.getVar('MACHINE', d, 1))]}"
  92 PACKAGE_ARCHS = "all any noarch ${TARGET_ARCH} ${PACKAGE_EXTRA_ARCHS} ${MACHINE}"
  93
  94 MULTIMACH_ARCH = "${PACKAGE_ARCH}"
  95 MULTIMACH_TARGET_SYS = "${MULTIMACH_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
  96 MULTIMACH_HOST_SYS = "${MULTIMACH_ARCH}${HOST_VENDOR}-${HOST_OS}"
  97 BASEPKG_HOST_SYS = "${BASE_PACKAGE_ARCH}${HOST_VENDOR}-${HOST_OS}"
  98 BASEPKG_TARGET_SYS = "${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
  99
 100 # select proper CPU to get binary locales generated
 101 QEMU_OPTIONS = ""
 102 QEMU_OPTIONS_iwmmxt  = "-cpu pxa270-c5"
 103 QEMU_OPTIONS_armv6   = "-cpu arm1136"
 104 QEMU_OPTIONS_armv6-novfp = ""-cpu arm1136"
 105 QEMU_OPTIONS_armv7a   = "-cpu cortex-a8"
 106
 107 ##################################################################
 108 # Date/time variables.
 109 ##################################################################
 110
 111 DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
 112 TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
 113 DATETIME = "${DATE}${TIME}"
 114
 115 ##################################################################
 116 # Openembedded Software Prerequisites.
 117 ##################################################################
 118
 119 # python-native should be here but python relies on building
 120 # its own in staging
 121 ASSUME_PROVIDED = "\
 122     bc-native \
 123     bzip2-native \
 124     cvs-native \
 125     diffstat-native \
 126     patch-native \
 127     perl-native-runtime \
 128     python-native-runtime \
 129     svn-native \
 130     texinfo-native \
 131     util-linux-native \
 132     "
 133
 134 ##################################################################
 135 # Package default variables.
 136 ##################################################################
 137 PN = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[0] or 'defaultpkgname'}"
 138 PV = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[1] or '1.0'}"
 139 PR = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[2] or 'r0'}"
 140 PF = "${PN}-${EXTENDPE}${PV}-${PR}"
 141 EXTENDPE = "${@['','${PE\x7d_'][bb.data.getVar('PE',d,1) > 0]}"
 142 EXTENDPEVER = "${@['','${PE\x7d:'][bb.data.getVar('PE',d,1) > 0]}"
 143 EXTENDPV = "${EXTENDPEVER}${PV}-${PR}${DISTRO_PR}"
 144 P = "${PN}-${PV}"
 145
 146 # Base package name
 147 # Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
 148 # otherwise it is the same as PN and P
 149 BPN = "${@base_package_name(d)}"
 150 BP = "${BPN}-${PV}"
 151
 152 # Package info.
 153
 154 SECTION = "base"
 155 PRIORITY = "optional"
 156 DESCRIPTION = "Version ${PV}-${PR} of package ${PN}"
 157 LICENSE = "unknown"
 158 MAINTAINER = "OpenEmbedded Team <openembedded-devel@lists.openembedded.org>"
 159 HOMEPAGE = "unknown"
 160
 161 # Package dependencies and provides.
 162
 163 # Ensure that -dev packages recommend the corresponding -dev packages of their
 164 # deps, and the same for -dbg.
 165 DEPCHAIN_PRE  = ""
 166 DEPCHAIN_POST = "-dev -dbg"
 167
 168 DEPENDS = ""
 169 RDEPENDS = ""
 170 PROVIDES = ""
 171 PROVIDES_prepend = "${P} ${PF} ${PN} "
 172 RPROVIDES = ""
 173
 174 MULTI_PROVIDER_WHITELIST = "virtual/libintl"
 175
 176 SOLIBS = ".so.*"
 177 SOLIBS_darwin = ".*.dylib"
 178 SOLIBS_darwin8 = ".*.dylib"
 179
 180 SOLIBSDEV = ".so"
 181 SOLIBSDEV_darwin = ".dylib"
 182 SOLIBSDEV_darwin8 = ".dylib"
 183
 184 PACKAGES = "${PN}-dbg ${PN} ${PN}-doc ${PN}-dev ${PN}-locale"
 185 #enable this when bitbake is upgraded to cope with ++ values in the field
 186 #PACKAGES_DYNAMIC = "${PN}-locale-*"
 187 FILES = ""
 188
 189 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*.so.* \
 190             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
 191             ${base_bindir}/* ${base_sbindir}/* ${base_libdir}/*.so* ${datadir}/${PN} ${libdir}/${PN}/* \
 192             ${datadir}/pixmaps ${datadir}/applications \
 193             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
 194             ${libdir}/bonobo/servers"
 195
 196 FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
 197             ${datadir}/gnome/help"
 198 SECTION_${PN}-doc = "doc"
 199
 200 FILES_${PN}-dev = "${includedir} ${libdir}/lib*.so ${libdir}/*.la \
 201                 ${libdir}/*.a ${libdir}/*.o ${libdir}/pkgconfig \
 202                 ${base_libdir}/*.a ${base_libdir}/*.o ${datadir}/aclocal"
 203 SECTION_${PN}-dev = "devel"
 204 ALLOW_EMPTY_${PN}-dev = "1"
 205 RDEPENDS_${PN}-dev = "${PN} (= ${EXTENDPV})"
 206
 207 FILES_${PN}-dbg = "${bindir}/.debug ${sbindir}/.debug ${libexecdir}/.debug ${libdir}/.debug \
 208             ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug ${libdir}/${PN}/.debug \
 209             ${libdir}/matchbox-panel/.debug"
 210 SECTION_${PN}-dbg = "devel"
 211 ALLOW_EMPTY_${PN}-dbg = "1"
 212 RRECOMMENDS_${PN}-dbg = "${PN} (= ${EXTENDPV})"
 213
 214 FILES_${PN}-locale = "${datadir}/locale"
 215
 216 # File manifest
 217
 218 export MANIFEST = "${FILESDIR}/manifest"
 219
 220 FILE_DIRNAME = "${@os.path.dirname(bb.data.getVar('FILE', d))}"
 221 FILESPATH = "${FILE_DIRNAME}/${PF}:${FILE_DIRNAME}/${P}:${FILE_DIRNAME}/${PN}:${FILE_DIRNAME}/${BP}:${FILE_DIRNAME}/${BPN}:${FILE_DIRNAME}/files:${FILE_DIRNAME}"
 222 FILESDIR = "${@bb.which(bb.data.getVar('FILESPATH', d, 1), '.')}"
 223
 224 ##################################################################
 225 # General work and output directories for the build system.
 226 ##################################################################
 227
 228 TMPDIR = "${TOPDIR}/tmp"
 229 CACHE = "${TMPDIR}/cache${@['', '/' + str(bb.data.getVar('MACHINE', d, 1))][bool(bb.data.getVar('MACHINE', d, 1))]}"
 230 CO_DIR = "${DL_DIR}"
 231 CVSDIR = "${CO_DIR}/cvs"
 232 SVNDIR = "${CO_DIR}/svn"
 233 GITDIR = "${CO_DIR}/git"
 234 BZRDIR = "${CO_DIR}/bzr"
 235 HGDIR = "${CO_DIR}/hg"
 236
 237 STAMP = "${TMPDIR}/stamps/${MULTIMACH_TARGET_SYS}/${PF}"
 238 WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PF}"
 239 T = "${WORKDIR}/temp"
 240 D = "${WORKDIR}/image"
 241 S = "${WORKDIR}/${BP}"
 242 B = "${S}"
 243
 244 STAGING_DIR = "${TMPDIR}/staging"
 245
 246 STAGING_DIR_NATIVE = "${STAGING_DIR}/${BUILD_SYS}"
 247 STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_bindir}"
 248 STAGING_BINDIR_CROSS  = "${STAGING_DIR_NATIVE}${layout_bindir}/${MULTIMACH_HOST_SYS}"
 249 STAGING_BINDIR_CROSS_BASEPKG = "${STAGING_DIR_NATIVE}${layout_bindir}/${BASEPKG_TARGET_SYS}"
 250 STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_libdir}"
 251 STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_includedir}"
 252 STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_sysconfdir}"
 253 STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_datadir}"
 254
 255 # This should really be MULTIMACH_HOST_SYS but that breaks "all" and machine
 256 # specific packages - hack around it for now.
 257 STAGING_DIR_HOST = "${STAGING_DIR}/${BASEPKG_HOST_SYS}"
 258 STAGING_BINDIR = "${STAGING_DIR_HOST}${layout_bindir}"
 259 STAGING_LIBDIR = "${STAGING_DIR_HOST}${layout_libdir}"
 260 STAGING_INCDIR = "${STAGING_DIR_HOST}${layout_includedir}"
 261 STAGING_DATADIR = "${STAGING_DIR_HOST}${layout_datadir}"
 262 STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${layout_exec_prefix}"
 263 STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
 264 STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
 265 STAGING_PYDIR = "${STAGING_DIR}/lib/python2.4"
 266
 267 # This should really be MULTIMACH_TARGET_SYS but that breaks "all" and machine
 268 # specific packages - hack around it for now.
 269 STAGING_DIR_TARGET = "${STAGING_DIR}/${BASEPKG_TARGET_SYS}"
 270
 271 DEPLOY_DIR = "${TMPDIR}/deploy"
 272 DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
 273 DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
 274 DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
 275 DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
 276 DEPLOY_DIR_IMAGE = "${DEPLOY_DIR}/images"
 277 DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
 278
 279 PKGDATA_DIR = "${TMPDIR}/pkgdata/${MULTIMACH_TARGET_SYS}"
 280
 281 SDK_NAME = "${DISTRO}/${TARGET_ARCH}"
 282 SDK_PREFIX = "/usr/local/${SDK_NAME}"
 283
 284 ##################################################################
 285 # Kernel info.
 286 ##################################################################
 287
 288 OLDEST_KERNEL = "2.4.0"
 289 STAGING_KERNEL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/kernel"
 290
 291 ##################################################################
 292 # Specific image creation and rootfs population info.
 293 ##################################################################
 294
 295 IMAGE_ROOTFS = "${TMPDIR}/rootfs"
 296 IMAGE_BASENAME = "${PN}"
 297 IMAGE_NAME = "${IMAGE_BASENAME}-${MACHINE}-${DATETIME}"
 298 IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
 299 IMAGE_EXTRA_SPACE = 10240
 300
 301 IMAGE_CMD = ""
 302 IMAGE_CMD_jffs2 = "mkfs.jffs2 -x lzo --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
 303 IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
 304 IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
 305 IMAGE_CMD_ext2 = "genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
 306 IMAGE_CMD_ext2.gz = "rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz; genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz; rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz"
 307 IMAGE_CMD_ext3 = "genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
 308 IMAGE_CMD_ext3.gz = "rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz; genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz; rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz"
 309 IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
 310 IMAGE_CMD_squashfs-lzma = "mksquashfs-lzma ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend"
 311 IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
 312 IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
 313 IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
 314 IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio)"
 315 IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz)"
 316 IMAGE_CMD_ubifs = "mkfs.ubifs -r ${IMAGE_ROOTFS} -o ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.ubifs.img"
 317
 318 EXTRA_IMAGECMD = ""
 319 EXTRA_IMAGECMD_jffs2 = ""
 320 EXTRA_IMAGECMD_yaffs2 = "1"
 321 EXTRA_IMAGECMD_squashfs = ""
 322 EXTRA_IMAGECMD_squashfs-lzma = ""
 323 EXTRA_IMAGECMD_ubifs = ""
 324
 325 IMAGE_DEPENDS = ""
 326 IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
 327 IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
 328 IMAGE_DEPENDS_cramfs = "cramfs-native"
 329 IMAGE_DEPENDS_ext2 = "genext2fs-native"
 330 IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
 331 IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
 332 IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
 333 IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
 334 IMAGE_DEPENDS_squashfs-lzma = "squashfs-lzma-tools-native"
 335 IMAGE_DEPENDS_ubifs = "mtd-utils-native"
 336
 337 EXTRA_IMAGEDEPENDS = ""
 338
 339 ##################################################################
 340 # Toolchain info.
 341 ##################################################################
 342
 343 CROSS_DIR = "${TMPDIR}/cross/${BASE_PACKAGE_ARCH}"
 344 CROSS_DATADIR = "${CROSS_DIR}/share"
 345 PATH_prepend = "${STAGING_BINDIR_CROSS}:${STAGING_BINDIR_CROSS_BASEPKG}:${STAGING_DIR_NATIVE}${layout_sbindir}:${STAGING_BINDIR_NATIVE}:${CROSS_DIR}/bin:${STAGING_DIR_NATIVE}${layout_base_sbindir}:${STAGING_DIR_NATIVE}${layout_base_bindir}:"
 346 export PATH
 347
 348 ##################################################################
 349 # Build utility info.
 350 ##################################################################
 351
 352 CCACHE = "${@bb.which(bb.data.getVar('PATH', d, 1), 'ccache') and 'ccache '}"
 353 TOOLCHAIN_OPTIONS = ""
 354
 355 export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 356 export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 357 export F77 = "${CCACHE}${HOST_PREFIX}g77 ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 358 export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS}"
 359 export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS}"
 360 export CCLD = "${CC}"
 361 export AR = "${HOST_PREFIX}ar"
 362 export AS = "${HOST_PREFIX}as"
 363 export RANLIB = "${HOST_PREFIX}ranlib"
 364 export STRIP = "${HOST_PREFIX}strip"
 365 export OBJCOPY = "${HOST_PREFIX}objcopy"
 366 export OBJDUMP = "${HOST_PREFIX}objdump"
 367 PYTHON = "${@sys.executable}"
 368
 369 export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
 370 export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
 371 export BUILD_F77 = "${CCACHE}${BUILD_PREFIX}g77 ${BUILD_CC_ARCH}"
 372 export BUILD_CPP = "${BUILD_PREFIX}cpp"
 373 export BUILD_LD = "${BUILD_PREFIX}ld"
 374 export BUILD_CCLD = "${BUILD_PREFIX}gcc"
 375 export BUILD_AR = "${BUILD_PREFIX}ar"
 376 export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
 377 export BUILD_STRIP = "${BUILD_PREFIX}strip"
 378
 379 export MAKE = "make"
 380 EXTRA_OEMAKE = "-e MAKEFLAGS="
 381
 382 ##################################################################
 383 # Patch handling.
 384 ##################################################################
 385 PATCHTOOL = 'quilt'
 386 PATCHRESOLVE = 'noop'
 387
 388 ##################################################################
 389 # Build flags and options.
 390 ##################################################################
 391
 392 export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
 393 export CPPFLAGS = "${TARGET_CPPFLAGS}"
 394 export TARGET_CPPFLAGS = "-isystem${STAGING_DIR_TARGET}${layout_includedir}"
 395
 396 export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
 397 export CFLAGS = "${TARGET_CFLAGS}"
 398 export TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 399
 400 export BUILD_CXXFLAGS = "${BUILD_CFLAGS} -fpermissive"
 401 export CXXFLAGS = "${TARGET_CXXFLAGS}"
 402 export TARGET_CXXFLAGS = "${TARGET_CFLAGS} -fpermissive"
 403
 404 export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
 405                         -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
 406                         -Wl,-rpath,${STAGING_LIBDIR_NATIVE} -Wl,-O1"
 407
 408 export LDFLAGS = "${TARGET_LDFLAGS}"
 409 export TARGET_LDFLAGS = "-L${STAGING_DIR_TARGET}${layout_libdir} \
 410                          -Wl,-rpath-link,${STAGING_DIR_TARGET}${layout_libdir} \
 411                          -Wl,-O1 \
 412                          ${TARGET_LINK_HASH_STYLE}"
 413
 414 # Which flags to leave by strip-flags() in bin/build/oebuild.sh ?
 415 ALLOWED_FLAGS = "-O -mcpu -march -pipe"
 416
 417 # Pass parallel make options to the compile task only
 418 EXTRA_OEMAKE_prepend_task_do_compile = "${PARALLEL_MAKE} "
 419 EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
 420
 421 ##################################################################
 422 # Optimization flags.
 423 ##################################################################
 424
 425 FULL_OPTIMIZATION = "-fexpensive-optimizations -fomit-frame-pointer -frename-registers -O2"
 426 DEBUG_OPTIMIZATION = "-O -fno-omit-frame-pointer -g"
 427 SELECTED_OPTIMIZATION = "${@bb.data.getVar(['FULL_OPTIMIZATION', 'DEBUG_OPTIMIZATION'][bb.data.getVar('DEBUG_BUILD', d, 1) == '1'], d, 1)}"
 428 BUILD_OPTIMIZATION = "-O2"
 429
 430 ##################################################################
 431 # Bootstrap stuff.
 432 ##################################################################
 433
 434 BOOTSTRAP_EXTRA_RDEPENDS = ""
 435 BOOTSTRAP_EXTRA_RRECOMMENDS = ""
 436
 437 ##################################################################
 438 # Palmtop stuff.
 439 ##################################################################
 440
 441 export QTDIR = "${STAGING_DIR_HOST}/qt2"
 442 export QPEDIR = "${STAGING_DIR_HOST}"
 443 export OPIEDIR = "${STAGING_DIR_HOST}"
 444 export palmtopdir = "${libdir}/opie"
 445 export palmqtdir = "${palmtopdir}"
 446
 447 ##################################################################
 448 # Download locations and utilities.
 449 ##################################################################
 450
 451 GNU_MIRROR = "ftp://ftp.gnu.org/gnu"
 452 DEBIAN_MIRROR = "ftp://ftp.debian.org/debian/pool"
 453 SOURCEFORGE_MIRROR = "http://downloads.sourceforge.net"
 454 GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
 455 GPEPHONE_MIRROR = "http://gpephone.linuxtogo.org/download/gpephone"
 456 GPE_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/base;module=${PN}"
 457 GPE_EXTRA_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/extra;module=${PN}"
 458 GPEPHONE_SVN = "svn://projects.linuxtogo.org/svn/gpephone/trunk/source;module=${PN}"
 459 XLIBS_MIRROR = "http://xlibs.freedesktop.org/release"
 460 XORG_MIRROR = "http://xorg.freedesktop.org/releases"
 461 GNOME_MIRROR = "http://ftp.gnome.org/pub/GNOME/sources"
 462 FREEBSD_MIRROR = "ftp://ftp.freebsd.org/pub/FreeBSD/"
 463 HANDHELDS_CVS = "cvs://anoncvs:anoncvs@anoncvs.handhelds.org/cvs"
 464 E_CVS = "cvs://anonymous@anoncvs.enlightenment.org/var/cvs/e"
 465 E_URI = "http://enlightenment.freedesktop.org/files"
 466 FREEDESKTOP_CVS = "cvs://anoncvs:anoncvs@anoncvs.freedesktop.org/cvs"
 467 FREESMARTPHONE_GIT = "git://git.freesmartphone.org"
 468 GENTOO_MIRROR = "http://distro.ibiblio.org/pub/linux/distributions/gentoo/distfiles"
 469 APACHE_MIRROR = "http://www.apache.org/dist"
 470 KERNELORG_MIRROR = "http://kernel.org"
 471
 472 # You can use the mirror of your country to get faster downloads by putting
 473 #  export DEBIAN_MIRROR = "ftp://ftp.de.debian.org/debian/pool"
 474 #     into your local.conf
 475
 476 FETCHCMD_svn = "/usr/bin/env svn"
 477 FETCHCMD_cvs = "/usr/bin/env cvs"
 478 FETCHCMD_wget = "/usr/bin/env wget -t 5"
 479 FETCHCMD_bzr = "/usr/bin/env bzr"
 480 FETCHCMD_hg = "/usr/bin/env hg"
 481
 482 FETCHCOMMAND = "ERROR, this must be a BitBake bug"
 483 FETCHCOMMAND_wget = "/usr/bin/env wget -t 5 --passive-ftp -P ${DL_DIR} ${URI}"
 484 FETCHCOMMAND_cvs = "/usr/bin/env cvs '-d${CVSROOT}' co ${CVSCOOPTS} ${CVSMODULE}"
 485 FETCHCOMMAND_svn = "/usr/bin/env svn co ${SVNCOOPTS} ${SVNROOT} ${SVNMODULE}"
 486 RESUMECOMMAND = "ERROR, this must be a BitBake bug"
 487 RESUMECOMMAND_wget = "/usr/bin/env wget -c -t 5 --passive-ftp -P ${DL_DIR} ${URI}"
 488 UPDATECOMMAND = "ERROR, this must be a BitBake bug"
 489 UPDATECOMMAND_cvs = "/usr/bin/env cvs -d${CVSROOT} update -d -P ${CVSCOOPTS}"
 490 UPDATECOMMAND_svn = "/usr/bin/env svn update ${SVNCOOPTS}"
 491 SRCDATE = "${DATE}"
 492 SRCREV = "1"
 493 AUTOREV = "${@bb.fetch.get_srcrev(d)}"
 494
 495 SRC_URI = "file://${FILE}"
 496
 497 ##################################################################
 498 # UI/Interaction Configuration
 499 ##################################################################
 500
 501 SHELLRCCMD = "bash --rcfile $TERMRCFILE"
 502 export SHELLCMDS = "${SHELLRCCMD}"
 503 # Some common terminal programs to choose from
 504 GNOME_TERMCMD = 'gnome-terminal --disable-factory -t "$TERMWINDOWTITLE"'
 505 GNOME_TERMCMDRUN = '${GNOME_TERMCMD} -x $SHELLCMDS'
 506 SCREEN_TERMCMD = 'screen -D -m -t "$TERMWINDOWTITLE"'
 507 SCREEN_TERMCMDRUN = '${SCREEN_TERMCMD} $SHELLCMDS'
 508 XTERM_TERMCMD = 'xterm -T "$TERMWINDOWTITLE"'
 509 XTERM_TERMCMDRUN = '${XTERM_TERMCMD} -e $SHELLCMDS'
 510 KONSOLE_TERMCMD = 'konsole -T "$TERMWINDOWTITLE"'
 511 KONSOLE_TERMCMDRUN = '${KONSOLE_TERMCMD} -e $SHELLCMDS'
 512
 513 # Set a default
 514 TERMCMD ?= "${GNOME_TERMCMD}"
 515 TERMCMDRUN ?= "${GNOME_TERMCMDRUN}"
 516
 517 ##################################################################
 518 # Miscellaneous utilities.
 519 ##################################################################
 520
 521 MKTEMPDIRCMD = "mktemp -d -q ${TMPBASE}"
 522 MKTEMPCMD = "mktemp -q ${TMPBASE}"
 523
 524 # GNU patch tries to be intellgent about checking out read-only files from
 525 # a RCS, which freaks out those special folks with active Perforce clients
 526 # the following makes patch ignore RCS:
 527
 528 export PATCH_GET="0"
 529
 530 # Program to be used to build ipkg packages
 531
 532 IPKGBUILDCMD = "ipkg-build -o 0 -g 0"
 533
 534 ##################################################################
 535 # Not sure about the rest of this yet.
 536 ##################################################################
 537
 538 # slot - currently unused by OE. portage remnants
 539 SLOT = "0"
 540
 541 # Other
 542
 543 export PKG_CONFIG_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}${layout_libdir}/pkgconfig"
 544 export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
 545 export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 546 export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
 547
 548 export QMAKE_MKSPEC_PATH = "${STAGING_DATADIR_NATIVE}/qmake"
 549 export STAGING_SIPDIR = "${STAGING_DATADIR_NATIVE}/sip"
 550 export STAGING_IDLDIR = "${STAGING_DATADIR}/idl"
 551
 552 # library package naming
 553 AUTO_LIBNAME_PKGS = "${PACKAGES}"
 554
 555 # Globally toggle certain dependencies
 556 ENTERPRISE_DISTRO ?= "0"
 557
 558 ###
 559 ### Config file processing
 560 ###
 561
 562 # This means that an envionment variable named '<foo>_arm' overrides an
 563 # environment variable '<foo>' (when ${TARGET_ARCH} is arm). And the same: an
 564 # environment variable '<foo>_ramses' overrides both '<foo>' and '<foo>_arm
 565 # when ${MACHINE} is 'ramses'. And finally '<foo>_local' overrides anything.
 566 #
 567 # This works for  functions as well, they are really just environment variables.
 568 # Default OVERRIDES to make compilation fail fast in case of build system misconfiguration.
 569 OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:fail-fast:pn-${PN}"
 570 # Alternative OVERRIDES definition without "fail fast", usually only for native building and Scratchbox toolchains.
 571 #OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:pn-${PN}"
 572
 573 ##################################################################
 574 # Include the rest of the config files.
 575 ##################################################################
 576
 577 include conf/site.conf
 578 include conf/auto.conf
 579 include conf/local.conf
 580 # USERDISTRO should always contain original DISTRO value as set by user
 581 # If a distro config overrides DISTRO for whatever reason (e.g. to get
 582 # overrides like it wants), USERDISTRO must be reassigned with := first
 583 USERDISTRO = "${DISTRO}"
 584 include conf/build/${BUILD_SYS}.conf
 585 include conf/target/${TARGET_SYS}.conf
 586 include conf/machine/${MACHINE}.conf
 587 include conf/distro/${DISTRO}.conf
 588 include conf/documentation.conf
 589 require conf/sanity.conf
 590 require conf/abi_version.conf
 591 require conf/enterprise.conf
 592
 593 ##################################################################
 594 # Weak variables (usually to retain backwards compatibility)
 595 ##################################################################
 596
 597 DL_DIR ?= "${TMPDIR}/downloads"
 598 IMAGE_FSTYPES ?= "tar.gz"
 599 PCMCIA_MANAGER ?= "pcmcia-cs"
 600 DEFAULT_TASK_PROVIDER ?= "task-base"
 601 MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
 602 IMAGE_ROOTFS_SIZE_ext2 ?= "65536"
 603 IMAGE_ROOTFS_SIZE_ext2.gz ?= "65536"
 604 IMAGE_ROOTFS_SIZE_ext3 ?= "65536"
 605 IMAGE_ROOTFS_SIZE_ext3.gz ?= "65536"
 606 DISTRO_PR ?= ""
 607
 608 # Forcefully set CACHE now so future changes to things like
 609 # MACHINE don't change the path to the cache
 610 CACHE := "${CACHE}"
 611
 612 # Default to disabling packaged staging code
 613 export PSTAGING_ACTIVE = "0"
 614
 615 ##################################################################
 616 # Magic Cookie for SANITY CHECK
 617 ##################################################################
 618 OES_BITBAKE_CONF = "1"
 619
 620 ##################################################################
 621 # Machine properties and task-base stuff
 622 ##################################################################
 623
 624 MACHINE_FEATURES ?= "kernel26"
 625 DISTRO_FEATURES ?= ""
 626
 627 # This is used to limit what packages goes into images built, so set big by default
 628 ROOT_FLASH_SIZE ?= "256"
 629
 630 MACHINE_GUI_CLASS ?= "smallscreen"
 631 # GUI_MACHINE_CLASS is deprecated, please use MACHINE_GUI_CLASS instead
 632 GUI_MACHINE_CLASS ?= "${MACHINE_GUI_CLASS}"
 633 MACHINE_DISPLAY_WIDTH_PIXELS ?= "240"
 634 MACHINE_DISPLAY_HEIGHT_PIXELS ?= "320"
 635 MACHINE_DISPLAY_ORIENTATION ?= "0"
 636 MACHINE_DISPLAY_BPP ?= "16"
 637
 638 DISTRO_EXTRA_RDEPENDS ?= ""
 639 DISTRO_EXTRA_RRECOMMENDS ?= ""
 640 MACHINE_EXTRA_RDEPENDS ?= ""
 641 MACHINE_EXTRA_RRECOMMENDS ?= ""
 642 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
 643 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
 644
 645 COMBINED_FEATURES = "\
 646     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "alsa", d)} \
 647     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "bluetooth", d)} \
 648     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "ext2", d)} \
 649     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "vfat", d)} \
 650     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "irda", d)} \
 651     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pcmcia", d)} \
 652     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pci", d)} \
 653     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbgadget", d)} \
 654     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbhost", d)} \
 655     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "wifi", d)}"