code.vuplus.com Git - vuplus_openembedded/blob - conf/bitbake.conf

   1 ##################################################################
   2 # Standard target filesystem layout.
   3 ##################################################################
   4
   5 # Path prefixes
   6 layout_prefix = "/usr"
   7 layout_exec_prefix = "/usr"
   8 layout_base_prefix = ""
   9
  10 # Base paths
  11 layout_base_bindir = "${layout_base_prefix}/bin"
  12 layout_base_sbindir = "${layout_base_prefix}/sbin"
  13 layout_base_libdir = "${layout_base_prefix}/lib"
  14
  15 # Architecture independent paths
  16 layout_sysconfdir = "${layout_base_prefix}/etc"
  17 layout_localstatedir = "${layout_base_prefix}/var"
  18 layout_servicedir = "${layout_base_prefix}/srv"
  19 layout_sharedstatedir = "${layout_prefix}/com"
  20 layout_datadir = "${layout_prefix}/share"
  21 layout_infodir = "${layout_datadir}/info"
  22 layout_mandir = "${layout_datadir}/man"
  23 layout_docdir = "${layout_datadir}/doc"
  24
  25 # Architecture dependent paths
  26 layout_bindir = "${layout_exec_prefix}/bin"
  27 layout_sbindir = "${layout_exec_prefix}/sbin"
  28 layout_libdir = "${layout_exec_prefix}/lib"
  29 layout_includedir = "${layout_exec_prefix}/include"
  30 layout_libexecdir = "${layout_exec_prefix}/libexec"
  31
  32 ##################################################################
  33 # Standard target filesystem paths.
  34 ##################################################################
  35
  36 # Path prefixes
  37 export base_prefix = ""
  38 export prefix = "${layout_prefix}"
  39 export exec_prefix = "${layout_exec_prefix}"
  40
  41 # Base paths
  42 export base_bindir = "${layout_base_bindir}"
  43 export base_sbindir = "${layout_base_sbindir}"
  44 export base_libdir = "${layout_base_libdir}"
  45
  46 # Architecture independent paths
  47 export datadir = "${layout_datadir}"
  48 export sysconfdir = "${layout_sysconfdir}"
  49 export sharedstatedir = "${layout_sharedstatedir}"
  50 export localstatedir = "${layout_localstatedir}"
  51 export infodir = "${layout_infodir}"
  52 export mandir = "${layout_mandir}"
  53 export docdir = "${layout_docdir}"
  54 export servicedir = "${layout_servicedir}"
  55
  56 # Architecture dependent paths
  57 export bindir = "${layout_bindir}"
  58 export sbindir = "${layout_sbindir}"
  59 export libexecdir = "${layout_libexecdir}"
  60 export libdir = "${layout_libdir}"
  61 export includedir = "${layout_includedir}"
  62 export oldincludedir = "${layout_includedir}"
  63
  64 ##################################################################
  65 # Architecture-dependent build variables.
  66 ##################################################################
  67
  68 BUILD_ARCH = "${@os.uname()[4]}"
  69 BUILD_OS = "${@os.uname()[0].lower()}"
  70 BUILD_VENDOR = ""
  71 BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
  72 BUILD_PREFIX = ""
  73 BUILD_CC_ARCH = ""
  74
  75 HOST_ARCH = "${TARGET_ARCH}"
  76 HOST_OS = "${TARGET_OS}"
  77 HOST_VENDOR = "${TARGET_VENDOR}"
  78 HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
  79 HOST_PREFIX = "${TARGET_PREFIX}"
  80 HOST_CC_ARCH = "${TARGET_CC_ARCH}"
  81
  82 TARGET_ARCH ?= "INVALID"
  83 TARGET_OS = "INVALID"
  84 TARGET_VENDOR = "${BUILD_VENDOR}"
  85 TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}${@['-' + bb.data.getVar('TARGET_OS', d, 1), ''][bb.data.getVar('TARGET_OS', d, 1) == ('' or 'custom')]}"
  86 TARGET_PREFIX = "${TARGET_SYS}-"
  87 TARGET_CC_ARCH = ""
  88
  89 BASE_PACKAGE_ARCH = "${HOST_ARCH}"
  90 PACKAGE_ARCH = "${BASE_PACKAGE_ARCH}"
  91 MACHINE_ARCH = "${@[bb.data.getVar('HOST_ARCH', d, 1), bb.data.getVar('MACHINE', d, 1)][bool(bb.data.getVar('MACHINE', d, 1))]}"
  92 PACKAGE_ARCHS = "all any noarch ${TARGET_ARCH} ${PACKAGE_EXTRA_ARCHS} ${MACHINE}"
  93
  94 MULTIMACH_ARCH = "${PACKAGE_ARCH}"
  95 MULTIMACH_TARGET_SYS = "${MULTIMACH_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
  96 MULTIMACH_HOST_SYS = "${MULTIMACH_ARCH}${HOST_VENDOR}-${HOST_OS}"
  97
  98 # select proper CPU to get binary locales generated
  99 QEMU_OPTIONS = ""
 100 QEMU_OPTIONS_iwmmxt  = "-cpu pxa270-c5"
 101 QEMU_OPTIONS_armv6   = "-cpu arm1136"
 102
 103 ##################################################################
 104 # Date/time variables.
 105 ##################################################################
 106
 107 DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
 108 TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
 109 DATETIME = "${DATE}${TIME}"
 110
 111 ##################################################################
 112 # Openembedded Software Prerequisites.
 113 ##################################################################
 114
 115 # python-native should be here but python relies on building
 116 # its own in staging
 117 ASSUME_PROVIDED = "\
 118     bc-native \
 119     bzip2-native \
 120     cvs-native \
 121     diffstat-native \
 122     patch-native \
 123     perl-native-runtime \
 124     python-native-runtime \
 125     svn-native \
 126     texinfo-native \
 127     util-linux-native \
 128     "
 129
 130 ##################################################################
 131 # Package default variables.
 132 ##################################################################
 133
 134 PN = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[0] or 'defaultpkgname'}"
 135 PV = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[1] or '1.0'}"
 136 PR = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[2] or 'r0'}"
 137 PF = "${PN}-${EXTENDPE}${PV}-${PR}"
 138 EXTENDPE = "${@['','${PE\x7d_'][bb.data.getVar('PE',d,1) > 0]}"
 139 EXTENDPEVER = "${@['','${PE\x7d:'][bb.data.getVar('PE',d,1) > 0]}"
 140 DEBPV = "${EXTENDPEVER}${PV}-${PR}"
 141 P = "${PN}-${PV}"
 142
 143 # Package info.
 144
 145 SECTION = "base"
 146 PRIORITY = "optional"
 147 DESCRIPTION = "Version ${PV}-${PR} of package ${PN}"
 148 LICENSE = "unknown"
 149 MAINTAINER = "OpenEmbedded Team <openembedded-devel@lists.openembedded.org>"
 150 HOMEPAGE = "unknown"
 151
 152 # Package dependencies and provides.
 153
 154 # Ensure that -dev packages recommend the corresponding -dev packages of their
 155 # deps, and the same for -dbg.
 156 DEPCHAIN_PRE  = ""
 157 DEPCHAIN_POST = "-dev -dbg"
 158
 159 DEPENDS = ""
 160 RDEPENDS = ""
 161 PROVIDES = ""
 162 PROVIDES_prepend = "${P} ${PF} ${PN} "
 163 RPROVIDES = ""
 164
 165 MULTI_PROVIDER_WHITELIST = "virtual/libintl"
 166
 167 PACKAGES = "${PN}-dbg ${PN} ${PN}-doc ${PN}-dev ${PN}-locale"
 168 #enable this when bitbake is upgraded to cope with ++ values in the field
 169 #PACKAGES_DYNAMIC = "${PN}-locale-*"
 170 FILES = ""
 171
 172 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*.so.* \
 173             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
 174             ${base_bindir}/* ${base_sbindir}/* ${base_libdir}/*.so* ${datadir}/${PN} ${libdir}/${PN}/* \
 175             ${datadir}/pixmaps ${datadir}/applications \
 176             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
 177             ${libdir}/bonobo/servers"
 178
 179 FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
 180             ${datadir}/gnome/help"
 181 SECTION_${PN}-doc = "doc"
 182
 183 FILES_${PN}-dev = "${includedir} ${libdir}/lib*.so ${libdir}/*.la \
 184                 ${libdir}/*.a ${libdir}/*.o ${libdir}/pkgconfig \
 185                 ${base_libdir}/*.a ${base_libdir}/*.o ${datadir}/aclocal"
 186 SECTION_${PN}-dev = "devel"
 187 ALLOW_EMPTY_${PN}-dev = "1"
 188 RDEPENDS_${PN}-dev = "${PN} (= ${DEBPV})"
 189
 190 FILES_${PN}-dbg = "${bindir}/.debug ${sbindir}/.debug ${libexecdir}/.debug ${libdir}/.debug \
 191             ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug ${libdir}/${PN}/.debug \
 192             ${libdir}/matchbox-panel/.debug"
 193 SECTION_${PN}-dbg = "devel"
 194 ALLOW_EMPTY_${PN}-dbg = "1"
 195 RRECOMMENDS_${PN}-dbg = "${PN} (= ${DEBPV})"
 196
 197 FILES_${PN}-locale = "${datadir}/locale"
 198
 199 # File manifest
 200
 201 export MANIFEST = "${FILESDIR}/manifest"
 202
 203 FILE_DIRNAME = "${@os.path.dirname(bb.data.getVar('FILE', d))}"
 204 FILESPATH = "${FILE_DIRNAME}/${PF}:${FILE_DIRNAME}/${P}:${FILE_DIRNAME}/${PN}:${FILE_DIRNAME}/files:${FILE_DIRNAME}"
 205 FILESDIR = "${@bb.which(bb.data.getVar('FILESPATH', d, 1), '.')}"
 206
 207 ##################################################################
 208 # General work and output directories for the build system.
 209 ##################################################################
 210
 211 TMPDIR = "${TOPDIR}/tmp"
 212 CACHE = "${TMPDIR}/cache${@['', '/' + str(bb.data.getVar('MACHINE', d, 1))][bool(bb.data.getVar('MACHINE', d, 1))]}"
 213 CO_DIR = "${DL_DIR}"
 214 CVSDIR = "${CO_DIR}/cvs"
 215 SVNDIR = "${CO_DIR}/svn"
 216 GITDIR = "${CO_DIR}/git"
 217 BZRDIR = "${CO_DIR}/bzr"
 218
 219 STAMP = "${TMPDIR}/stamps/${MULTIMACH_TARGET_SYS}/${PF}"
 220 WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PF}"
 221 T = "${WORKDIR}/temp"
 222 D = "${WORKDIR}/image"
 223 S = "${WORKDIR}/${P}"
 224 B = "${S}"
 225
 226 STAGING_DIR = "${TMPDIR}/staging"
 227
 228 STAGING_DIR_NATIVE = "${STAGING_DIR}/${BUILD_SYS}"
 229 STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_bindir}"
 230 STAGING_BINDIR_CROSS  = "${STAGING_DIR_NATIVE}${layout_bindir}/${HOST_SYS}"
 231 STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_libdir}"
 232 STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_includedir}"
 233 STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_sysconfdir}"
 234 STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_datadir}"
 235
 236 STAGING_DIR_HOST = "${STAGING_DIR}/${HOST_SYS}"
 237 STAGING_BINDIR = "${STAGING_DIR_HOST}${layout_bindir}"
 238 STAGING_LIBDIR = "${STAGING_DIR_HOST}${layout_libdir}"
 239 STAGING_INCDIR = "${STAGING_DIR_HOST}${layout_includedir}"
 240 STAGING_DATADIR = "${STAGING_DIR_HOST}${layout_datadir}"
 241 STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${layout_exec_prefix}"
 242 STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
 243 STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
 244 STAGING_PYDIR = "${STAGING_DIR}/lib/python2.4"
 245
 246 STAGING_DIR_TARGET = "${STAGING_DIR}/${TARGET_SYS}"
 247
 248 DEPLOY_DIR = "${TMPDIR}/deploy"
 249 DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
 250 DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
 251 DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
 252 DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
 253 DEPLOY_DIR_IMAGE = "${DEPLOY_DIR}/images"
 254 DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
 255
 256 PKGDATA_DIR = "${STAGING_DIR}/pkgdata/${MULTIMACH_TARGET_SYS}"
 257
 258 SDK_NAME = "${DISTRO}/${TARGET_ARCH}"
 259 SDK_PREFIX = "/usr/local/${SDK_NAME}"
 260
 261 ##################################################################
 262 # Kernel info.
 263 ##################################################################
 264
 265 OLDEST_KERNEL = "2.4.0"
 266 STAGING_KERNEL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/kernel"
 267
 268 ##################################################################
 269 # Specific image creation and rootfs population info.
 270 ##################################################################
 271
 272 IMAGE_ROOTFS = "${TMPDIR}/rootfs"
 273 IMAGE_BASENAME = "${PN}"
 274 IMAGE_NAME = "${IMAGE_BASENAME}-${MACHINE}-${DATETIME}"
 275 IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
 276
 277 IMAGE_CMD = ""
 278 IMAGE_CMD_jffs2 = "mkfs.jffs2 -x lzo --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
 279 IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
 280 IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
 281 IMAGE_CMD_ext2 = "genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
 282 IMAGE_CMD_ext2.gz = "rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz; genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz; rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz"
 283 IMAGE_CMD_ext3 = "genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
 284 IMAGE_CMD_ext3.gz = "rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz; genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz; rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz"
 285 IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
 286 IMAGE_CMD_squashfs-lzma = "mksquashfs-lzma ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend"
 287 IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
 288 IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
 289 IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
 290 IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio)"
 291 IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz)"
 292
 293 EXTRA_IMAGECMD = ""
 294 EXTRA_IMAGECMD_jffs2 = ""
 295 EXTRA_IMAGECMD_yaffs2 = "1"
 296 EXTRA_IMAGECMD_squashfs = ""
 297 EXTRA_IMAGECMD_squashfs-lzma = ""
 298
 299 IMAGE_DEPENDS = ""
 300 IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
 301 IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
 302 IMAGE_DEPENDS_cramfs = "cramfs-native"
 303 IMAGE_DEPENDS_ext2 = "genext2fs-native"
 304 IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
 305 IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
 306 IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
 307 IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
 308 IMAGE_DEPENDS_squashfs-lzma = "squashfs-lzma-tools-native"
 309
 310 EXTRA_IMAGEDEPENDS = ""
 311
 312 ##################################################################
 313 # Toolchain info.
 314 ##################################################################
 315
 316 CROSS_DIR = "${TMPDIR}/cross"
 317 CROSS_DATADIR = "${CROSS_DIR}/share"
 318 PATH_prepend = "${STAGING_BINDIR_CROSS}:${STAGING_DIR_NATIVE}${layout_sbindir}:${STAGING_BINDIR_NATIVE}:${CROSS_DIR}/bin:${STAGING_DIR_NATIVE}${layout_base_sbindir}:"
 319 export PATH
 320
 321 ##################################################################
 322 # Build utility info.
 323 ##################################################################
 324
 325 CCACHE = "${@bb.which(bb.data.getVar('PATH', d, 1), 'ccache') and 'ccache '}"
 326 TOOLCHAIN_OPTIONS = ""
 327
 328 export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 329 export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 330 export F77 = "${CCACHE}${HOST_PREFIX}g77 ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 331 export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS}"
 332 export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS}"
 333 export CCLD = "${CC}"
 334 export AR = "${HOST_PREFIX}ar"
 335 export AS = "${HOST_PREFIX}as"
 336 export RANLIB = "${HOST_PREFIX}ranlib"
 337 export STRIP = "${HOST_PREFIX}strip"
 338 export OBJCOPY = "${HOST_PREFIX}objcopy"
 339 export OBJDUMP = "${HOST_PREFIX}objdump"
 340 PYTHON = "${@sys.executable}"
 341
 342 export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
 343 export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
 344 export BUILD_F77 = "${CCACHE}${BUILD_PREFIX}g77 ${BUILD_CC_ARCH}"
 345 export BUILD_CPP = "${BUILD_PREFIX}cpp"
 346 export BUILD_LD = "${BUILD_PREFIX}ld"
 347 export BUILD_CCLD = "${BUILD_PREFIX}gcc"
 348 export BUILD_AR = "${BUILD_PREFIX}ar"
 349 export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
 350 export BUILD_STRIP = "${BUILD_PREFIX}strip"
 351
 352 export MAKE = "make"
 353 EXTRA_OEMAKE = "-e MAKEFLAGS="
 354
 355 ##################################################################
 356 # Patch handling.
 357 ##################################################################
 358 PATCHTOOL = 'quilt'
 359 PATCHRESOLVE = 'noop'
 360
 361 ##################################################################
 362 # Build flags and options.
 363 ##################################################################
 364
 365 export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
 366 export CPPFLAGS = "${TARGET_CPPFLAGS}"
 367 export TARGET_CPPFLAGS = "-isystem${STAGING_DIR_TARGET}${layout_includedir}"
 368
 369 export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
 370 export CFLAGS = "${TARGET_CFLAGS}"
 371 export TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 372
 373 export BUILD_CXXFLAGS = "${BUILD_CFLAGS} -fpermissive"
 374 export CXXFLAGS = "${TARGET_CXXFLAGS}"
 375 export TARGET_CXXFLAGS = "${TARGET_CFLAGS} -fpermissive"
 376
 377 export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
 378                         -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
 379                         -Wl,-rpath,${STAGING_LIBDIR_NATIVE} -Wl,-O1"
 380
 381 export LDFLAGS = "${TARGET_LDFLAGS}"
 382 export TARGET_LDFLAGS = "-L${STAGING_DIR_TARGET}${layout_libdir} \
 383                          -Wl,-rpath-link,${STAGING_DIR_TARGET}${layout_libdir} \
 384                          -Wl,-O1"
 385
 386 # Which flags to leave by strip-flags() in bin/build/oebuild.sh ?
 387 ALLOWED_FLAGS = "-O -mcpu -march -pipe"
 388
 389 # Pass parallel make options to the compile task only
 390 EXTRA_OEMAKE_prepend_task_do_compile = "${PARALLEL_MAKE} "
 391 EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
 392
 393 ##################################################################
 394 # Optimization flags.
 395 ##################################################################
 396
 397 FULL_OPTIMIZATION = "-fexpensive-optimizations -fomit-frame-pointer -frename-registers -O2"
 398 DEBUG_OPTIMIZATION = "-O -g"
 399 SELECTED_OPTIMIZATION = "${@bb.data.getVar(['FULL_OPTIMIZATION', 'DEBUG_OPTIMIZATION'][bb.data.getVar('DEBUG_BUILD', d, 1) == '1'], d, 1)}"
 400 BUILD_OPTIMIZATION = "-O2"
 401
 402 ##################################################################
 403 # Bootstrap stuff.
 404 ##################################################################
 405
 406 BOOTSTRAP_EXTRA_RDEPENDS = ""
 407 BOOTSTRAP_EXTRA_RRECOMMENDS = ""
 408
 409 ##################################################################
 410 # Palmtop stuff.
 411 ##################################################################
 412
 413 export QTDIR = "${STAGING_DIR_HOST}/qt2"
 414 export QPEDIR = "${STAGING_DIR_HOST}"
 415 export OPIEDIR = "${STAGING_DIR_HOST}"
 416 export palmtopdir = "${libdir}/opie"
 417 export palmqtdir = "${palmtopdir}"
 418
 419 ##################################################################
 420 # Download locations and utilities.
 421 ##################################################################
 422
 423 GNU_MIRROR = "ftp://ftp.gnu.org/gnu"
 424 DEBIAN_MIRROR = "ftp://ftp.debian.org/debian/pool"
 425 SOURCEFORGE_MIRROR = "http://downloads.sourceforge.net"
 426 GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
 427 GPEPHONE_MIRROR = "http://gpephone.linuxtogo.org/download/gpephone"
 428 GPE_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/base;module=${PN}"
 429 GPE_EXTRA_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/extra;module=${PN}"
 430 GPEPHONE_SVN = "svn://projects.linuxtogo.org/svn/gpephone/trunk/source;module=${PN}"
 431 XLIBS_MIRROR = "http://xlibs.freedesktop.org/release"
 432 XORG_MIRROR = "http://xorg.freedesktop.org/releases"
 433 GNOME_MIRROR = "http://ftp.gnome.org/pub/GNOME/sources"
 434 FREEBSD_MIRROR = "ftp://ftp.freebsd.org/pub/FreeBSD/"
 435 HANDHELDS_CVS = "cvs://anoncvs:anoncvs@anoncvs.handhelds.org/cvs"
 436 E_CVS = "cvs://anonymous@anoncvs.enlightenment.org/var/cvs/e"
 437 E_URI = "http://enlightenment.freedesktop.org/files"
 438 FREEDESKTOP_CVS = "cvs://anoncvs:anoncvs@anoncvs.freedesktop.org/cvs"
 439 FREESMARTPHONE_GIT = "git://git.freesmartphone.org"
 440 GENTOO_MIRROR = "http://distro.ibiblio.org/pub/linux/distributions/gentoo/distfiles"
 441 APACHE_MIRROR = "http://www.apache.org/dist"
 442 KERNELORG_MIRROR = "http://kernel.org/"
 443
 444 # You can use the mirror of your country to get faster downloads by putting
 445 #  export DEBIAN_MIRROR = "ftp://ftp.de.debian.org/debian/pool"
 446 #     into your local.conf
 447
 448 FETCHCMD_svn = "/usr/bin/env svn"
 449 FETCHCMD_cvs = "/usr/bin/env cvs"
 450 FETCHCMD_wget = "/usr/bin/env wget -t 5"
 451 FETCHCMD_bzr = "/usr/bin/env bzr"
 452
 453 FETCHCOMMAND = "ERROR, this must be a BitBake bug"
 454 FETCHCOMMAND_wget = "/usr/bin/env wget -t 5 --passive-ftp -P ${DL_DIR} ${URI}"
 455 FETCHCOMMAND_cvs = "/usr/bin/env cvs -d${CVSROOT} co ${CVSCOOPTS} ${CVSMODULE}"
 456 FETCHCOMMAND_svn = "/usr/bin/env svn co ${SVNCOOPTS} ${SVNROOT} ${SVNMODULE}"
 457 RESUMECOMMAND = "ERROR, this must be a BitBake bug"
 458 RESUMECOMMAND_wget = "/usr/bin/env wget -c -t 5 --passive-ftp -P ${DL_DIR} ${URI}"
 459 UPDATECOMMAND = "ERROR, this must be a BitBake bug"
 460 UPDATECOMMAND_cvs = "/usr/bin/env cvs -d${CVSROOT} update -d -P ${CVSCOOPTS}"
 461 UPDATECOMMAND_svn = "/usr/bin/env svn update ${SVNCOOPTS}"
 462 SRCDATE = "${DATE}"
 463 SRCREV = "1"
 464 AUTOREV = "${@bb.fetch.get_srcrev(d)}"
 465
 466 SRC_URI = "file://${FILE}"
 467
 468 ##################################################################
 469 # UI/Interaction Configuration
 470 ##################################################################
 471
 472 SHELLRCCMD = "bash --rcfile $TERMRCFILE"
 473 export SHELLCMDS = "${SHELLRCCMD}"
 474 # Some common terminal programs to choose from
 475 GNOME_TERMCMD = 'gnome-terminal --disable-factory -t "$TERMWINDOWTITLE"'
 476 GNOME_TERMCMDRUN = '${GNOME_TERMCMD} -x $SHELLCMDS'
 477 SCREEN_TERMCMD = 'screen -D -m -t "$TERMWINDOWTITLE"'
 478 SCREEN_TERMCMDRUN = '${SCREEN_TERMCMD} $SHELLCMDS'
 479 XTERM_TERMCMD = 'xterm -T "$TERMWINDOWTITLE"'
 480 XTERM_TERMCMDRUN = '${XTERM_TERMCMD} -e $SHELLCMDS'
 481 KONSOLE_TERMCMD = 'konsole -T "$TERMWINDOWTITLE"'
 482 KONSOLE_TERMCMDRUN = '${KONSOLE_TERMCMD} -e $SHELLCMDS'
 483
 484 # Set a default
 485 TERMCMD ?= "${GNOME_TERMCMD}"
 486 TERMCMDRUN ?= "${GNOME_TERMCMDRUN}"
 487
 488 ##################################################################
 489 # Miscellaneous utilities.
 490 ##################################################################
 491
 492 MKTEMPDIRCMD = "mktemp -d -q ${TMPBASE}"
 493 MKTEMPCMD = "mktemp -q ${TMPBASE}"
 494
 495 # GNU patch tries to be intellgent about checking out read-only files from
 496 # a RCS, which freaks out those special folks with active Perforce clients
 497 # the following makes patch ignore RCS:
 498
 499 export PATCH_GET="0"
 500
 501 # Program to be used to build ipkg packages
 502
 503 IPKGBUILDCMD = "ipkg-build -o 0 -g 0"
 504
 505 ##################################################################
 506 # Not sure about the rest of this yet.
 507 ##################################################################
 508
 509 # slot - currently unused by OE. portage remnants
 510 SLOT = "0"
 511
 512 # Other
 513
 514 export PKG_CONFIG_DIR = "${STAGING_LIBDIR}/pkgconfig"
 515 export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}"
 516 export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR}/${TARGET_SYS}"
 517 export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
 518
 519 export QMAKE_MKSPEC_PATH = "${STAGING_DATADIR_NATIVE}/qmake"
 520 export STAGING_SIPDIR = "${STAGING_DATADIR_NATIVE}/sip"
 521 export STAGING_IDLDIR = "${STAGING_DATADIR}/idl"
 522
 523 # library package naming
 524 AUTO_LIBNAME_PKGS = "${PACKAGES}"
 525
 526 ###
 527 ### Config file processing
 528 ###
 529
 530 # This means that an envionment variable named '<foo>_arm' overrides an
 531 # environment variable '<foo>' (when ${TARGET_ARCH} is arm). And the same: an
 532 # environment variable '<foo>_ramses' overrides both '<foo>' and '<foo>_arm
 533 # when ${MACHINE} is 'ramses'. And finally '<foo>_local' overrides anything.
 534 #
 535 # This works for  functions as well, they are really just environment variables.
 536 # Default OVERRIDES to make compilation fail fast in case of build system misconfiguration.
 537 OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:fail-fast:pn-${PN}"
 538 # Alternative OVERRIDES definition without "fail fast", usually only for native building and Scratchbox toolchains.
 539 #OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:pn-${PN}"
 540
 541 ##################################################################
 542 # Include the rest of the config files.
 543 ##################################################################
 544
 545 include conf/site.conf
 546 include conf/auto.conf
 547 include conf/local.conf
 548 # USERDISTRO should always contain original DISTRO value as set by user
 549 # If a distro config overrides DISTRO for whatever reason (e.g. to get
 550 # overrides like it wants), USERDISTRO must be reassigned with := first
 551 USERDISTRO = "${DISTRO}"
 552 include conf/build/${BUILD_SYS}.conf
 553 include conf/target/${TARGET_SYS}.conf
 554 include conf/machine/${MACHINE}.conf
 555 include conf/distro/${DISTRO}.conf
 556 include conf/documentation.conf
 557 require conf/sanity.conf
 558
 559 ##################################################################
 560 # Weak variables (usually to retain backwards compatibility)
 561 ##################################################################
 562
 563 DL_DIR ?= "${TMPDIR}/downloads"
 564 IMAGE_FSTYPES ?= "tar.gz"
 565 PCMCIA_MANAGER ?= "pcmcia-cs"
 566 DEFAULT_TASK_PROVIDER ?= "task-base"
 567 MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
 568 IMAGE_ROOTFS_SIZE_ext2 ?= "65536"
 569 IMAGE_ROOTFS_SIZE_ext2.gz ?= "65536"
 570 IMAGE_ROOTFS_SIZE_ext3 ?= "65536"
 571 IMAGE_ROOTFS_SIZE_ext3.gz ?= "65536"
 572
 573 # Forcefully set CACHE now so future changes to things like
 574 # MACHINE don't change the path to the cache
 575 CACHE := "${CACHE}"
 576
 577 # Default to disabling packaged staging code
 578 export PSTAGING_ACTIVE = "0"
 579
 580 ##################################################################
 581 # Magic Cookie for SANITY CHECK
 582 ##################################################################
 583 OES_BITBAKE_CONF = "1"
 584
 585 ##################################################################
 586 # Machine properties and task-base stuff
 587 ##################################################################
 588
 589 MACHINE_FEATURES ?= "kernel26"
 590 DISTRO_FEATURES ?= ""
 591
 592 # This is used to limit what packages goes into images built, so set big by default
 593 ROOT_FLASH_SIZE ?= "256"
 594
 595 MACHINE_GUI_CLASS ?= "smallscreen"
 596 # GUI_MACHINE_CLASS is deprecated, please use MACHINE_GUI_CLASS instead
 597 GUI_MACHINE_CLASS ?= "${MACHINE_GUI_CLASS}"
 598 MACHINE_DISPLAY_WIDTH_PIXELS ?= "240"
 599 MACHINE_DISPLAY_HEIGHT_PIXELS ?= "320"
 600 MACHINE_DISPLAY_ORIENTATION ?= "0"
 601 MACHINE_DISPLAY_BPP ?= "16"
 602
 603 DISTRO_EXTRA_RDEPENDS ?= ""
 604 DISTRO_EXTRA_RRECOMMENDS ?= ""
 605 MACHINE_EXTRA_RDEPENDS ?= ""
 606 MACHINE_EXTRA_RRECOMMENDS ?= ""
 607 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
 608 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
 609
 610 COMBINED_FEATURES = "\
 611     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "alsa", d)} \
 612     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "bluetooth", d)} \
 613     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "ext2", d)} \
 614     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "vfat", d)} \
 615     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "irda", d)} \
 616     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pcmcia", d)} \
 617     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pci", d)} \
 618     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbgadget", d)} \
 619     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbhost", d)} \
 620     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "wifi", d)}"
 621