code.vuplus.com Git - vuplus_openembedded/blob - classes/kernel.bbclass

   1 inherit linux-kernel-base module_strip
   2
   3 PROVIDES += "virtual/kernel"
   4 DEPENDS += "virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules"
   5
   6 KERNEL_IMAGETYPE ?= "zImage"
   7
   8 # Add dependency on mkimage for kernels that build a uImage
   9
  10 python __anonymous () {
  11
  12     import bb
  13
  14     kerneltype = bb.data.getVar('KERNEL_IMAGETYPE', d, 1) or ''
  15     if kerneltype == 'uImage':
  16         depends = bb.data.getVar("DEPENDS", d, 1)
  17         depends = "%s u-boot-mkimage-openmoko-native" % depends
  18         bb.data.setVar("DEPENDS", depends, d)
  19
  20     image = bb.data.getVar('INITRAMFS_IMAGE', d, True)
  21     if image != '' and image is not None:
  22         bb.data.setVar('INITRAMFS_TASK', '${INITRAMFS_IMAGE}:do_rootfs', d)
  23 }
  24
  25 INITRAMFS_IMAGE ?= ""
  26 INITRAMFS_TASK ?= ""
  27
  28 inherit kernel-arch
  29
  30 PACKAGES_DYNAMIC += "kernel-module-*"
  31 PACKAGES_DYNAMIC += "kernel-image-*"
  32 PACKAGES_DYNAMIC += "kernel-firmware-*"
  33
  34 export OS = "${TARGET_OS}"
  35 export CROSS_COMPILE = "${TARGET_PREFIX}"
  36
  37 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  38
  39 KERNEL_RELEASE ?= "${KERNEL_VERSION}"
  40
  41 KERNEL_CCSUFFIX ?= ""
  42 KERNEL_LDSUFFIX ?= ""
  43
  44 # Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
  45 # specific options necessary for building the kernel and modules.
  46 #FIXME: should be this: TARGET_CC_KERNEL_ARCH ?= "${TARGET_CC_ARCH}"
  47 TARGET_CC_KERNEL_ARCH ?= ""
  48 HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
  49 TARGET_LD_KERNEL_ARCH ?= ""
  50 HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
  51
  52 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX} ${HOST_CC_KERNEL_ARCH}"
  53 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX} ${HOST_LD_KERNEL_ARCH}"
  54
  55 # Where built kernel lies in the kernel tree
  56 KERNEL_OUTPUT ?= "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  57 KERNEL_IMAGEDEST = "boot"
  58
  59 #
  60 # configuration
  61 #
  62 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  63
  64 KERNEL_VERSION = "${@get_kernelversion('${S}')}"
  65 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  66
  67 KERNEL_LOCALVERSION ?= ""
  68
  69 # kernels are generally machine specific
  70 PACKAGE_ARCH = "${MACHINE_ARCH}"
  71
  72 # U-Boot support
  73 UBOOT_ENTRYPOINT ?= "20008000"
  74 UBOOT_LOADADDRESS ?= "${UBOOT_ENTRYPOINT}"
  75
  76 kernel_do_compile() {
  77         if [ ! -z "${INITRAMFS_IMAGE}" ]; then
  78                 cp "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.cpio.gz" initramfs.cpio.gz
  79         fi
  80         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
  81         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  82         if [ "${KERNEL_MAJOR_VERSION}" != "2.6" ]; then
  83                 oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  84         fi
  85         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  86         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  87                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  88         else
  89                 oenote "no modules to compile"
  90         fi
  91 }
  92 kernel_do_compile[depends] = "${INITRAMFS_TASK}"
  93
  94 kernel_do_stage() {
  95         ASMDIR=`readlink include/asm`
  96
  97         mkdir -p ${STAGING_KERNEL_DIR}/include/$ASMDIR
  98         cp -fR include/$ASMDIR/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
  99         # Kernel 2.6.27 moved headers from includes/asm-${ARCH} to arch/${ARCH}/include/asm
 100         if [ -e arch/${ARCH}/include/asm/ ] ; then
 101                 cp -fR arch/${ARCH}/include/asm/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
 102                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}/include
 103                 cp -fR arch/${ARCH}/* ${STAGING_KERNEL_DIR}/arch/${ARCH}/
 104         fi
 105         rm -f $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 106         ln -sf $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 107
 108         mkdir -p ${STAGING_KERNEL_DIR}/include/asm-generic
 109         cp -fR include/asm-generic/* ${STAGING_KERNEL_DIR}/include/asm-generic/
 110
 111         mkdir -p ${STAGING_KERNEL_DIR}/include/linux
 112         cp -fR include/linux/* ${STAGING_KERNEL_DIR}/include/linux/
 113
 114         mkdir -p ${STAGING_KERNEL_DIR}/include/net
 115         cp -fR include/net/* ${STAGING_KERNEL_DIR}/include/net/
 116
 117         mkdir -p ${STAGING_KERNEL_DIR}/include/pcmcia
 118         cp -fR include/pcmcia/* ${STAGING_KERNEL_DIR}/include/pcmcia/
 119
 120         for entry in drivers/crypto include/media include/acpi include/sound include/video; do
 121                 if [ -d $entry ]; then
 122                         mkdir -p ${STAGING_KERNEL_DIR}/$entry
 123                         cp -fR $entry/* ${STAGING_KERNEL_DIR}/$entry/
 124                 fi
 125         done
 126
 127         if [ -d drivers/sound ]; then
 128                 # 2.4 alsa needs some headers from this directory
 129                 mkdir -p ${STAGING_KERNEL_DIR}/include/drivers/sound
 130                 cp -fR drivers/sound/*.h ${STAGING_KERNEL_DIR}/include/drivers/sound/
 131         fi
 132
 133         install -m 0644 .config ${STAGING_KERNEL_DIR}/config-${KERNEL_VERSION}
 134         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/.config
 135         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/kernel-config
 136         echo "${KERNEL_VERSION}" >${STAGING_KERNEL_DIR}/kernel-abiversion
 137         echo "${S}" >${STAGING_KERNEL_DIR}/kernel-source
 138         echo "${KERNEL_CCSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ccsuffix
 139         echo "${KERNEL_LDSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ldsuffix
 140         [ -e Rules.make ] && install -m 0644 Rules.make ${STAGING_KERNEL_DIR}/
 141         [ -e Makefile ] && install -m 0644 Makefile ${STAGING_KERNEL_DIR}/
 142
 143         # Check if arch/${ARCH}/Makefile exists and install it
 144         if [ -e arch/${ARCH}/Makefile ]; then
 145                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}
 146                 install -m 0644 arch/${ARCH}/Makefile* ${STAGING_KERNEL_DIR}/arch/${ARCH}
 147         # Otherwise check arch/x86/Makefile for i386 and x86_64 on kernels >= 2.6.24
 148         elif [ -e arch/x86/Makefile ]; then
 149                 install -d ${STAGING_KERNEL_DIR}/arch/x86
 150                 install -m 0644 arch/x86/Makefile* ${STAGING_KERNEL_DIR}/arch/x86
 151         fi
 152         cp -fR include/config* ${STAGING_KERNEL_DIR}/include/
 153         # Install kernel images and system.map to staging
 154         [ -e vmlinux ] && install -m 0644 vmlinux ${STAGING_KERNEL_DIR}/
 155         install -m 0644 ${KERNEL_OUTPUT} ${STAGING_KERNEL_DIR}/${KERNEL_IMAGETYPE}
 156         install -m 0644 System.map ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION}
 157         [ -e Module.symvers ] && install -m 0644 Module.symvers ${STAGING_KERNEL_DIR}/
 158
 159         cp -fR scripts ${STAGING_KERNEL_DIR}/
 160 }
 161
 162 kernel_do_install() {
 163         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 164         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 165                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 166         else
 167                 oenote "no modules to install"
 168         fi
 169
 170         install -d ${D}/${KERNEL_IMAGEDEST}
 171         install -d ${D}/boot
 172         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION}
 173         install -m 0644 System.map ${D}/boot/System.map-${KERNEL_VERSION}
 174         install -m 0644 .config ${D}/boot/config-${KERNEL_VERSION}
 175         install -m 0644 vmlinux ${D}/boot/vmlinux-${KERNEL_VERSION}
 176         install -d ${D}/etc/modutils
 177         if [ "${KERNEL_MAJOR_VERSION}" = "2.6" ]; then
 178                 install -d ${D}/etc/modprobe.d
 179         fi
 180
 181         # Check if scripts/genksyms exists and if so, build it
 182         if [ -e scripts/genksyms/ ]; then
 183                 oe_runmake SUBDIRS="scripts/genksyms"
 184         fi
 185
 186         install -d ${STAGING_KERNEL_DIR}
 187         cp -fR scripts ${STAGING_KERNEL_DIR}/
 188 }
 189
 190 kernel_do_configure() {
 191         yes '' | oe_runmake oldconfig
 192 }
 193
 194 do_menuconfig() {
 195         export TERMWINDOWTITLE="${PN} Kernel Configuration"
 196         export SHELLCMDS="make menuconfig"
 197         ${TERMCMDRUN}
 198         if [ $? -ne 0 ]; then
 199                 echo "Fatal: '${TERMCMD}' not found. Check TERMCMD variable."
 200                 exit 1
 201         fi
 202 }
 203 do_menuconfig[nostamp] = "1"
 204 addtask menuconfig after do_patch
 205
 206 pkg_postinst_kernel () {
 207         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 208 }
 209
 210 pkg_postrm_kernel () {
 211         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} || true
 212 }
 213
 214 inherit cml1
 215
 216 EXPORT_FUNCTIONS do_compile do_install do_stage do_configure
 217
 218 # kernel-base becomes kernel-${KERNEL_VERSION}
 219 # kernel-image becomes kernel-image-${KERNEL_VERISON}
 220 PACKAGES = "kernel kernel-base kernel-image kernel-dev kernel-vmlinux"
 221 FILES = ""
 222 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 223 FILES_kernel-dev = "/boot/System.map* /boot/config*"
 224 FILES_kernel-vmlinux = "/boot/vmlinux*"
 225 RDEPENDS_kernel = "kernel-base"
 226 RRECOMMENDS_kernel-module-hostap-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 227 RRECOMMENDS_kernel-module-orinoco-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 228 # Allow machines to override this dependency if kernel image files are
 229 # not wanted in images as standard
 230 RDEPENDS_kernel-base ?= "kernel-image"
 231 PKG_kernel-image = "kernel-image-${KERNEL_VERSION}"
 232 PKG_kernel-base = "kernel-${KERNEL_VERSION}"
 233 ALLOW_EMPTY_kernel = "1"
 234 ALLOW_EMPTY_kernel-base = "1"
 235 ALLOW_EMPTY_kernel-image = "1"
 236
 237 # Userspace workarounds for kernel modules issues
 238 # This is shame, fix the kernel instead!
 239 DEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 240 RDEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 241
 242 # renamed modules
 243 RPROVIDES_kernel-module-aes-generic = "kernel-module-aes"
 244
 245 pkg_postinst_kernel-image () {
 246 if [ ! -e "$D/lib/modules/${KERNEL_VERSION}" ]; then
 247         mkdir -p $D/lib/modules/${KERNEL_VERSION}
 248 fi
 249 if [ -n "$D" ]; then
 250         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 251 else
 252         depmod -a
 253 fi
 254 }
 255
 256 pkg_postinst_modules () {
 257 if [ -n "$D" ]; then
 258         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 259 else
 260         depmod -a
 261         update-modules || true
 262 fi
 263 }
 264
 265 pkg_postrm_modules () {
 266 update-modules || true
 267 }
 268
 269 autoload_postinst_fragment() {
 270 if [ x"$D" = "x" ]; then
 271         modprobe %s || true
 272 fi
 273 }
 274
 275 # autoload defaults (alphabetically sorted)
 276 module_autoload_hidp = "hidp"
 277 module_autoload_ipv6 = "ipv6"
 278 module_autoload_ipsec = "ipsec"
 279 module_autoload_ircomm-tty = "ircomm-tty"
 280 module_autoload_rfcomm = "rfcomm"
 281 module_autoload_sa1100-rtc = "sa1100-rtc"
 282 # sa1100-rtc was renamed in 2.6.23 onwards
 283 module_autoload_rtc-sa1100 = "rtc-sa1100"
 284
 285 # alias defaults (alphabetically sorted)
 286 module_conf_af_packet = "alias net-pf-17 af_packet"
 287 module_conf_bluez = "alias net-pf-31 bluez"
 288 module_conf_bnep = "alias bt-proto-4 bnep"
 289 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 290 module_conf_l2cap = "alias bt-proto-0 l2cap"
 291 module_conf_sco = "alias bt-proto-2 sco"
 292 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 293
 294 python populate_packages_prepend () {
 295         def extract_modinfo(file):
 296                 import tempfile, os, re
 297                 tempfile.tempdir = bb.data.getVar("WORKDIR", d, 1)
 298                 tmpfile = tempfile.mkstemp()[1]
 299                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 300                 os.system(cmd)
 301                 f = open(tmpfile)
 302                 l = f.read().split("\000")
 303                 f.close()
 304                 os.unlink(tmpfile)
 305                 exp = re.compile("([^=]+)=(.*)")
 306                 vals = {}
 307                 for i in l:
 308                         m = exp.match(i)
 309                         if not m:
 310                                 continue
 311                         vals[m.group(1)] = m.group(2)
 312                 return vals
 313
 314         def parse_depmod():
 315                 import os, re
 316
 317                 dvar = bb.data.getVar('D', d, 1)
 318                 if not dvar:
 319                         bb.error("D not defined")
 320                         return
 321
 322                 kernelver = bb.data.getVar('KERNEL_VERSION', d, 1)
 323                 kernelver_stripped = kernelver
 324                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 325                 if m:
 326                         kernelver_stripped = m.group(1)
 327                 path = bb.data.getVar("PATH", d, 1)
 328                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 329                 major_version = bb.data.getVar('KERNEL_MAJOR_VERSION', d, 1)
 330
 331                 cmd = "PATH=\"%s\" %sdepmod-%s -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, major_version, dvar, dvar, kernelver, kernelver_stripped)
 332                 f = os.popen(cmd, 'r')
 333
 334                 deps = {}
 335                 pattern0 = "^(.*\.k?o):..*$"
 336                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 337                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 338                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 339                 pattern4 = "^\t(.*\.k?o)\s*$"
 340
 341                 line = f.readline()
 342                 while line:
 343                         if not re.match(pattern0, line):
 344                                 line = f.readline()
 345                                 continue
 346                         m1 = re.match(pattern1, line)
 347                         if m1:
 348                                 deps[m1.group(1)] = m1.group(2).split()
 349                         else:
 350                                 m2 = re.match(pattern2, line)
 351                                 if m2:
 352                                         deps[m2.group(1)] = m2.group(2).split()
 353                                         line = f.readline()
 354                                         m3 = re.match(pattern3, line)
 355                                         while m3:
 356                                                 deps[m2.group(1)].extend(m3.group(1).split())
 357                                                 line = f.readline()
 358                                                 m3 = re.match(pattern3, line)
 359                                         m4 = re.match(pattern4, line)
 360                                         deps[m2.group(1)].extend(m4.group(1).split())
 361                         line = f.readline()
 362                 f.close()
 363                 return deps
 364
 365         def get_dependencies(file, pattern, format):
 366                 file = file.replace(bb.data.getVar('D', d, 1) or '', '', 1)
 367
 368                 if module_deps.has_key(file):
 369                         import os.path, re
 370                         dependencies = []
 371                         for i in module_deps[file]:
 372                                 m = re.match(pattern, os.path.basename(i))
 373                                 if not m:
 374                                         continue
 375                                 on = legitimize_package_name(m.group(1))
 376                                 dependency_pkg = format % on
 377                                 dependencies.append(dependency_pkg)
 378                         return dependencies
 379                 return []
 380
 381         def frob_metadata(file, pkg, pattern, format, basename):
 382                 import re
 383                 vals = extract_modinfo(file)
 384
 385                 dvar = bb.data.getVar('D', d, 1)
 386
 387                 # If autoloading is requested, output /etc/modutils/<name> and append
 388                 # appropriate modprobe commands to the postinst
 389                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 390                 if not autoload:
 391                     # Also, try canonical name with dashes
 392                     autoload = bb.data.getVar('module_autoload_%s' % basename.replace('_', '-'), d, 1)
 393                 if autoload:
 394                         name = '%s/etc/modutils/%s' % (dvar, basename)
 395                         f = open(name, 'w')
 396                         for m in autoload.split():
 397                                 f.write('%s\n' % m)
 398                         f.close()
 399                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 400                         if not postinst:
 401                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 402                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 403                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 404
 405                 # Write out any modconf fragment
 406                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 407                 if modconf:
 408                         if bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1) == "2.6":
 409                                 name = '%s/etc/modprobe.d/%s.conf' % (dvar, basename)
 410                         else:
 411                                 name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 412                         f = open(name, 'w')
 413                         f.write("%s\n" % modconf)
 414                         f.close()
 415
 416                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 417                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf /etc/modprobe.d/%s.conf" % (files, basename, basename, basename)
 418                 bb.data.setVar('FILES_%s' % pkg, files, d)
 419
 420                 if vals.has_key("description"):
 421                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 422                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 423
 424                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 425                 if rdepends_str:
 426                         rdepends = rdepends_str.split()
 427                 else:
 428                         rdepends = []
 429                 rdepends.extend(get_dependencies(file, pattern, format))
 430                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 431
 432         module_deps = parse_depmod()
 433         module_regex = '^(.*)\.k?o$'
 434         module_pattern = 'kernel-module-%s'
 435
 436         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 437         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 438
 439         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.bin$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 440         do_split_packages(d, root='/lib/firmware', file_regex='^(.*)\.fw$', output_pattern='kernel-firmware-%s', description='Firmware for %s', recursive=True, extra_depends='')
 441         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='update-modules kernel-%s' % bb.data.getVar("KERNEL_VERSION", d, 1))
 442
 443         import re, os
 444         metapkg = "kernel-modules"
 445         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 446         bb.data.setVar('FILES_' + metapkg, "", d)
 447         blacklist = [ 'kernel-dev', 'kernel-image', 'kernel-base', 'kernel-vmlinux' ]
 448         for l in module_deps.values():
 449                 for i in l:
 450                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 451                         blacklist.append(pkg)
 452         metapkg_rdepends = []
 453         packages = bb.data.getVar('PACKAGES', d, 1).split()
 454         for pkg in packages[1:]:
 455                 if not pkg in blacklist and not pkg in metapkg_rdepends:
 456                         metapkg_rdepends.append(pkg)
 457         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
 458         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 459         packages.append(metapkg)
 460         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 461 }
 462
 463 # Support checking the kernel size since some kernels need to reside in partitions
 464 # with a fixed length or there is a limit in transferring the kernel to memory
 465 do_sizecheck() {
 466         if [ ! -z "${KERNEL_IMAGE_MAXSIZE}" -a -z "${DONT_CHECK_KERNELSIZE}" ]; then
 467                 size=`ls -l ${KERNEL_OUTPUT} | awk '{ print $5}'`
 468                 if [ $size -ge ${KERNEL_IMAGE_MAXSIZE} ]; then
 469                         rm ${KERNEL_OUTPUT}
 470                         die  "This kernel (size=$size > ${KERNEL_IMAGE_MAXSIZE}) is too big for your device. Please reduce the size of the kernel by making more of it modular."
 471                 fi
 472         fi
 473 }
 474
 475 addtask sizecheck before do_install after do_compile
 476
 477 KERNEL_IMAGE_BASE_NAME ?= "${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}"
 478 KERNEL_IMAGE_SYMLINK_NAME ?= "${KERNEL_IMAGETYPE}-${MACHINE}"
 479
 480 do_deploy() {
 481         install -d ${DEPLOY_DIR_IMAGE}
 482         install -m 0644 ${KERNEL_OUTPUT} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 483         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 484
 485         if [ -d "${D}/lib" ]; then
 486         tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${PV}-${PR}-${MACHINE}.tgz -C ${D} lib
 487         fi
 488
 489         if test "x${KERNEL_IMAGETYPE}" = "xuImage" ; then
 490                 if test -e arch/${ARCH}/boot/compressed/vmlinux ; then
 491                         ${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
 492                         uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C none -a ${UBOOT_LOADADDRESS} -e ${UBOOT_ENTRYPOINT} -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 493                         rm -f linux.bin
 494                 else
 495                         ${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
 496                         rm -f linux.bin.gz
 497                         gzip -9 linux.bin
 498                         uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C gzip -a ${UBOOT_LOADADDRESS} -e ${UBOOT_ENTRYPOINT} -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 499                         rm -f linux.bin.gz
 500                 fi
 501                 package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 502         fi
 503
 504         cd ${DEPLOY_DIR_IMAGE}
 505         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 506         ln -sf ${KERNEL_IMAGE_BASE_NAME}.bin ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 507         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.bin
 508 }
 509
 510 do_deploy[dirs] = "${S}"
 511
 512 addtask deploy before do_package after do_install