code.vuplus.com Git - vuplus_openembedded/blob - classes/update-rc.d.bbclass

   1 DEPENDS_append = " update-rc.d"
   2 RDEPENDS_append = " update-rc.d"
   3
   4 INITSCRIPT_PARAMS ?= "defaults"
   5
   6 INIT_D_DIR = "${sysconfdir}/init.d"
   7
   8 updatercd_postinst() {
   9 if test "x$D" != "x"; then
  10         D="-r $D"
  11 else
  12         D="-s"
  13 fi
  14 update-rc.d $D ${INITSCRIPT_NAME} ${INITSCRIPT_PARAMS}
  15 }
  16
  17 updatercd_prerm() {
  18 if test "x$D" != "x"; then
  19         D="-r $D"
  20 else
  21         ${INIT_D_DIR}/${INITSCRIPT_NAME} stop
  22 fi
  23 }
  24
  25 updatercd_postrm() {
  26 update-rc.d $D ${INITSCRIPT_NAME} remove
  27 }
  28
  29
  30 def update_rc_after_parse(d):
  31     import bb
  32     if bb.data.getVar('INITSCRIPT_PACKAGES', d) == None:
  33         if bb.data.getVar('INITSCRIPT_NAME', d) == None:
  34             raise bb.build.FuncFailed, "%s inherits update-rc.d but doesn't set INITSCRIPT_NAME" % bb.data.getVar('FILE', d)
  35         if bb.data.getVar('INITSCRIPT_PARAMS', d) == None:
  36             raise bb.build.FuncFailed, "%s inherits update-rc.d but doesn't set INITSCRIPT_PARAMS" % bb.data.getVar('FILE', d)
  37
  38 python __anonymous() {
  39     update_rc_after_parse(d)
  40 }
  41
  42 python populate_packages_prepend () {
  43         def update_rcd_package(pkg):
  44                 bb.debug(1, 'adding update-rc.d calls to postinst/postrm for %s' % pkg)
  45                 localdata = bb.data.createCopy(d)
  46                 overrides = bb.data.getVar("OVERRIDES", localdata, 1)
  47                 bb.data.setVar("OVERRIDES", "%s:%s" % (pkg, overrides), localdata)
  48                 bb.data.update_data(localdata)
  49
  50                 postinst = bb.data.getVar('pkg_postinst', localdata, 1)
  51                 if not postinst:
  52                         postinst = '#!/bin/sh\n'
  53                 postinst += bb.data.getVar('updatercd_postinst', localdata, 1)
  54                 bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
  55                 prerm = bb.data.getVar('pkg_prerm', localdata, 1)
  56                 if not prerm:
  57                         prerm = '#!/bin/sh\n'
  58                 prerm += bb.data.getVar('updatercd_prerm', localdata, 1)
  59                 bb.data.setVar('pkg_prerm_%s' % pkg, prerm, d)
  60                 postrm = bb.data.getVar('pkg_postrm', localdata, 1)
  61                 if not postrm:
  62                         postrm = '#!/bin/sh\n'
  63                 postrm += bb.data.getVar('updatercd_postrm', localdata, 1)
  64                 bb.data.setVar('pkg_postrm_%s' % pkg, postrm, d)
  65
  66         pkgs = bb.data.getVar('INITSCRIPT_PACKAGES', d, 1)
  67         if pkgs == None:
  68                 pkgs = bb.data.getVar('PN', d, 1)
  69                 packages = (bb.data.getVar('PACKAGES', d, 1) or "").split()
  70                 if not pkgs in packages and packages != []:
  71                         pkgs = packages[0]
  72         for pkg in pkgs.split():
  73                 update_rcd_package(pkg)
  74 }