code.vuplus.com Git - vuplus_openembedded/blob - conf/bitbake.conf

   1 ##################################################################
   2 # Standard target filesystem layout.
   3 ##################################################################
   4
   5 # Path prefixes
   6 layout_prefix = "/usr"
   7 layout_exec_prefix = "/usr"
   8 layout_base_prefix = ""
   9
  10 # Base paths
  11 layout_base_bindir = "${layout_base_prefix}/bin"
  12 layout_base_sbindir = "${layout_base_prefix}/sbin"
  13 layout_base_libdir = "${layout_base_prefix}/lib"
  14
  15 # Architecture independent paths
  16 layout_sysconfdir = "${layout_base_prefix}/etc"
  17 layout_localstatedir = "${layout_base_prefix}/var"
  18 layout_servicedir = "${layout_base_prefix}/srv"
  19 layout_sharedstatedir = "${layout_prefix}/com"
  20 layout_datadir = "${layout_prefix}/share"
  21 layout_infodir = "${layout_datadir}/info"
  22 layout_mandir = "${layout_datadir}/man"
  23 layout_docdir = "${layout_datadir}/doc"
  24
  25 # Architecture dependent paths
  26 layout_bindir = "${layout_exec_prefix}/bin"
  27 layout_sbindir = "${layout_exec_prefix}/sbin"
  28 layout_libdir = "${layout_exec_prefix}/lib"
  29 layout_includedir = "${layout_exec_prefix}/include"
  30 layout_libexecdir = "${layout_exec_prefix}/libexec"
  31
  32 ##################################################################
  33 # Standard target filesystem paths.
  34 ##################################################################
  35
  36 # Path prefixes
  37 export base_prefix = ""
  38 export prefix = "${layout_prefix}"
  39 export exec_prefix = "${layout_exec_prefix}"
  40
  41 # Base paths
  42 export base_bindir = "${layout_base_bindir}"
  43 export base_sbindir = "${layout_base_sbindir}"
  44 export base_libdir = "${layout_base_libdir}"
  45
  46 # Architecture independent paths
  47 export datadir = "${layout_datadir}"
  48 export sysconfdir = "${layout_sysconfdir}"
  49 export sharedstatedir = "${layout_sharedstatedir}"
  50 export localstatedir = "${layout_localstatedir}"
  51 export infodir = "${layout_infodir}"
  52 export mandir = "${layout_mandir}"
  53 export docdir = "${layout_docdir}"
  54 export servicedir = "${layout_servicedir}"
  55
  56 # Architecture dependent paths
  57 export bindir = "${layout_bindir}"
  58 export sbindir = "${layout_sbindir}"
  59 export libexecdir = "${layout_libexecdir}"
  60 export libdir = "${layout_libdir}"
  61 export includedir = "${layout_includedir}"
  62 export oldincludedir = "${layout_includedir}"
  63
  64 ##################################################################
  65 # Architecture-dependent build variables.
  66 ##################################################################
  67
  68 BUILD_ARCH = "${@os.uname()[4]}"
  69 BUILD_OS = "${@os.uname()[0].lower()}"
  70 BUILD_VENDOR = ""
  71 BUILD_SYS = "${BUILD_ARCH}${BUILD_VENDOR}-${BUILD_OS}"
  72 BUILD_PREFIX = ""
  73 BUILD_CC_ARCH = ""
  74
  75 HOST_ARCH = "${TARGET_ARCH}"
  76 HOST_OS = "${TARGET_OS}"
  77 HOST_VENDOR = "${TARGET_VENDOR}"
  78 HOST_SYS = "${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
  79 HOST_PREFIX = "${TARGET_PREFIX}"
  80 HOST_CC_ARCH = "${TARGET_CC_ARCH}"
  81
  82 TARGET_ARCH ?= "INVALID"
  83 TARGET_OS = "INVALID"
  84 TARGET_VENDOR = "${BUILD_VENDOR}"
  85 TARGET_SYS = "${TARGET_ARCH}${TARGET_VENDOR}${@['-' + bb.data.getVar('TARGET_OS', d, 1), ''][bb.data.getVar('TARGET_OS', d, 1) == ('' or 'custom')]}"
  86 TARGET_PREFIX = "${TARGET_SYS}-"
  87 TARGET_CC_ARCH = ""
  88
  89 BASE_PACKAGE_ARCH = "${HOST_ARCH}"
  90 PACKAGE_ARCH = "${BASE_PACKAGE_ARCH}"
  91 MACHINE_ARCH = "${@[bb.data.getVar('HOST_ARCH', d, 1), bb.data.getVar('MACHINE', d, 1)][bool(bb.data.getVar('MACHINE', d, 1))]}"
  92 PACKAGE_ARCHS = "all any noarch ${TARGET_ARCH} ${PACKAGE_EXTRA_ARCHS} ${MACHINE}"
  93
  94 MULTIMACH_ARCH = "${PACKAGE_ARCH}"
  95 MULTIMACH_TARGET_SYS = "${MULTIMACH_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
  96 MULTIMACH_HOST_SYS = "${MULTIMACH_ARCH}${HOST_VENDOR}-${HOST_OS}"
  97 BASEPKG_HOST_SYS = "${BASE_PACKAGE_ARCH}${HOST_VENDOR}-${HOST_OS}"
  98 BASEPKG_TARGET_SYS = "${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
  99
 100 # select proper CPU to get binary locales generated
 101 QEMU_OPTIONS = ""
 102 QEMU_OPTIONS_iwmmxt  = "-cpu pxa270-c5"
 103 QEMU_OPTIONS_armv6   = "-cpu arm1136"
 104 QEMU_OPTIONS_armv7a   = "-cpu cortex-a8"
 105
 106 ##################################################################
 107 # Date/time variables.
 108 ##################################################################
 109
 110 DATE := "${@time.strftime('%Y%m%d',time.gmtime())}"
 111 TIME := "${@time.strftime('%H%M%S',time.gmtime())}"
 112 DATETIME = "${DATE}${TIME}"
 113
 114 ##################################################################
 115 # Openembedded Software Prerequisites.
 116 ##################################################################
 117
 118 # python-native should be here but python relies on building
 119 # its own in staging
 120 ASSUME_PROVIDED = "\
 121     bc-native \
 122     bzip2-native \
 123     cvs-native \
 124     diffstat-native \
 125     patch-native \
 126     perl-native-runtime \
 127     python-native-runtime \
 128     svn-native \
 129     texinfo-native \
 130     util-linux-native \
 131     "
 132
 133 ##################################################################
 134 # Package default variables.
 135 ##################################################################
 136 PN = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[0] or 'defaultpkgname'}"
 137 PV = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[1] or '1.0'}"
 138 FILE_PR = "${@bb.parse.BBHandler.vars_from_file(bb.data.getVar('FILE',d),d)[2] or 'r0'}"
 139 PR = "${FILE_PR}${DISTRO_PR}"
 140 PF = "${PN}-${EXTENDPE}${PV}-${PR}"
 141 EXTENDPE = "${@['','${PE\x7d_'][bb.data.getVar('PE',d,1) > 0]}"
 142 EXTENDPEVER = "${@['','${PE\x7d:'][bb.data.getVar('PE',d,1) > 0]}"
 143 DEBPV = "${EXTENDPEVER}${PV}-${PR}"
 144 P = "${PN}-${PV}"
 145
 146 # Base package name
 147 # Automatically derives "foo" from "foo-native", "foo-cross" or "foo-initial"
 148 # otherwise it is the same as PN and P
 149 BPN = "${@base_package_name(d)}"
 150 BP = "${BPN}-${PV}"
 151
 152 # Package info.
 153
 154 SECTION = "base"
 155 PRIORITY = "optional"
 156 DESCRIPTION = "Version ${PV}-${PR} of package ${PN}"
 157 LICENSE = "unknown"
 158 MAINTAINER = "OpenEmbedded Team <openembedded-devel@lists.openembedded.org>"
 159 HOMEPAGE = "unknown"
 160
 161 # Package dependencies and provides.
 162
 163 # Ensure that -dev packages recommend the corresponding -dev packages of their
 164 # deps, and the same for -dbg.
 165 DEPCHAIN_PRE  = ""
 166 DEPCHAIN_POST = "-dev -dbg"
 167
 168 DEPENDS = ""
 169 RDEPENDS = ""
 170 PROVIDES = ""
 171 PROVIDES_prepend = "${P} ${PF} ${PN} "
 172 RPROVIDES = ""
 173
 174 MULTI_PROVIDER_WHITELIST = "virtual/libintl"
 175
 176 SOLIBS = ".so.*"
 177 SOLIBS_darwin = ".*.dylib"
 178 SOLIBS_darwin8 = ".*.dylib"
 179
 180 SOLIBSDEV = ".so"
 181 SOLIBSDEV_darwin = ".dylib"
 182 SOLIBSDEV_darwin8 = ".dylib"
 183
 184 PACKAGES = "${PN}-dbg ${PN} ${PN}-doc ${PN}-dev ${PN}-locale"
 185 #enable this when bitbake is upgraded to cope with ++ values in the field
 186 #PACKAGES_DYNAMIC = "${PN}-locale-*"
 187 FILES = ""
 188
 189 FILES_${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*.so.* \
 190             ${sysconfdir} ${sharedstatedir} ${localstatedir} \
 191             ${base_bindir}/* ${base_sbindir}/* ${base_libdir}/*.so* ${datadir}/${PN} ${libdir}/${PN}/* \
 192             ${datadir}/pixmaps ${datadir}/applications \
 193             ${datadir}/idl ${datadir}/omf ${datadir}/sounds \
 194             ${libdir}/bonobo/servers"
 195
 196 FILES_${PN}-doc = "${docdir} ${mandir} ${infodir} ${datadir}/gtk-doc \
 197             ${datadir}/gnome/help"
 198 SECTION_${PN}-doc = "doc"
 199
 200 FILES_${PN}-dev = "${includedir} ${libdir}/lib*.so ${libdir}/*.la \
 201                 ${libdir}/*.a ${libdir}/*.o ${libdir}/pkgconfig \
 202                 ${base_libdir}/*.a ${base_libdir}/*.o ${datadir}/aclocal"
 203 SECTION_${PN}-dev = "devel"
 204 ALLOW_EMPTY_${PN}-dev = "1"
 205 RDEPENDS_${PN}-dev = "${PN} (= ${DEBPV})"
 206
 207 FILES_${PN}-dbg = "${bindir}/.debug ${sbindir}/.debug ${libexecdir}/.debug ${libdir}/.debug \
 208             ${base_bindir}/.debug ${base_sbindir}/.debug ${base_libdir}/.debug ${libdir}/${PN}/.debug \
 209             ${libdir}/matchbox-panel/.debug"
 210 SECTION_${PN}-dbg = "devel"
 211 ALLOW_EMPTY_${PN}-dbg = "1"
 212 RRECOMMENDS_${PN}-dbg = "${PN} (= ${DEBPV})"
 213
 214 FILES_${PN}-locale = "${datadir}/locale"
 215
 216 # File manifest
 217
 218 export MANIFEST = "${FILESDIR}/manifest"
 219
 220 FILE_DIRNAME = "${@os.path.dirname(bb.data.getVar('FILE', d))}"
 221 FILESPATH = "${FILE_DIRNAME}/${PF}:${FILE_DIRNAME}/${P}:${FILE_DIRNAME}/${PN}:${FILE_DIRNAME}/${BP}:${FILE_DIRNAME}/${BPN}:${FILE_DIRNAME}/files:${FILE_DIRNAME}"
 222 FILESDIR = "${@bb.which(bb.data.getVar('FILESPATH', d, 1), '.')}"
 223
 224 ##################################################################
 225 # General work and output directories for the build system.
 226 ##################################################################
 227
 228 TMPDIR = "${TOPDIR}/tmp"
 229 CACHE = "${TMPDIR}/cache${@['', '/' + str(bb.data.getVar('MACHINE', d, 1))][bool(bb.data.getVar('MACHINE', d, 1))]}"
 230 CO_DIR = "${DL_DIR}"
 231 CVSDIR = "${CO_DIR}/cvs"
 232 SVNDIR = "${CO_DIR}/svn"
 233 GITDIR = "${CO_DIR}/git"
 234 BZRDIR = "${CO_DIR}/bzr"
 235 HGDIR = "${CO_DIR}/hg"
 236
 237 STAMP = "${TMPDIR}/stamps/${MULTIMACH_TARGET_SYS}/${PF}"
 238 WORKDIR = "${TMPDIR}/work/${MULTIMACH_TARGET_SYS}/${PF}"
 239 T = "${WORKDIR}/temp"
 240 D = "${WORKDIR}/image"
 241 S = "${WORKDIR}/${BP}"
 242 B = "${S}"
 243
 244 STAGING_DIR = "${TMPDIR}/staging"
 245
 246 STAGING_DIR_NATIVE = "${STAGING_DIR}/${BUILD_SYS}"
 247 STAGING_BINDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_bindir}"
 248 STAGING_BINDIR_CROSS  = "${STAGING_DIR_NATIVE}${layout_bindir}/${MULTIMACH_HOST_SYS}"
 249 STAGING_LIBDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_libdir}"
 250 STAGING_INCDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_includedir}"
 251 STAGING_ETCDIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_sysconfdir}"
 252 STAGING_DATADIR_NATIVE = "${STAGING_DIR_NATIVE}${layout_datadir}"
 253
 254 # This should really be MULTIMACH_HOST_SYS but that breaks "all" and machine
 255 # specific packages - hack around it for now.
 256 STAGING_DIR_HOST = "${STAGING_DIR}/${BASEPKG_HOST_SYS}"
 257 STAGING_BINDIR = "${STAGING_DIR_HOST}${layout_bindir}"
 258 STAGING_LIBDIR = "${STAGING_DIR_HOST}${layout_libdir}"
 259 STAGING_INCDIR = "${STAGING_DIR_HOST}${layout_includedir}"
 260 STAGING_DATADIR = "${STAGING_DIR_HOST}${layout_datadir}"
 261 STAGING_EXECPREFIXDIR = "${STAGING_DIR_HOST}${layout_exec_prefix}"
 262 STAGING_LOADER_DIR = "${STAGING_DIR_HOST}/loader"
 263 STAGING_FIRMWARE_DIR = "${STAGING_DIR_HOST}/firmware"
 264 STAGING_PYDIR = "${STAGING_DIR}/lib/python2.4"
 265
 266 # This should really be MULTIMACH_TARGET_SYS but that breaks "all" and machine
 267 # specific packages - hack around it for now.
 268 STAGING_DIR_TARGET = "${STAGING_DIR}/${BASEPKG_TARGET_SYS}"
 269
 270 DEPLOY_DIR = "${TMPDIR}/deploy"
 271 DEPLOY_DIR_TAR = "${DEPLOY_DIR}/tar"
 272 DEPLOY_DIR_IPK = "${DEPLOY_DIR}/ipk"
 273 DEPLOY_DIR_RPM = "${DEPLOY_DIR}/rpm"
 274 DEPLOY_DIR_DEB = "${DEPLOY_DIR}/deb"
 275 DEPLOY_DIR_IMAGE = "${DEPLOY_DIR}/images"
 276 DEPLOY_DIR_TOOLS = "${DEPLOY_DIR}/tools"
 277
 278 PKGDATA_DIR = "${TMPDIR}/pkgdata/${MULTIMACH_TARGET_SYS}"
 279
 280 SDK_NAME = "${DISTRO}/${TARGET_ARCH}"
 281 SDK_PREFIX = "/usr/local/${SDK_NAME}"
 282
 283 ##################################################################
 284 # Kernel info.
 285 ##################################################################
 286
 287 OLDEST_KERNEL = "2.4.0"
 288 STAGING_KERNEL_DIR = "${STAGING_DIR}/${MULTIMACH_TARGET_SYS}/kernel"
 289
 290 ##################################################################
 291 # Specific image creation and rootfs population info.
 292 ##################################################################
 293
 294 IMAGE_ROOTFS = "${TMPDIR}/rootfs"
 295 IMAGE_BASENAME = "${PN}"
 296 IMAGE_NAME = "${IMAGE_BASENAME}-${MACHINE}-${DATETIME}"
 297 IMAGE_LINK_NAME = "${IMAGE_BASENAME}-${MACHINE}"
 298 IMAGE_EXTRA_SPACE = 10240
 299
 300 IMAGE_CMD = ""
 301 IMAGE_CMD_jffs2 = "mkfs.jffs2 -x lzo --root=${IMAGE_ROOTFS} --faketime --output=${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.jffs2 ${EXTRA_IMAGECMD}"
 302 IMAGE_CMD_yaffs2 = "mkyaffs2image ${EXTRA_IMAGECMD} ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.yaffs2"
 303 IMAGE_CMD_cramfs = "mkcramfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cramfs ${EXTRA_IMAGECMD}"
 304 IMAGE_CMD_ext2 = "genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}"
 305 IMAGE_CMD_ext2.gz = "rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz; genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2 ${EXTRA_IMAGECMD}; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext2.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext2.gz; rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz"
 306 IMAGE_CMD_ext3 = "genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3"
 307 IMAGE_CMD_ext3.gz = "rm -rf ${DEPLOY_DIR_IMAGE}/tmp.gz && mkdir ${DEPLOY_DIR_IMAGE}/tmp.gz; genext2fs -b ${IMAGE_ROOTFS_SIZE} -d ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3 ${EXTRA_IMAGECMD}; tune2fs -j ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; gzip -f -9 ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3; mv ${DEPLOY_DIR_IMAGE}/tmp.gz/${IMAGE_NAME}.rootfs.ext3.gz ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.ext3.gz; rmdir ${DEPLOY_DIR_IMAGE}/tmp.gz"
 308 IMAGE_CMD_squashfs = "mksquashfs ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs ${EXTRA_IMAGECMD} -noappend"
 309 IMAGE_CMD_squashfs-lzma = "mksquashfs-lzma ${IMAGE_ROOTFS} ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.squashfs-lzma ${EXTRA_IMAGECMD} -noappend"
 310 IMAGE_CMD_tar = "cd ${IMAGE_ROOTFS} && tar -cvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar ."
 311 IMAGE_CMD_tar.gz = "cd ${IMAGE_ROOTFS} && tar -zcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.gz ."
 312 IMAGE_CMD_tar.bz2 = "cd ${IMAGE_ROOTFS} && tar -jcvf ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.tar.bz2 ."
 313 IMAGE_CMD_cpio = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio)"
 314 IMAGE_CMD_cpio.gz = "cd ${IMAGE_ROOTFS} && (find . | cpio -o -H newc | gzip -c -9 >${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.rootfs.cpio.gz)"
 315
 316 EXTRA_IMAGECMD = ""
 317 EXTRA_IMAGECMD_jffs2 = ""
 318 EXTRA_IMAGECMD_yaffs2 = "1"
 319 EXTRA_IMAGECMD_squashfs = ""
 320 EXTRA_IMAGECMD_squashfs-lzma = ""
 321
 322 IMAGE_DEPENDS = ""
 323 IMAGE_DEPENDS_jffs2 = "mtd-utils-native"
 324 IMAGE_DEPENDS_yaffs2 = "yaffs2-utils-native"
 325 IMAGE_DEPENDS_cramfs = "cramfs-native"
 326 IMAGE_DEPENDS_ext2 = "genext2fs-native"
 327 IMAGE_DEPENDS_ext2.gz = "genext2fs-native"
 328 IMAGE_DEPENDS_ext3 = "genext2fs-native e2fsprogs-native"
 329 IMAGE_DEPENDS_ext3.gz = "genext2fs-native e2fsprogs-native"
 330 IMAGE_DEPENDS_squashfs = "squashfs-tools-native"
 331 IMAGE_DEPENDS_squashfs-lzma = "squashfs-lzma-tools-native"
 332
 333 EXTRA_IMAGEDEPENDS = ""
 334
 335 ##################################################################
 336 # Toolchain info.
 337 ##################################################################
 338
 339 CROSS_DIR = "${TMPDIR}/cross/${BASE_PACKAGE_ARCH}"
 340 CROSS_DATADIR = "${CROSS_DIR}/share"
 341 PATH_prepend = "${STAGING_BINDIR_CROSS}:${STAGING_DIR_NATIVE}${layout_sbindir}:${STAGING_BINDIR_NATIVE}:${CROSS_DIR}/bin:${STAGING_DIR_NATIVE}${layout_base_sbindir}:${STAGING_DIR_NATIVE}${layout_base_bindir}:"
 342 export PATH
 343
 344 ##################################################################
 345 # Build utility info.
 346 ##################################################################
 347
 348 CCACHE = "${@bb.which(bb.data.getVar('PATH', d, 1), 'ccache') and 'ccache '}"
 349 TOOLCHAIN_OPTIONS = ""
 350
 351 export CC = "${CCACHE}${HOST_PREFIX}gcc ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 352 export CXX = "${CCACHE}${HOST_PREFIX}g++ ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 353 export F77 = "${CCACHE}${HOST_PREFIX}g77 ${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
 354 export CPP = "${HOST_PREFIX}gcc -E${TOOLCHAIN_OPTIONS}"
 355 export LD = "${HOST_PREFIX}ld${TOOLCHAIN_OPTIONS}"
 356 export CCLD = "${CC}"
 357 export AR = "${HOST_PREFIX}ar"
 358 export AS = "${HOST_PREFIX}as"
 359 export RANLIB = "${HOST_PREFIX}ranlib"
 360 export STRIP = "${HOST_PREFIX}strip"
 361 export OBJCOPY = "${HOST_PREFIX}objcopy"
 362 export OBJDUMP = "${HOST_PREFIX}objdump"
 363 PYTHON = "${@sys.executable}"
 364
 365 export BUILD_CC = "${CCACHE}${BUILD_PREFIX}gcc ${BUILD_CC_ARCH}"
 366 export BUILD_CXX = "${CCACHE}${BUILD_PREFIX}g++ ${BUILD_CC_ARCH}"
 367 export BUILD_F77 = "${CCACHE}${BUILD_PREFIX}g77 ${BUILD_CC_ARCH}"
 368 export BUILD_CPP = "${BUILD_PREFIX}cpp"
 369 export BUILD_LD = "${BUILD_PREFIX}ld"
 370 export BUILD_CCLD = "${BUILD_PREFIX}gcc"
 371 export BUILD_AR = "${BUILD_PREFIX}ar"
 372 export BUILD_RANLIB = "${BUILD_PREFIX}ranlib"
 373 export BUILD_STRIP = "${BUILD_PREFIX}strip"
 374
 375 export MAKE = "make"
 376 EXTRA_OEMAKE = "-e MAKEFLAGS="
 377
 378 ##################################################################
 379 # Patch handling.
 380 ##################################################################
 381 PATCHTOOL = 'quilt'
 382 PATCHRESOLVE = 'noop'
 383
 384 ##################################################################
 385 # Build flags and options.
 386 ##################################################################
 387
 388 export BUILD_CPPFLAGS = "-isystem${STAGING_INCDIR_NATIVE}"
 389 export CPPFLAGS = "${TARGET_CPPFLAGS}"
 390 export TARGET_CPPFLAGS = "-isystem${STAGING_DIR_TARGET}${layout_includedir}"
 391
 392 export BUILD_CFLAGS = "${BUILD_CPPFLAGS} ${BUILD_OPTIMIZATION}"
 393 export CFLAGS = "${TARGET_CFLAGS}"
 394 export TARGET_CFLAGS = "${TARGET_CPPFLAGS} ${SELECTED_OPTIMIZATION}"
 395
 396 export BUILD_CXXFLAGS = "${BUILD_CFLAGS} -fpermissive"
 397 export CXXFLAGS = "${TARGET_CXXFLAGS}"
 398 export TARGET_CXXFLAGS = "${TARGET_CFLAGS} -fpermissive"
 399
 400 export BUILD_LDFLAGS = "-L${STAGING_LIBDIR_NATIVE} \
 401                         -Wl,-rpath-link,${STAGING_LIBDIR_NATIVE} \
 402                         -Wl,-rpath,${STAGING_LIBDIR_NATIVE} -Wl,-O1"
 403
 404 export LDFLAGS = "${TARGET_LDFLAGS}"
 405 export TARGET_LDFLAGS = "-L${STAGING_DIR_TARGET}${layout_libdir} \
 406                          -Wl,-rpath-link,${STAGING_DIR_TARGET}${layout_libdir} \
 407                          -Wl,-O1 \
 408                          ${TARGET_LINK_HASH_STYLE}"
 409
 410 # Which flags to leave by strip-flags() in bin/build/oebuild.sh ?
 411 ALLOWED_FLAGS = "-O -mcpu -march -pipe"
 412
 413 # Pass parallel make options to the compile task only
 414 EXTRA_OEMAKE_prepend_task_do_compile = "${PARALLEL_MAKE} "
 415 EXTRA_OEMAKE_prepend_task-compile = "${PARALLEL_MAKE} "
 416
 417 ##################################################################
 418 # Optimization flags.
 419 ##################################################################
 420
 421 FULL_OPTIMIZATION = "-fexpensive-optimizations -fomit-frame-pointer -frename-registers -O2"
 422 DEBUG_OPTIMIZATION = "-O -fno-omit-frame-pointer -g"
 423 SELECTED_OPTIMIZATION = "${@bb.data.getVar(['FULL_OPTIMIZATION', 'DEBUG_OPTIMIZATION'][bb.data.getVar('DEBUG_BUILD', d, 1) == '1'], d, 1)}"
 424 BUILD_OPTIMIZATION = "-O2"
 425
 426 ##################################################################
 427 # Bootstrap stuff.
 428 ##################################################################
 429
 430 BOOTSTRAP_EXTRA_RDEPENDS = ""
 431 BOOTSTRAP_EXTRA_RRECOMMENDS = ""
 432
 433 ##################################################################
 434 # Palmtop stuff.
 435 ##################################################################
 436
 437 export QTDIR = "${STAGING_DIR_HOST}/qt2"
 438 export QPEDIR = "${STAGING_DIR_HOST}"
 439 export OPIEDIR = "${STAGING_DIR_HOST}"
 440 export palmtopdir = "${libdir}/opie"
 441 export palmqtdir = "${palmtopdir}"
 442
 443 ##################################################################
 444 # Download locations and utilities.
 445 ##################################################################
 446
 447 GNU_MIRROR = "ftp://ftp.gnu.org/gnu"
 448 DEBIAN_MIRROR = "ftp://ftp.debian.org/debian/pool"
 449 SOURCEFORGE_MIRROR = "http://downloads.sourceforge.net"
 450 GPE_MIRROR = "http://gpe.linuxtogo.org/download/source"
 451 GPEPHONE_MIRROR = "http://gpephone.linuxtogo.org/download/gpephone"
 452 GPE_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/base;module=${PN}"
 453 GPE_EXTRA_SVN = "svn://projects.linuxtogo.org/svn/gpe/trunk/extra;module=${PN}"
 454 GPEPHONE_SVN = "svn://projects.linuxtogo.org/svn/gpephone/trunk/source;module=${PN}"
 455 XLIBS_MIRROR = "http://xlibs.freedesktop.org/release"
 456 XORG_MIRROR = "http://xorg.freedesktop.org/releases"
 457 GNOME_MIRROR = "http://ftp.gnome.org/pub/GNOME/sources"
 458 FREEBSD_MIRROR = "ftp://ftp.freebsd.org/pub/FreeBSD/"
 459 HANDHELDS_CVS = "cvs://anoncvs:anoncvs@anoncvs.handhelds.org/cvs"
 460 E_CVS = "cvs://anonymous@anoncvs.enlightenment.org/var/cvs/e"
 461 E_URI = "http://enlightenment.freedesktop.org/files"
 462 FREEDESKTOP_CVS = "cvs://anoncvs:anoncvs@anoncvs.freedesktop.org/cvs"
 463 FREESMARTPHONE_GIT = "git://git.freesmartphone.org"
 464 GENTOO_MIRROR = "http://distro.ibiblio.org/pub/linux/distributions/gentoo/distfiles"
 465 APACHE_MIRROR = "http://www.apache.org/dist"
 466 KERNELORG_MIRROR = "http://kernel.org"
 467
 468 # You can use the mirror of your country to get faster downloads by putting
 469 #  export DEBIAN_MIRROR = "ftp://ftp.de.debian.org/debian/pool"
 470 #     into your local.conf
 471
 472 FETCHCMD_svn = "/usr/bin/env svn"
 473 FETCHCMD_cvs = "/usr/bin/env cvs"
 474 FETCHCMD_wget = "/usr/bin/env wget -t 5"
 475 FETCHCMD_bzr = "/usr/bin/env bzr"
 476 FETCHCMD_hg = "/usr/bin/env hg"
 477
 478 FETCHCOMMAND = "ERROR, this must be a BitBake bug"
 479 FETCHCOMMAND_wget = "/usr/bin/env wget -t 5 --passive-ftp -P ${DL_DIR} ${URI}"
 480 FETCHCOMMAND_cvs = "/usr/bin/env cvs '-d${CVSROOT}' co ${CVSCOOPTS} ${CVSMODULE}"
 481 FETCHCOMMAND_svn = "/usr/bin/env svn co ${SVNCOOPTS} ${SVNROOT} ${SVNMODULE}"
 482 RESUMECOMMAND = "ERROR, this must be a BitBake bug"
 483 RESUMECOMMAND_wget = "/usr/bin/env wget -c -t 5 --passive-ftp -P ${DL_DIR} ${URI}"
 484 UPDATECOMMAND = "ERROR, this must be a BitBake bug"
 485 UPDATECOMMAND_cvs = "/usr/bin/env cvs -d${CVSROOT} update -d -P ${CVSCOOPTS}"
 486 UPDATECOMMAND_svn = "/usr/bin/env svn update ${SVNCOOPTS}"
 487 SRCDATE = "${DATE}"
 488 SRCREV = "1"
 489 AUTOREV = "${@bb.fetch.get_srcrev(d)}"
 490
 491 SRC_URI = "file://${FILE}"
 492
 493 ##################################################################
 494 # UI/Interaction Configuration
 495 ##################################################################
 496
 497 SHELLRCCMD = "bash --rcfile $TERMRCFILE"
 498 export SHELLCMDS = "${SHELLRCCMD}"
 499 # Some common terminal programs to choose from
 500 GNOME_TERMCMD = 'gnome-terminal --disable-factory -t "$TERMWINDOWTITLE"'
 501 GNOME_TERMCMDRUN = '${GNOME_TERMCMD} -x $SHELLCMDS'
 502 SCREEN_TERMCMD = 'screen -D -m -t "$TERMWINDOWTITLE"'
 503 SCREEN_TERMCMDRUN = '${SCREEN_TERMCMD} $SHELLCMDS'
 504 XTERM_TERMCMD = 'xterm -T "$TERMWINDOWTITLE"'
 505 XTERM_TERMCMDRUN = '${XTERM_TERMCMD} -e $SHELLCMDS'
 506 KONSOLE_TERMCMD = 'konsole -T "$TERMWINDOWTITLE"'
 507 KONSOLE_TERMCMDRUN = '${KONSOLE_TERMCMD} -e $SHELLCMDS'
 508
 509 # Set a default
 510 TERMCMD ?= "${GNOME_TERMCMD}"
 511 TERMCMDRUN ?= "${GNOME_TERMCMDRUN}"
 512
 513 ##################################################################
 514 # Miscellaneous utilities.
 515 ##################################################################
 516
 517 MKTEMPDIRCMD = "mktemp -d -q ${TMPBASE}"
 518 MKTEMPCMD = "mktemp -q ${TMPBASE}"
 519
 520 # GNU patch tries to be intellgent about checking out read-only files from
 521 # a RCS, which freaks out those special folks with active Perforce clients
 522 # the following makes patch ignore RCS:
 523
 524 export PATCH_GET="0"
 525
 526 # Program to be used to build ipkg packages
 527
 528 IPKGBUILDCMD = "ipkg-build -o 0 -g 0"
 529
 530 ##################################################################
 531 # Not sure about the rest of this yet.
 532 ##################################################################
 533
 534 # slot - currently unused by OE. portage remnants
 535 SLOT = "0"
 536
 537 # Other
 538
 539 export PKG_CONFIG_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}${layout_libdir}/pkgconfig"
 540 export PKG_CONFIG_PATH = "${PKG_CONFIG_DIR}:${STAGING_DATADIR}/pkgconfig"
 541 export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR}/${BASE_PACKAGE_ARCH}${TARGET_VENDOR}-${TARGET_OS}"
 542 export PKG_CONFIG_DISABLE_UNINSTALLED = "yes"
 543
 544 export QMAKE_MKSPEC_PATH = "${STAGING_DATADIR_NATIVE}/qmake"
 545 export STAGING_SIPDIR = "${STAGING_DATADIR_NATIVE}/sip"
 546 export STAGING_IDLDIR = "${STAGING_DATADIR}/idl"
 547
 548 # library package naming
 549 AUTO_LIBNAME_PKGS = "${PACKAGES}"
 550
 551 ###
 552 ### Config file processing
 553 ###
 554
 555 # This means that an envionment variable named '<foo>_arm' overrides an
 556 # environment variable '<foo>' (when ${TARGET_ARCH} is arm). And the same: an
 557 # environment variable '<foo>_ramses' overrides both '<foo>' and '<foo>_arm
 558 # when ${MACHINE} is 'ramses'. And finally '<foo>_local' overrides anything.
 559 #
 560 # This works for  functions as well, they are really just environment variables.
 561 # Default OVERRIDES to make compilation fail fast in case of build system misconfiguration.
 562 OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:fail-fast:pn-${PN}"
 563 # Alternative OVERRIDES definition without "fail fast", usually only for native building and Scratchbox toolchains.
 564 #OVERRIDES = "local:${MACHINE}:${DISTRO}:${TARGET_OS}:${TARGET_ARCH}:build-${BUILD_OS}:pn-${PN}"
 565
 566 ##################################################################
 567 # Include the rest of the config files.
 568 ##################################################################
 569
 570 include conf/site.conf
 571 include conf/auto.conf
 572 include conf/local.conf
 573 # USERDISTRO should always contain original DISTRO value as set by user
 574 # If a distro config overrides DISTRO for whatever reason (e.g. to get
 575 # overrides like it wants), USERDISTRO must be reassigned with := first
 576 USERDISTRO = "${DISTRO}"
 577 include conf/build/${BUILD_SYS}.conf
 578 include conf/target/${TARGET_SYS}.conf
 579 include conf/machine/${MACHINE}.conf
 580 include conf/distro/${DISTRO}.conf
 581 include conf/documentation.conf
 582 require conf/sanity.conf
 583
 584 ##################################################################
 585 # Weak variables (usually to retain backwards compatibility)
 586 ##################################################################
 587
 588 DL_DIR ?= "${TMPDIR}/downloads"
 589 IMAGE_FSTYPES ?= "tar.gz"
 590 PCMCIA_MANAGER ?= "pcmcia-cs"
 591 DEFAULT_TASK_PROVIDER ?= "task-base"
 592 MACHINE_TASK_PROVIDER ?= "${DEFAULT_TASK_PROVIDER}"
 593 IMAGE_ROOTFS_SIZE_ext2 ?= "65536"
 594 IMAGE_ROOTFS_SIZE_ext2.gz ?= "65536"
 595 IMAGE_ROOTFS_SIZE_ext3 ?= "65536"
 596 IMAGE_ROOTFS_SIZE_ext3.gz ?= "65536"
 597
 598 # Forcefully set CACHE now so future changes to things like
 599 # MACHINE don't change the path to the cache
 600 CACHE := "${CACHE}"
 601
 602 # Default to disabling packaged staging code
 603 export PSTAGING_ACTIVE = "0"
 604
 605 ##################################################################
 606 # Magic Cookie for SANITY CHECK
 607 ##################################################################
 608 OES_BITBAKE_CONF = "1"
 609
 610 ##################################################################
 611 # Machine properties and task-base stuff
 612 ##################################################################
 613
 614 MACHINE_FEATURES ?= "kernel26"
 615 DISTRO_FEATURES ?= ""
 616
 617 # This is used to limit what packages goes into images built, so set big by default
 618 ROOT_FLASH_SIZE ?= "256"
 619
 620 MACHINE_GUI_CLASS ?= "smallscreen"
 621 # GUI_MACHINE_CLASS is deprecated, please use MACHINE_GUI_CLASS instead
 622 GUI_MACHINE_CLASS ?= "${MACHINE_GUI_CLASS}"
 623 MACHINE_DISPLAY_WIDTH_PIXELS ?= "240"
 624 MACHINE_DISPLAY_HEIGHT_PIXELS ?= "320"
 625 MACHINE_DISPLAY_ORIENTATION ?= "0"
 626 MACHINE_DISPLAY_BPP ?= "16"
 627
 628 DISTRO_EXTRA_RDEPENDS ?= ""
 629 DISTRO_EXTRA_RRECOMMENDS ?= ""
 630 MACHINE_EXTRA_RDEPENDS ?= ""
 631 MACHINE_EXTRA_RRECOMMENDS ?= ""
 632 MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
 633 MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
 634
 635 COMBINED_FEATURES = "\
 636     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "alsa", d)} \
 637     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "bluetooth", d)} \
 638     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "ext2", d)} \
 639     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "vfat", d)} \
 640     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "irda", d)} \
 641     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pcmcia", d)} \
 642     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "pci", d)} \
 643     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbgadget", d)} \
 644     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "usbhost", d)} \
 645     ${@base_both_contain("DISTRO_FEATURES", "MACHINE_FEATURES", "wifi", d)}"
 646