code.vuplus.com Git - vuplus_openembedded/blob - classes/update-rc.d.bbclass

   1 DEPENDS_append = " update-rc.d"
   2 RDEPENDS_append = " update-rc.d"
   3
   4 INITSCRIPT_PARAMS ?= "defaults"
   5
   6 INIT_D_DIR = "${sysconfdir}/init.d"
   7
   8 updatercd_postinst() {
   9 if test "x$D" != "x"; then
  10         OPT="-r $D"
  11 else
  12         OPT="-s"
  13 fi
  14 update-rc.d $OPT ${INITSCRIPT_NAME} ${INITSCRIPT_PARAMS}
  15 }
  16
  17 updatercd_prerm() {
  18 if test "x$D" = "x"; then
  19         ${INIT_D_DIR}/${INITSCRIPT_NAME} stop
  20 fi
  21 }
  22
  23 updatercd_postrm() {
  24 update-rc.d $D ${INITSCRIPT_NAME} remove
  25 }
  26
  27
  28 def update_rc_after_parse(d):
  29     import bb
  30     if bb.data.getVar('INITSCRIPT_PACKAGES', d) == None:
  31         if bb.data.getVar('INITSCRIPT_NAME', d) == None:
  32             raise bb.build.FuncFailed, "%s inherits update-rc.d but doesn't set INITSCRIPT_NAME" % bb.data.getVar('FILE', d)
  33         if bb.data.getVar('INITSCRIPT_PARAMS', d) == None:
  34             raise bb.build.FuncFailed, "%s inherits update-rc.d but doesn't set INITSCRIPT_PARAMS" % bb.data.getVar('FILE', d)
  35
  36 python __anonymous() {
  37     update_rc_after_parse(d)
  38 }
  39
  40 python populate_packages_prepend () {
  41         def update_rcd_package(pkg):
  42                 bb.debug(1, 'adding update-rc.d calls to postinst/postrm for %s' % pkg)
  43                 localdata = bb.data.createCopy(d)
  44                 overrides = bb.data.getVar("OVERRIDES", localdata, 1)
  45                 bb.data.setVar("OVERRIDES", "%s:%s" % (pkg, overrides), localdata)
  46                 bb.data.update_data(localdata)
  47
  48                 postinst = bb.data.getVar('pkg_postinst', localdata, 1)
  49                 if not postinst:
  50                         postinst = '#!/bin/sh\n'
  51                 postinst += bb.data.getVar('updatercd_postinst', localdata, 1)
  52                 bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
  53                 prerm = bb.data.getVar('pkg_prerm', localdata, 1)
  54                 if not prerm:
  55                         prerm = '#!/bin/sh\n'
  56                 prerm += bb.data.getVar('updatercd_prerm', localdata, 1)
  57                 bb.data.setVar('pkg_prerm_%s' % pkg, prerm, d)
  58                 postrm = bb.data.getVar('pkg_postrm', localdata, 1)
  59                 if not postrm:
  60                         postrm = '#!/bin/sh\n'
  61                 postrm += bb.data.getVar('updatercd_postrm', localdata, 1)
  62                 bb.data.setVar('pkg_postrm_%s' % pkg, postrm, d)
  63
  64         pkgs = bb.data.getVar('INITSCRIPT_PACKAGES', d, 1)
  65         if pkgs == None:
  66                 pkgs = bb.data.getVar('PN', d, 1)
  67                 packages = (bb.data.getVar('PACKAGES', d, 1) or "").split()
  68                 if not pkgs in packages and packages != []:
  69                         pkgs = packages[0]
  70         for pkg in pkgs.split():
  71                 update_rcd_package(pkg)
  72 }