code.vuplus.com Git - vuplus_openembedded/blob - classes/kernel.bbclass

   1 inherit linux-kernel-base module_strip
   2
   3 PROVIDES += "virtual/kernel"
   4 DEPENDS += "virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules"
   5
   6 KERNEL_IMAGETYPE ?= "zImage"
   7
   8 # Add dependency on mkimage for kernels that build a uImage
   9
  10 python __anonymous () {
  11
  12     import bb
  13
  14     kerneltype = bb.data.getVar('KERNEL_IMAGETYPE', d, 1) or ''
  15     if kerneltype == 'uImage':
  16         depends = bb.data.getVar("DEPENDS", d, 1)
  17         depends = "%s u-boot-mkimage-openmoko-native" % depends
  18         bb.data.setVar("DEPENDS", depends, d)
  19
  20     image = bb.data.getVar('INITRAMFS_IMAGE', d, True)
  21     if image != '' and image is not None:
  22         bb.data.setVar('INITRAMFS_TASK', '${INITRAMFS_IMAGE}:do_rootfs', d)
  23 }
  24
  25 INITRAMFS_IMAGE ?= ""
  26 INITRAMFS_TASK ?= ""
  27
  28 inherit kernel-arch
  29
  30 PACKAGES_DYNAMIC += "kernel-module-*"
  31 PACKAGES_DYNAMIC += "kernel-image-*"
  32
  33 export OS = "${TARGET_OS}"
  34 export CROSS_COMPILE = "${TARGET_PREFIX}"
  35
  36 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  37
  38 KERNEL_RELEASE ?= "${KERNEL_VERSION}"
  39
  40 KERNEL_CCSUFFIX ?= ""
  41 KERNEL_LDSUFFIX ?= ""
  42
  43 # Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
  44 # specific options necessary for building the kernel and modules.
  45 #FIXME: should be this: TARGET_CC_KERNEL_ARCH ?= "${TARGET_CC_ARCH}"
  46 TARGET_CC_KERNEL_ARCH ?= ""
  47 HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
  48 TARGET_LD_KERNEL_ARCH ?= ""
  49 HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
  50
  51 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX} ${HOST_CC_KERNEL_ARCH}"
  52 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX} ${HOST_LD_KERNEL_ARCH}"
  53
  54 # Where built kernel lies in the kernel tree
  55 KERNEL_OUTPUT ?= "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  56 KERNEL_IMAGEDEST = "boot"
  57
  58 #
  59 # configuration
  60 #
  61 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  62
  63 KERNEL_VERSION = "${@get_kernelversion('${S}')}"
  64 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  65
  66 KERNEL_LOCALVERSION ?= ""
  67
  68 # kernels are generally machine specific
  69 PACKAGE_ARCH = "${MACHINE_ARCH}"
  70
  71 # U-Boot support
  72 UBOOT_ENTRYPOINT ?= "20008000"
  73 UBOOT_LOADADDRESS ?= "${UBOOT_ENTRYPOINT}"
  74
  75 kernel_do_compile() {
  76         if [ ! -z "${INITRAMFS_IMAGE}" ]; then
  77                 cp "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.cpio.gz" initramfs.cpio.gz
  78         fi
  79         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
  80         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  81         if [ "${KERNEL_MAJOR_VERSION}" != "2.6" ]; then
  82                 oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  83         fi
  84         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  85         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  86                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  87         else
  88                 oenote "no modules to compile"
  89         fi
  90 }
  91 kernel_do_compile[depends] = "${INITRAMFS_TASK}"
  92
  93
  94 kernel_do_stage() {
  95         ASMDIR=`readlink include/asm`
  96
  97         mkdir -p ${STAGING_KERNEL_DIR}/include/$ASMDIR
  98         cp -fR include/$ASMDIR/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
  99         rm -f $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 100         ln -sf $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 101
 102         mkdir -p ${STAGING_KERNEL_DIR}/include/asm-generic
 103         cp -fR include/asm-generic/* ${STAGING_KERNEL_DIR}/include/asm-generic/
 104
 105         mkdir -p ${STAGING_KERNEL_DIR}/include/linux
 106         cp -fR include/linux/* ${STAGING_KERNEL_DIR}/include/linux/
 107
 108         mkdir -p ${STAGING_KERNEL_DIR}/include/net
 109         cp -fR include/net/* ${STAGING_KERNEL_DIR}/include/net/
 110
 111         mkdir -p ${STAGING_KERNEL_DIR}/include/pcmcia
 112         cp -fR include/pcmcia/* ${STAGING_KERNEL_DIR}/include/pcmcia/
 113
 114         for entry in drivers/crypto include/media include/acpi include/sound include/video; do
 115                 if [ -d $entry ]; then
 116                         mkdir -p ${STAGING_KERNEL_DIR}/$entry
 117                         cp -fR $entry/* ${STAGING_KERNEL_DIR}/$entry/
 118                 fi
 119         done
 120
 121         if [ -d drivers/sound ]; then
 122                 # 2.4 alsa needs some headers from this directory
 123                 mkdir -p ${STAGING_KERNEL_DIR}/include/drivers/sound
 124                 cp -fR drivers/sound/*.h ${STAGING_KERNEL_DIR}/include/drivers/sound/
 125         fi
 126
 127         install -m 0644 .config ${STAGING_KERNEL_DIR}/config-${KERNEL_VERSION}
 128         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/.config
 129         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/kernel-config
 130         echo "${KERNEL_VERSION}" >${STAGING_KERNEL_DIR}/kernel-abiversion
 131         echo "${S}" >${STAGING_KERNEL_DIR}/kernel-source
 132         echo "${KERNEL_CCSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ccsuffix
 133         echo "${KERNEL_LDSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ldsuffix
 134         [ -e Rules.make ] && install -m 0644 Rules.make ${STAGING_KERNEL_DIR}/
 135         [ -e Makefile ] && install -m 0644 Makefile ${STAGING_KERNEL_DIR}/
 136
 137         # Check if arch/${ARCH}/Makefile exists and install it
 138         if [ -e arch/${ARCH}/Makefile ]; then
 139                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}
 140                 install -m 0644 arch/${ARCH}/Makefile* ${STAGING_KERNEL_DIR}/arch/${ARCH}
 141         # Otherwise check arch/x86/Makefile for i386 and x86_64 on kernels >= 2.6.24
 142         elif [ -e arch/x86/Makefile ]; then
 143                 install -d ${STAGING_KERNEL_DIR}/arch/x86
 144                 install -m 0644 arch/x86/Makefile* ${STAGING_KERNEL_DIR}/arch/x86
 145         fi
 146         cp -fR include/config* ${STAGING_KERNEL_DIR}/include/
 147         # Install kernel images and system.map to staging
 148         [ -e vmlinux ] && install -m 0644 vmlinux ${STAGING_KERNEL_DIR}/
 149         install -m 0644 ${KERNEL_OUTPUT} ${STAGING_KERNEL_DIR}/${KERNEL_IMAGETYPE}
 150         install -m 0644 System.map ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION}
 151         [ -e Module.symvers ] && install -m 0644 Module.symvers ${STAGING_KERNEL_DIR}/
 152
 153         cp -fR scripts ${STAGING_KERNEL_DIR}/
 154 }
 155
 156 kernel_do_install() {
 157         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 158         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 159                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 160         else
 161                 oenote "no modules to install"
 162         fi
 163
 164         install -d ${D}/${KERNEL_IMAGEDEST}
 165         install -d ${D}/boot
 166         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION}
 167         install -m 0644 System.map ${D}/boot/System.map-${KERNEL_VERSION}
 168         install -m 0644 .config ${D}/boot/config-${KERNEL_VERSION}
 169         install -m 0644 vmlinux ${D}/boot/vmlinux-${KERNEL_VERSION}
 170         install -d ${D}/etc/modutils
 171         if [ "${KERNEL_MAJOR_VERSION}" = "2.6" ]; then
 172                 install -d ${D}/etc/modprobe.d
 173         fi
 174
 175         # Check if scripts/genksyms exists and if so, build it
 176         if [ -e scripts/genksyms/ ]; then
 177                 oe_runmake SUBDIRS="scripts/genksyms"
 178         fi
 179
 180         install -d ${STAGING_KERNEL_DIR}
 181         cp -fR scripts ${STAGING_KERNEL_DIR}/
 182 }
 183
 184 kernel_do_configure() {
 185         yes '' | oe_runmake oldconfig
 186 }
 187
 188 do_menuconfig() {
 189         export TERMWINDOWTITLE="${PN} Kernel Configuration"
 190         export SHELLCMDS="make menuconfig"
 191         ${TERMCMDRUN}
 192         if [ $? -ne 0 ]; then
 193                 echo "Fatal: '${TERMCMD}' not found. Check TERMCMD variable."
 194                 exit 1
 195         fi
 196 }
 197 do_menuconfig[nostamp] = "1"
 198 addtask menuconfig after do_patch
 199
 200 pkg_postinst_kernel () {
 201         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 202 }
 203
 204 pkg_postrm_kernel () {
 205         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} || true
 206 }
 207
 208 inherit cml1
 209
 210 EXPORT_FUNCTIONS do_compile do_install do_stage do_configure
 211
 212 # kernel-base becomes kernel-${KERNEL_VERSION}
 213 # kernel-image becomes kernel-image-${KERNEL_VERISON}
 214 PACKAGES = "kernel kernel-base kernel-image kernel-dev kernel-vmlinux"
 215 FILES = ""
 216 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 217 FILES_kernel-dev = "/boot/System.map* /boot/config*"
 218 FILES_kernel-vmlinux = "/boot/vmlinux*"
 219 RDEPENDS_kernel = "kernel-base"
 220 RRECOMMENDS_kernel-module-hostap-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 221 RRECOMMENDS_kernel-module-orinoco-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 222 # Allow machines to override this dependency if kernel image files are
 223 # not wanted in images as standard
 224 RDEPENDS_kernel-base ?= "kernel-image"
 225 PKG_kernel-image = "kernel-image-${KERNEL_VERSION}"
 226 PKG_kernel-base = "kernel-${KERNEL_VERSION}"
 227 ALLOW_EMPTY_kernel = "1"
 228 ALLOW_EMPTY_kernel-base = "1"
 229 ALLOW_EMPTY_kernel-image = "1"
 230
 231 # Userspace workarounds for kernel modules issues
 232 # This is shame, fix the kernel instead!
 233 DEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 234 RDEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 235
 236 # renamed modules
 237 RPROVIDES_kernel-module-aes-generic = "kernel-module-aes"
 238
 239 pkg_postinst_kernel-image () {
 240 if [ ! -e "$D/lib/modules/${KERNEL_VERSION}" ]; then
 241         mkdir -p $D/lib/modules/${KERNEL_VERSION}
 242 fi
 243 if [ -n "$D" ]; then
 244         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 245 else
 246         depmod -a
 247 fi
 248 }
 249
 250 pkg_postinst_modules () {
 251 if [ -n "$D" ]; then
 252         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 253 else
 254         depmod -a
 255         update-modules || true
 256 fi
 257 }
 258
 259 pkg_postrm_modules () {
 260 update-modules || true
 261 }
 262
 263 autoload_postinst_fragment() {
 264 if [ x"$D" = "x" ]; then
 265         modprobe %s || true
 266 fi
 267 }
 268
 269 # autoload defaults (alphabetically sorted)
 270 module_autoload_hidp = "hidp"
 271 module_autoload_ipv6 = "ipv6"
 272 module_autoload_ipsec = "ipsec"
 273 module_autoload_ircomm-tty = "ircomm-tty"
 274 module_autoload_rfcomm = "rfcomm"
 275 module_autoload_sa1100-rtc = "sa1100-rtc"
 276 # sa1100-rtc was renamed in 2.6.23 onwards
 277 module_autoload_rtc-sa1100 = "rtc-sa1100"
 278
 279 # alias defaults (alphabetically sorted)
 280 module_conf_af_packet = "alias net-pf-17 af_packet"
 281 module_conf_bluez = "alias net-pf-31 bluez"
 282 module_conf_bnep = "alias bt-proto-4 bnep"
 283 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 284 module_conf_l2cap = "alias bt-proto-0 l2cap"
 285 module_conf_sco = "alias bt-proto-2 sco"
 286 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 287
 288 python populate_packages_prepend () {
 289         def extract_modinfo(file):
 290                 import os, re
 291                 tmpfile = os.tmpnam()
 292                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 293                 os.system(cmd)
 294                 f = open(tmpfile)
 295                 l = f.read().split("\000")
 296                 f.close()
 297                 os.unlink(tmpfile)
 298                 exp = re.compile("([^=]+)=(.*)")
 299                 vals = {}
 300                 for i in l:
 301                         m = exp.match(i)
 302                         if not m:
 303                                 continue
 304                         vals[m.group(1)] = m.group(2)
 305                 return vals
 306
 307         def parse_depmod():
 308                 import os, re
 309
 310                 dvar = bb.data.getVar('D', d, 1)
 311                 if not dvar:
 312                         bb.error("D not defined")
 313                         return
 314
 315                 kernelver = bb.data.getVar('KERNEL_VERSION', d, 1)
 316                 kernelver_stripped = kernelver
 317                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 318                 if m:
 319                         kernelver_stripped = m.group(1)
 320                 path = bb.data.getVar("PATH", d, 1)
 321                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 322                 major_version = bb.data.getVar('KERNEL_MAJOR_VERSION', d, 1)
 323
 324                 cmd = "PATH=\"%s\" %sdepmod-%s -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, major_version, dvar, dvar, kernelver, kernelver_stripped)
 325                 f = os.popen(cmd, 'r')
 326
 327                 deps = {}
 328                 pattern0 = "^(.*\.k?o):..*$"
 329                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 330                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 331                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 332                 pattern4 = "^\t(.*\.k?o)\s*$"
 333
 334                 line = f.readline()
 335                 while line:
 336                         if not re.match(pattern0, line):
 337                                 line = f.readline()
 338                                 continue
 339                         m1 = re.match(pattern1, line)
 340                         if m1:
 341                                 deps[m1.group(1)] = m1.group(2).split()
 342                         else:
 343                                 m2 = re.match(pattern2, line)
 344                                 if m2:
 345                                         deps[m2.group(1)] = m2.group(2).split()
 346                                         line = f.readline()
 347                                         m3 = re.match(pattern3, line)
 348                                         while m3:
 349                                                 deps[m2.group(1)].extend(m3.group(1).split())
 350                                                 line = f.readline()
 351                                                 m3 = re.match(pattern3, line)
 352                                         m4 = re.match(pattern4, line)
 353                                         deps[m2.group(1)].extend(m4.group(1).split())
 354                         line = f.readline()
 355                 f.close()
 356                 return deps
 357
 358         def get_dependencies(file, pattern, format):
 359                 file = file.replace(bb.data.getVar('D', d, 1) or '', '', 1)
 360
 361                 if module_deps.has_key(file):
 362                         import os.path, re
 363                         dependencies = []
 364                         for i in module_deps[file]:
 365                                 m = re.match(pattern, os.path.basename(i))
 366                                 if not m:
 367                                         continue
 368                                 on = legitimize_package_name(m.group(1))
 369                                 dependency_pkg = format % on
 370                                 dependencies.append(dependency_pkg)
 371                         return dependencies
 372                 return []
 373
 374         def frob_metadata(file, pkg, pattern, format, basename):
 375                 import re
 376                 vals = extract_modinfo(file)
 377
 378                 dvar = bb.data.getVar('D', d, 1)
 379
 380                 # If autoloading is requested, output /etc/modutils/<name> and append
 381                 # appropriate modprobe commands to the postinst
 382                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 383                 if not autoload:
 384                     # Also, try canonical name with dashes
 385                     autoload = bb.data.getVar('module_autoload_%s' % basename.replace('_', '-'), d, 1)
 386                 if autoload:
 387                         name = '%s/etc/modutils/%s' % (dvar, basename)
 388                         f = open(name, 'w')
 389                         for m in autoload.split():
 390                                 f.write('%s\n' % m)
 391                         f.close()
 392                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 393                         if not postinst:
 394                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 395                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 396                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 397
 398                 # Write out any modconf fragment
 399                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 400                 if modconf:
 401                         if bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1) == "2.6":
 402                                 name = '%s/etc/modprobe.d/%s.conf' % (dvar, basename)
 403                         else:
 404                                 name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 405                         f = open(name, 'w')
 406                         f.write("%s\n" % modconf)
 407                         f.close()
 408
 409                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 410                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf /etc/modprobe.d/%s.conf" % (files, basename, basename, basename)
 411                 bb.data.setVar('FILES_%s' % pkg, files, d)
 412
 413                 if vals.has_key("description"):
 414                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 415                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 416
 417                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 418                 if rdepends_str:
 419                         rdepends = rdepends_str.split()
 420                 else:
 421                         rdepends = []
 422                 rdepends.extend(get_dependencies(file, pattern, format))
 423                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 424
 425         module_deps = parse_depmod()
 426         module_regex = '^(.*)\.k?o$'
 427         module_pattern = 'kernel-module-%s'
 428
 429         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 430         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 431         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='update-modules kernel-%s' % bb.data.getVar("KERNEL_VERSION", d, 1))
 432
 433         import re, os
 434         metapkg = "kernel-modules"
 435         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 436         bb.data.setVar('FILES_' + metapkg, "", d)
 437         blacklist = [ 'kernel-dev', 'kernel-image', 'kernel-base', 'kernel-vmlinux' ]
 438         for l in module_deps.values():
 439                 for i in l:
 440                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 441                         blacklist.append(pkg)
 442         metapkg_rdepends = []
 443         packages = bb.data.getVar('PACKAGES', d, 1).split()
 444         for pkg in packages[1:]:
 445                 if not pkg in blacklist and not pkg in metapkg_rdepends:
 446                         metapkg_rdepends.append(pkg)
 447         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
 448         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 449         packages.append(metapkg)
 450         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 451 }
 452
 453 # Support checking the kernel size since some kernels need to reside in partitions
 454 # with a fixed length or there is a limit in transferring the kernel to memory
 455 do_sizecheck() {
 456         if [ ! -z "${KERNEL_IMAGE_MAXSIZE}" -a -z "${DONT_CHECK_KERNELSIZE}" ]; then
 457                 size=`ls -l ${KERNEL_OUTPUT} | awk '{ print $5}'`
 458                 if [ $size -ge ${KERNEL_IMAGE_MAXSIZE} ]; then
 459                         rm ${KERNEL_OUTPUT}
 460                         die  "This kernel (size=$size > ${KERNEL_IMAGE_MAXSIZE}) is too big for your device. Please reduce the size of the kernel by making more of it modular."
 461                 fi
 462         fi
 463 }
 464
 465 addtask sizecheck before do_install after do_compile
 466
 467 KERNEL_IMAGE_BASE_NAME ?= "${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}"
 468 KERNEL_IMAGE_SYMLINK_NAME ?= "${KERNEL_IMAGETYPE}-${MACHINE}"
 469
 470 do_deploy() {
 471         install -d ${DEPLOY_DIR_IMAGE}
 472         install -m 0644 ${KERNEL_OUTPUT} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 473         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 474
 475         if [ -d "${D}/lib" ]; then
 476         tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${PV}-${PR}-${MACHINE}.tgz -C ${D} lib
 477         fi
 478
 479         if test "x${KERNEL_IMAGETYPE}" = "xuImage" ; then
 480                 if test -e arch/${ARCH}/boot/compressed/vmlinux ; then
 481                         ${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
 482                         uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C none -a ${UBOOT_LOADADDRESS} -e ${UBOOT_ENTRYPOINT} -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 483                         rm -f linux.bin
 484                 else
 485                         ${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
 486                         rm -f linux.bin.gz
 487                         gzip -9 linux.bin
 488                         uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C gzip -a ${UBOOT_LOADADDRESS} -e ${UBOOT_ENTRYPOINT} -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 489                         rm -f linux.bin.gz
 490                 fi
 491                 package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 492         fi
 493
 494         cd ${DEPLOY_DIR_IMAGE}
 495         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 496         ln -sf ${KERNEL_IMAGE_BASE_NAME}.bin ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 497         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.bin
 498 }
 499
 500 do_deploy[dirs] = "${S}"
 501
 502 addtask deploy before do_package after do_install