code.vuplus.com Git - vuplus_openembedded/blob - classes/kernel.bbclass

   1 inherit linux-kernel-base module_strip
   2
   3 PROVIDES += "virtual/kernel"
   4 DEPENDS += "virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules"
   5
   6 KERNEL_IMAGETYPE ?= "zImage"
   7
   8 # Add dependency on mkimage for kernels that build a uImage
   9
  10 python __anonymous () {
  11
  12     import bb
  13
  14     kerneltype = bb.data.getVar('KERNEL_IMAGETYPE', d, 1) or ''
  15     if kerneltype == 'uImage':
  16         depends = bb.data.getVar("DEPENDS", d, 1)
  17         depends = "%s u-boot-mkimage-openmoko-native" % depends
  18         bb.data.setVar("DEPENDS", depends, d)
  19
  20     image = bb.data.getVar('INITRAMFS_IMAGE', d, True)
  21     if image != '' and image is not None:
  22         bb.data.setVar('INITRAMFS_TASK', '${INITRAMFS_IMAGE}:do_rootfs', d)
  23 }
  24
  25 INITRAMFS_IMAGE ?= ""
  26 INITRAMFS_TASK ?= ""
  27
  28 inherit kernel-arch
  29
  30 PACKAGES_DYNAMIC += "kernel-module-*"
  31 PACKAGES_DYNAMIC += "kernel-image-*"
  32 PACKAGES_DYNAMIC += "kernel-firmware-*"
  33
  34 export OS = "${TARGET_OS}"
  35 export CROSS_COMPILE = "${TARGET_PREFIX}"
  36
  37 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  38
  39 KERNEL_RELEASE ?= "${KERNEL_VERSION}"
  40
  41 KERNEL_CCSUFFIX ?= ""
  42 KERNEL_LDSUFFIX ?= ""
  43
  44 # Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
  45 # specific options necessary for building the kernel and modules.
  46 #FIXME: should be this: TARGET_CC_KERNEL_ARCH ?= "${TARGET_CC_ARCH}"
  47 TARGET_CC_KERNEL_ARCH ?= ""
  48 HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
  49 TARGET_LD_KERNEL_ARCH ?= ""
  50 HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
  51
  52 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX} ${HOST_CC_KERNEL_ARCH}"
  53 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX} ${HOST_LD_KERNEL_ARCH}"
  54
  55 # Where built kernel lies in the kernel tree
  56 KERNEL_OUTPUT ?= "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  57 KERNEL_IMAGEDEST = "boot"
  58
  59 #
  60 # configuration
  61 #
  62 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  63
  64 KERNEL_VERSION = "${@get_kernelversion('${S}')}"
  65 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  66
  67 KERNEL_LOCALVERSION ?= ""
  68
  69 # kernels are generally machine specific
  70 PACKAGE_ARCH = "${MACHINE_ARCH}"
  71
  72 # U-Boot support
  73 UBOOT_ENTRYPOINT ?= "20008000"
  74 UBOOT_LOADADDRESS ?= "${UBOOT_ENTRYPOINT}"
  75
  76 kernel_do_compile() {
  77         if [ ! -z "${INITRAMFS_IMAGE}" ]; then
  78                 cp "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.cpio.gz" initramfs.cpio.gz
  79         fi
  80         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
  81         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  82         if [ "${KERNEL_MAJOR_VERSION}" != "2.6" ]; then
  83                 oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  84         fi
  85         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  86         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  87                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  88         else
  89                 oenote "no modules to compile"
  90         fi
  91 }
  92 kernel_do_compile[depends] = "${INITRAMFS_TASK}"
  93
  94
  95 kernel_do_stage() {
  96         ASMDIR=`readlink include/asm`
  97
  98         mkdir -p ${STAGING_KERNEL_DIR}/include/$ASMDIR
  99         cp -fR include/$ASMDIR/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
 100         rm -f $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 101         ln -sf $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 102
 103         mkdir -p ${STAGING_KERNEL_DIR}/include/asm-generic
 104         cp -fR include/asm-generic/* ${STAGING_KERNEL_DIR}/include/asm-generic/
 105
 106         mkdir -p ${STAGING_KERNEL_DIR}/include/linux
 107         cp -fR include/linux/* ${STAGING_KERNEL_DIR}/include/linux/
 108
 109         mkdir -p ${STAGING_KERNEL_DIR}/include/net
 110         cp -fR include/net/* ${STAGING_KERNEL_DIR}/include/net/
 111
 112         mkdir -p ${STAGING_KERNEL_DIR}/include/pcmcia
 113         cp -fR include/pcmcia/* ${STAGING_KERNEL_DIR}/include/pcmcia/
 114
 115         for entry in drivers/crypto include/media include/acpi include/sound include/video; do
 116                 if [ -d $entry ]; then
 117                         mkdir -p ${STAGING_KERNEL_DIR}/$entry
 118                         cp -fR $entry/* ${STAGING_KERNEL_DIR}/$entry/
 119                 fi
 120         done
 121
 122         if [ -d drivers/sound ]; then
 123                 # 2.4 alsa needs some headers from this directory
 124                 mkdir -p ${STAGING_KERNEL_DIR}/include/drivers/sound
 125                 cp -fR drivers/sound/*.h ${STAGING_KERNEL_DIR}/include/drivers/sound/
 126         fi
 127
 128         install -m 0644 .config ${STAGING_KERNEL_DIR}/config-${KERNEL_VERSION}
 129         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/.config
 130         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/kernel-config
 131         echo "${KERNEL_VERSION}" >${STAGING_KERNEL_DIR}/kernel-abiversion
 132         echo "${S}" >${STAGING_KERNEL_DIR}/kernel-source
 133         echo "${KERNEL_CCSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ccsuffix
 134         echo "${KERNEL_LDSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ldsuffix
 135         [ -e Rules.make ] && install -m 0644 Rules.make ${STAGING_KERNEL_DIR}/
 136         [ -e Makefile ] && install -m 0644 Makefile ${STAGING_KERNEL_DIR}/
 137
 138         # Check if arch/${ARCH}/Makefile exists and install it
 139         if [ -e arch/${ARCH}/Makefile ]; then
 140                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}
 141                 install -m 0644 arch/${ARCH}/Makefile* ${STAGING_KERNEL_DIR}/arch/${ARCH}
 142         # Otherwise check arch/x86/Makefile for i386 and x86_64 on kernels >= 2.6.24
 143         elif [ -e arch/x86/Makefile ]; then
 144                 install -d ${STAGING_KERNEL_DIR}/arch/x86
 145                 install -m 0644 arch/x86/Makefile* ${STAGING_KERNEL_DIR}/arch/x86
 146         fi
 147         cp -fR include/config* ${STAGING_KERNEL_DIR}/include/
 148         # Install kernel images and system.map to staging
 149         [ -e vmlinux ] && install -m 0644 vmlinux ${STAGING_KERNEL_DIR}/
 150         install -m 0644 ${KERNEL_OUTPUT} ${STAGING_KERNEL_DIR}/${KERNEL_IMAGETYPE}
 151         install -m 0644 System.map ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION}
 152         [ -e Module.symvers ] && install -m 0644 Module.symvers ${STAGING_KERNEL_DIR}/
 153
 154         cp -fR scripts ${STAGING_KERNEL_DIR}/
 155 }
 156
 157 kernel_do_install() {
 158         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 159         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 160                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 161         else
 162                 oenote "no modules to install"
 163         fi
 164
 165         install -d ${D}/${KERNEL_IMAGEDEST}
 166         install -d ${D}/boot
 167         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION}
 168         install -m 0644 System.map ${D}/boot/System.map-${KERNEL_VERSION}
 169         install -m 0644 .config ${D}/boot/config-${KERNEL_VERSION}
 170         install -m 0644 vmlinux ${D}/boot/vmlinux-${KERNEL_VERSION}
 171         install -d ${D}/etc/modutils
 172         if [ "${KERNEL_MAJOR_VERSION}" = "2.6" ]; then
 173                 install -d ${D}/etc/modprobe.d
 174         fi
 175
 176         # Check if scripts/genksyms exists and if so, build it
 177         if [ -e scripts/genksyms/ ]; then
 178                 oe_runmake SUBDIRS="scripts/genksyms"
 179         fi
 180
 181         install -d ${STAGING_KERNEL_DIR}
 182         cp -fR scripts ${STAGING_KERNEL_DIR}/
 183 }
 184
 185 kernel_do_configure() {
 186         yes '' | oe_runmake oldconfig
 187 }
 188
 189 do_menuconfig() {
 190         export TERMWINDOWTITLE="${PN} Kernel Configuration"
 191         export SHELLCMDS="make menuconfig"
 192         ${TERMCMDRUN}
 193         if [ $? -ne 0 ]; then
 194                 echo "Fatal: '${TERMCMD}' not found. Check TERMCMD variable."
 195                 exit 1
 196         fi
 197 }
 198 do_menuconfig[nostamp] = "1"
 199 addtask menuconfig after do_patch
 200
 201 pkg_postinst_kernel () {
 202         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 203 }
 204
 205 pkg_postrm_kernel () {
 206         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} || true
 207 }
 208
 209 inherit cml1
 210
 211 EXPORT_FUNCTIONS do_compile do_install do_stage do_configure
 212
 213 # kernel-base becomes kernel-${KERNEL_VERSION}
 214 # kernel-image becomes kernel-image-${KERNEL_VERISON}
 215 PACKAGES = "kernel kernel-base kernel-image kernel-dev kernel-vmlinux"
 216 FILES = ""
 217 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 218 FILES_kernel-dev = "/boot/System.map* /boot/config*"
 219 FILES_kernel-vmlinux = "/boot/vmlinux*"
 220 RDEPENDS_kernel = "kernel-base"
 221 RRECOMMENDS_kernel-module-hostap-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 222 RRECOMMENDS_kernel-module-orinoco-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 223 # Allow machines to override this dependency if kernel image files are
 224 # not wanted in images as standard
 225 RDEPENDS_kernel-base ?= "kernel-image"
 226 PKG_kernel-image = "kernel-image-${KERNEL_VERSION}"
 227 PKG_kernel-base = "kernel-${KERNEL_VERSION}"
 228 ALLOW_EMPTY_kernel = "1"
 229 ALLOW_EMPTY_kernel-base = "1"
 230 ALLOW_EMPTY_kernel-image = "1"
 231
 232 # Userspace workarounds for kernel modules issues
 233 # This is shame, fix the kernel instead!
 234 DEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 235 RDEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 236
 237 # renamed modules
 238 RPROVIDES_kernel-module-aes-generic = "kernel-module-aes"
 239
 240 pkg_postinst_kernel-image () {
 241 if [ ! -e "$D/lib/modules/${KERNEL_VERSION}" ]; then
 242         mkdir -p $D/lib/modules/${KERNEL_VERSION}
 243 fi
 244 if [ -n "$D" ]; then
 245         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 246 else
 247         depmod -a
 248 fi
 249 }
 250
 251 pkg_postinst_modules () {
 252 if [ -n "$D" ]; then
 253         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 254 else
 255         depmod -a
 256         update-modules || true
 257 fi
 258 }
 259
 260 pkg_postrm_modules () {
 261 update-modules || true
 262 }
 263
 264 autoload_postinst_fragment() {
 265 if [ x"$D" = "x" ]; then
 266         modprobe %s || true
 267 fi
 268 }
 269
 270 # autoload defaults (alphabetically sorted)
 271 module_autoload_hidp = "hidp"
 272 module_autoload_ipv6 = "ipv6"
 273 module_autoload_ipsec = "ipsec"
 274 module_autoload_ircomm-tty = "ircomm-tty"
 275 module_autoload_rfcomm = "rfcomm"
 276 module_autoload_sa1100-rtc = "sa1100-rtc"
 277 # sa1100-rtc was renamed in 2.6.23 onwards
 278 module_autoload_rtc-sa1100 = "rtc-sa1100"
 279
 280 # alias defaults (alphabetically sorted)
 281 module_conf_af_packet = "alias net-pf-17 af_packet"
 282 module_conf_bluez = "alias net-pf-31 bluez"
 283 module_conf_bnep = "alias bt-proto-4 bnep"
 284 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 285 module_conf_l2cap = "alias bt-proto-0 l2cap"
 286 module_conf_sco = "alias bt-proto-2 sco"
 287 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 288
 289 python populate_packages_prepend () {
 290         def extract_modinfo(file):
 291                 import os, re
 292                 tmpfile = os.tmpnam()
 293                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 294                 os.system(cmd)
 295                 f = open(tmpfile)
 296                 l = f.read().split("\000")
 297                 f.close()
 298                 os.unlink(tmpfile)
 299                 exp = re.compile("([^=]+)=(.*)")
 300                 vals = {}
 301                 for i in l:
 302                         m = exp.match(i)
 303                         if not m:
 304                                 continue
 305                         vals[m.group(1)] = m.group(2)
 306                 return vals
 307
 308         def parse_depmod():
 309                 import os, re
 310
 311                 dvar = bb.data.getVar('D', d, 1)
 312                 if not dvar:
 313                         bb.error("D not defined")
 314                         return
 315
 316                 kernelver = bb.data.getVar('KERNEL_VERSION', d, 1)
 317                 kernelver_stripped = kernelver
 318                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 319                 if m:
 320                         kernelver_stripped = m.group(1)
 321                 path = bb.data.getVar("PATH", d, 1)
 322                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 323                 major_version = bb.data.getVar('KERNEL_MAJOR_VERSION', d, 1)
 324
 325                 cmd = "PATH=\"%s\" %sdepmod-%s -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, major_version, dvar, dvar, kernelver, kernelver_stripped)
 326                 f = os.popen(cmd, 'r')
 327
 328                 deps = {}
 329                 pattern0 = "^(.*\.k?o):..*$"
 330                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 331                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 332                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 333                 pattern4 = "^\t(.*\.k?o)\s*$"
 334
 335                 line = f.readline()
 336                 while line:
 337                         if not re.match(pattern0, line):
 338                                 line = f.readline()
 339                                 continue
 340                         m1 = re.match(pattern1, line)
 341                         if m1:
 342                                 deps[m1.group(1)] = m1.group(2).split()
 343                         else:
 344                                 m2 = re.match(pattern2, line)
 345                                 if m2:
 346                                         deps[m2.group(1)] = m2.group(2).split()
 347                                         line = f.readline()
 348                                         m3 = re.match(pattern3, line)
 349                                         while m3:
 350                                                 deps[m2.group(1)].extend(m3.group(1).split())
 351                                                 line = f.readline()
 352                                                 m3 = re.match(pattern3, line)
 353                                         m4 = re.match(pattern4, line)
 354                                         deps[m2.group(1)].extend(m4.group(1).split())
 355                         line = f.readline()
 356                 f.close()
 357                 return deps
 358
 359         def get_dependencies(file, pattern, format):
 360                 file = file.replace(bb.data.getVar('D', d, 1) or '', '', 1)
 361
 362                 if module_deps.has_key(file):
 363                         import os.path, re
 364                         dependencies = []
 365                         for i in module_deps[file]:
 366                                 m = re.match(pattern, os.path.basename(i))
 367                                 if not m:
 368                                         continue
 369                                 on = legitimize_package_name(m.group(1))
 370                                 dependency_pkg = format % on
 371                                 dependencies.append(dependency_pkg)
 372                         return dependencies
 373                 return []
 374
 375         def frob_metadata(file, pkg, pattern, format, basename):
 376                 import re
 377                 vals = extract_modinfo(file)
 378
 379                 dvar = bb.data.getVar('D', d, 1)
 380
 381                 # If autoloading is requested, output /etc/modutils/<name> and append
 382                 # appropriate modprobe commands to the postinst
 383                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 384                 if not autoload:
 385                     # Also, try canonical name with dashes
 386                     autoload = bb.data.getVar('module_autoload_%s' % basename.replace('_', '-'), d, 1)
 387                 if autoload:
 388                         name = '%s/etc/modutils/%s' % (dvar, basename)
 389                         f = open(name, 'w')
 390                         for m in autoload.split():
 391                                 f.write('%s\n' % m)
 392                         f.close()
 393                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 394                         if not postinst:
 395                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 396                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 397                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 398
 399                 # Write out any modconf fragment
 400                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 401                 if modconf:
 402                         if bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1) == "2.6":
 403                                 name = '%s/etc/modprobe.d/%s.conf' % (dvar, basename)
 404                         else:
 405                                 name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 406                         f = open(name, 'w')
 407                         f.write("%s\n" % modconf)
 408                         f.close()
 409
 410                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 411                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf /etc/modprobe.d/%s.conf" % (files, basename, basename, basename)
 412                 bb.data.setVar('FILES_%s' % pkg, files, d)
 413
 414                 if vals.has_key("description"):
 415                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 416                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 417
 418                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 419                 if rdepends_str:
 420                         rdepends = rdepends_str.split()
 421                 else:
 422                         rdepends = []
 423                 rdepends.extend(get_dependencies(file, pattern, format))
 424                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 425
 426         module_deps = parse_depmod()
 427         module_regex = '^(.*)\.k?o$'
 428         module_pattern = 'kernel-module-%s'
 429
 430         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 431         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 432
 433         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.bin$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 434         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.fw$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 435         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='update-modules kernel-%s' % bb.data.getVar("KERNEL_VERSION", d, 1))
 436
 437         import re, os
 438         metapkg = "kernel-modules"
 439         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 440         bb.data.setVar('FILES_' + metapkg, "", d)
 441         blacklist = [ 'kernel-dev', 'kernel-image', 'kernel-base', 'kernel-vmlinux' ]
 442         for l in module_deps.values():
 443                 for i in l:
 444                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 445                         blacklist.append(pkg)
 446         metapkg_rdepends = []
 447         packages = bb.data.getVar('PACKAGES', d, 1).split()
 448         for pkg in packages[1:]:
 449                 if not pkg in blacklist and not pkg in metapkg_rdepends:
 450                         metapkg_rdepends.append(pkg)
 451         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
 452         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 453         packages.append(metapkg)
 454         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 455 }
 456
 457 # Support checking the kernel size since some kernels need to reside in partitions
 458 # with a fixed length or there is a limit in transferring the kernel to memory
 459 do_sizecheck() {
 460         if [ ! -z "${KERNEL_IMAGE_MAXSIZE}" -a -z "${DONT_CHECK_KERNELSIZE}" ]; then
 461                 size=`ls -l ${KERNEL_OUTPUT} | awk '{ print $5}'`
 462                 if [ $size -ge ${KERNEL_IMAGE_MAXSIZE} ]; then
 463                         rm ${KERNEL_OUTPUT}
 464                         die  "This kernel (size=$size > ${KERNEL_IMAGE_MAXSIZE}) is too big for your device. Please reduce the size of the kernel by making more of it modular."
 465                 fi
 466         fi
 467 }
 468
 469 addtask sizecheck before do_install after do_compile
 470
 471 KERNEL_IMAGE_BASE_NAME ?= "${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}"
 472 KERNEL_IMAGE_SYMLINK_NAME ?= "${KERNEL_IMAGETYPE}-${MACHINE}"
 473
 474 do_deploy() {
 475         install -d ${DEPLOY_DIR_IMAGE}
 476         install -m 0644 ${KERNEL_OUTPUT} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 477         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 478
 479         if [ -d "${D}/lib" ]; then
 480         tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${PV}-${PR}-${MACHINE}.tgz -C ${D} lib
 481         fi
 482
 483         if test "x${KERNEL_IMAGETYPE}" = "xuImage" ; then
 484                 if test -e arch/${ARCH}/boot/compressed/vmlinux ; then
 485                         ${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
 486                         uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C none -a ${UBOOT_LOADADDRESS} -e ${UBOOT_ENTRYPOINT} -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 487                         rm -f linux.bin
 488                 else
 489                         ${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
 490                         rm -f linux.bin.gz
 491                         gzip -9 linux.bin
 492                         uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C gzip -a ${UBOOT_LOADADDRESS} -e ${UBOOT_ENTRYPOINT} -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 493                         rm -f linux.bin.gz
 494                 fi
 495                 package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 496         fi
 497
 498         cd ${DEPLOY_DIR_IMAGE}
 499         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 500         ln -sf ${KERNEL_IMAGE_BASE_NAME}.bin ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 501         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.bin
 502 }
 503
 504 do_deploy[dirs] = "${S}"
 505
 506 addtask deploy before do_package after do_install