code.vuplus.com Git - vuplus_openembedded/blob - classes/kernel.bbclass

   1 inherit linux-kernel-base module_strip
   2
   3 PROVIDES += "virtual/kernel"
   4 DEPENDS += "virtual/${TARGET_PREFIX}depmod-${@get_kernelmajorversion('${PV}')} virtual/${TARGET_PREFIX}gcc${KERNEL_CCSUFFIX} update-modules"
   5
   6 KERNEL_IMAGETYPE ?= "zImage"
   7
   8 # Add dependency on mkimage for kernels that build a uImage
   9
  10 python __anonymous () {
  11
  12     import bb
  13
  14     kerneltype = bb.data.getVar('KERNEL_IMAGETYPE', d, 1) or ''
  15     if kerneltype == 'uImage':
  16         depends = bb.data.getVar("DEPENDS", d, 1)
  17         depends = "%s u-boot-mkimage-openmoko-native" % depends
  18         bb.data.setVar("DEPENDS", depends, d)
  19
  20     image = bb.data.getVar('INITRAMFS_IMAGE', d, True)
  21     if image != '' and image is not None:
  22         bb.data.setVar('INITRAMFS_TASK', '${INITRAMFS_IMAGE}:do_rootfs', d)
  23 }
  24
  25 INITRAMFS_IMAGE ?= ""
  26 INITRAMFS_TASK ?= ""
  27
  28 inherit kernel-arch
  29
  30 PACKAGES_DYNAMIC += "kernel-module-*"
  31 PACKAGES_DYNAMIC += "kernel-image-*"
  32
  33 export OS = "${TARGET_OS}"
  34 export CROSS_COMPILE = "${TARGET_PREFIX}"
  35
  36 KERNEL_PRIORITY = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[-1]}"
  37
  38 KERNEL_RELEASE ?= "${KERNEL_VERSION}"
  39
  40 KERNEL_CCSUFFIX ?= ""
  41 KERNEL_LDSUFFIX ?= ""
  42
  43 # Set TARGET_??_KERNEL_ARCH in the machine .conf to set architecture
  44 # specific options necessary for building the kernel and modules.
  45 #FIXME: should be this: TARGET_CC_KERNEL_ARCH ?= "${TARGET_CC_ARCH}"
  46 TARGET_CC_KERNEL_ARCH ?= ""
  47 HOST_CC_KERNEL_ARCH ?= "${TARGET_CC_KERNEL_ARCH}"
  48 TARGET_LD_KERNEL_ARCH ?= ""
  49 HOST_LD_KERNEL_ARCH ?= "${TARGET_LD_KERNEL_ARCH}"
  50
  51 KERNEL_CC = "${CCACHE}${HOST_PREFIX}gcc${KERNEL_CCSUFFIX} ${HOST_CC_KERNEL_ARCH}"
  52 KERNEL_LD = "${LD}${KERNEL_LDSUFFIX} ${HOST_LD_KERNEL_ARCH}"
  53
  54 # Where built kernel lies in the kernel tree
  55 KERNEL_OUTPUT = "arch/${ARCH}/boot/${KERNEL_IMAGETYPE}"
  56 KERNEL_IMAGEDEST = "boot"
  57
  58 #
  59 # configuration
  60 #
  61 export CMDLINE_CONSOLE = "console=${@bb.data.getVar("KERNEL_CONSOLE",d,1) or "ttyS0"}"
  62
  63 KERNEL_VERSION = "${@get_kernelversion('${S}')}"
  64 KERNEL_MAJOR_VERSION = "${@get_kernelmajorversion('${KERNEL_VERSION}')}"
  65
  66 KERNEL_LOCALVERSION ?= ""
  67
  68 # kernels are generally machine specific
  69 PACKAGE_ARCH = "${MACHINE_ARCH}"
  70
  71 # U-Boot support
  72 UBOOT_ENTRYPOINT ?= "20008000"
  73 UBOOT_LOADADDRESS ?= "${UBOOT_ENTRYPOINT}"
  74
  75 kernel_do_compile() {
  76         if [ ! -z "${INITRAMFS_IMAGE}" ]; then
  77                 cp "${DEPLOY_DIR_IMAGE}/${INITRAMFS_IMAGE}-${MACHINE}.cpio.gz" initramfs.cpio.gz
  78         fi
  79         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
  80         oe_runmake include/linux/version.h CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  81         if [ "${KERNEL_MAJOR_VERSION}" != "2.6" ]; then
  82                 oe_runmake dep CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  83         fi
  84         oe_runmake ${KERNEL_IMAGETYPE} CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  85         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
  86                 oe_runmake modules  CC="${KERNEL_CC}" LD="${KERNEL_LD}"
  87         else
  88                 oenote "no modules to compile"
  89         fi
  90 }
  91 kernel_do_compile[depends] = "${INITRAMFS_TASK}"
  92
  93
  94 kernel_do_stage() {
  95         ASMDIR=`readlink include/asm`
  96
  97         mkdir -p ${STAGING_KERNEL_DIR}/include/$ASMDIR
  98         cp -fR include/$ASMDIR/* ${STAGING_KERNEL_DIR}/include/$ASMDIR/
  99         rm -f $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 100         ln -sf $ASMDIR ${STAGING_KERNEL_DIR}/include/asm
 101
 102         mkdir -p ${STAGING_KERNEL_DIR}/include/asm-generic
 103         cp -fR include/asm-generic/* ${STAGING_KERNEL_DIR}/include/asm-generic/
 104
 105         mkdir -p ${STAGING_KERNEL_DIR}/include/linux
 106         cp -fR include/linux/* ${STAGING_KERNEL_DIR}/include/linux/
 107
 108         mkdir -p ${STAGING_KERNEL_DIR}/include/net
 109         cp -fR include/net/* ${STAGING_KERNEL_DIR}/include/net/
 110
 111         mkdir -p ${STAGING_KERNEL_DIR}/include/pcmcia
 112         cp -fR include/pcmcia/* ${STAGING_KERNEL_DIR}/include/pcmcia/
 113
 114         for entry in drivers/crypto include/media include/acpi include/sound include/video; do
 115                 if [ -d $entry ]; then
 116                         mkdir -p ${STAGING_KERNEL_DIR}/$entry
 117                         cp -fR $entry/* ${STAGING_KERNEL_DIR}/$entry/
 118                 fi
 119         done
 120
 121         if [ -d drivers/sound ]; then
 122                 # 2.4 alsa needs some headers from this directory
 123                 mkdir -p ${STAGING_KERNEL_DIR}/include/drivers/sound
 124                 cp -fR drivers/sound/*.h ${STAGING_KERNEL_DIR}/include/drivers/sound/
 125         fi
 126
 127         install -m 0644 .config ${STAGING_KERNEL_DIR}/config-${KERNEL_VERSION}
 128         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/.config
 129         ln -sf config-${KERNEL_VERSION} ${STAGING_KERNEL_DIR}/kernel-config
 130         echo "${KERNEL_VERSION}" >${STAGING_KERNEL_DIR}/kernel-abiversion
 131         echo "${S}" >${STAGING_KERNEL_DIR}/kernel-source
 132         echo "${KERNEL_CCSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ccsuffix
 133         echo "${KERNEL_LDSUFFIX}" >${STAGING_KERNEL_DIR}/kernel-ldsuffix
 134         [ -e Rules.make ] && install -m 0644 Rules.make ${STAGING_KERNEL_DIR}/
 135         [ -e Makefile ] && install -m 0644 Makefile ${STAGING_KERNEL_DIR}/
 136
 137         # Check if arch/${ARCH}/Makefile exists and install it
 138         if [ -e arch/${ARCH}/Makefile ]; then
 139                 install -d ${STAGING_KERNEL_DIR}/arch/${ARCH}
 140                 install -m 0644 arch/${ARCH}/Makefile* ${STAGING_KERNEL_DIR}/arch/${ARCH}
 141         # Otherwise check arch/x86/Makefile for i386 and x86_64 on kernels >= 2.6.24
 142         elif [ -e arch/x86/Makefile ]; then
 143                 install -d ${STAGING_KERNEL_DIR}/arch/x86
 144                 install -m 0644 arch/x86/Makefile* ${STAGING_KERNEL_DIR}/arch/x86
 145         fi
 146         cp -fR include/config* ${STAGING_KERNEL_DIR}/include/
 147         # Install kernel images and system.map to staging
 148         [ -e vmlinux ] && install -m 0644 vmlinux ${STAGING_KERNEL_DIR}/
 149         install -m 0644 ${KERNEL_OUTPUT} ${STAGING_KERNEL_DIR}/${KERNEL_IMAGETYPE}
 150         install -m 0644 System.map ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION}
 151         [ -e Module.symvers ] && install -m 0644 Module.symvers ${STAGING_KERNEL_DIR}/
 152
 153         cp -fR scripts ${STAGING_KERNEL_DIR}/
 154 }
 155
 156 kernel_do_install() {
 157         unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS MACHINE
 158         if (grep -q -i -e '^CONFIG_MODULES=y$' .config); then
 159                 oe_runmake DEPMOD=echo INSTALL_MOD_PATH="${D}" modules_install
 160         else
 161                 oenote "no modules to install"
 162         fi
 163
 164         install -d ${D}/${KERNEL_IMAGEDEST}
 165         install -d ${D}/boot
 166         install -m 0644 ${KERNEL_OUTPUT} ${D}/${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE}-${KERNEL_VERSION}
 167         install -m 0644 System.map ${D}/boot/System.map-${KERNEL_VERSION}
 168         install -m 0644 .config ${D}/boot/config-${KERNEL_VERSION}
 169         install -m 0644 vmlinux ${D}/boot/vmlinux-${KERNEL_VERSION}
 170         install -d ${D}/etc/modutils
 171         if [ "${KERNEL_MAJOR_VERSION}" = "2.6" ]; then
 172                 install -d ${D}/etc/modprobe.d
 173         fi
 174
 175         # Check if scripts/genksyms exists and if so, build it
 176         if [ -e scripts/genksyms/ ]; then
 177                 oe_runmake SUBDIRS="scripts/genksyms"
 178         fi
 179
 180         install -d ${STAGING_KERNEL_DIR}
 181         cp -fR scripts ${STAGING_KERNEL_DIR}/
 182 }
 183
 184 kernel_do_configure() {
 185         yes '' | oe_runmake oldconfig
 186 }
 187
 188 do_menuconfig() {
 189         export TERMWINDOWTITLE="${PN} Kernel Configuration"
 190         export SHELLCMDS="make menuconfig"
 191         ${TERMCMDRUN}
 192         if [ $? -ne 0 ]; then
 193                 echo "Fatal: '${TERMCMD}' not found. Check TERMCMD variable."
 194                 exit 1
 195         fi
 196 }
 197 do_menuconfig[nostamp] = "1"
 198 addtask menuconfig after do_patch
 199
 200 pkg_postinst_kernel () {
 201         cd /${KERNEL_IMAGEDEST}; update-alternatives --install /${KERNEL_IMAGEDEST}/${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} ${KERNEL_PRIORITY} || true
 202 }
 203
 204 pkg_postrm_kernel () {
 205         cd /${KERNEL_IMAGEDEST}; update-alternatives --remove ${KERNEL_IMAGETYPE} ${KERNEL_IMAGETYPE}-${KERNEL_VERSION} || true
 206 }
 207
 208 inherit cml1
 209
 210 EXPORT_FUNCTIONS do_compile do_install do_stage do_configure
 211
 212 # kernel-base becomes kernel-${KERNEL_VERSION}
 213 # kernel-image becomes kernel-image-${KERNEL_VERISON}
 214 PACKAGES = "kernel kernel-base kernel-image kernel-dev kernel-vmlinux"
 215 FILES = ""
 216 FILES_kernel-image = "/boot/${KERNEL_IMAGETYPE}*"
 217 FILES_kernel-dev = "/boot/System.map* /boot/config*"
 218 FILES_kernel-vmlinux = "/boot/vmlinux*"
 219 RDEPENDS_kernel = "kernel-base"
 220 RRECOMMENDS_kernel-module-hostap-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 221 RRECOMMENDS_kernel-module-orinoco-cs += '${@base_version_less_or_equal("KERNEL_VERSION", "2.6.17", "", "apm-wifi-suspendfix", d)}'
 222 # Allow machines to override this dependency if kernel image files are
 223 # not wanted in images as standard
 224 RDEPENDS_kernel-base ?= "kernel-image"
 225 PKG_kernel-image = "kernel-image-${KERNEL_VERSION}"
 226 PKG_kernel-base = "kernel-${KERNEL_VERSION}"
 227 ALLOW_EMPTY_kernel = "1"
 228 ALLOW_EMPTY_kernel-base = "1"
 229 ALLOW_EMPTY_kernel-image = "1"
 230
 231 # Userspace workarounds for kernel modules issues
 232 # This is shame, fix the kernel instead!
 233 DEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 234 RDEPENDS_kernel-module-dtl1-cs = "bluez-dtl1-workaround"
 235
 236 pkg_postinst_kernel-image () {
 237 if [ ! -e "$D/lib/modules/${KERNEL_VERSION}" ]; then
 238         mkdir -p $D/lib/modules/${KERNEL_VERSION}
 239 fi
 240 if [ -n "$D" ]; then
 241         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 242 else
 243         depmod -a
 244 fi
 245 }
 246
 247 pkg_postinst_modules () {
 248 if [ -n "$D" ]; then
 249         ${HOST_PREFIX}depmod-${KERNEL_MAJOR_VERSION} -A -b $D -F ${STAGING_KERNEL_DIR}/System.map-${KERNEL_VERSION} ${KERNEL_VERSION}
 250 else
 251         depmod -a
 252         update-modules || true
 253 fi
 254 }
 255
 256 pkg_postrm_modules () {
 257 update-modules || true
 258 }
 259
 260 autoload_postinst_fragment() {
 261 if [ x"$D" = "x" ]; then
 262         modprobe %s || true
 263 fi
 264 }
 265
 266 # autoload defaults (alphabetically sorted)
 267 module_autoload_hidp = "hidp"
 268 module_autoload_ipv6 = "ipv6"
 269 module_autoload_ipsec = "ipsec"
 270 module_autoload_ircomm-tty = "ircomm-tty"
 271 module_autoload_rfcomm = "rfcomm"
 272 module_autoload_sa1100-rtc = "sa1100-rtc"
 273 # sa1100-rtc was renamed in 2.6.23 onwards
 274 module_autoload_rtc-sa1100 = "rtc-sa1100"
 275
 276 # alias defaults (alphabetically sorted)
 277 module_conf_af_packet = "alias net-pf-17 af_packet"
 278 module_conf_bluez = "alias net-pf-31 bluez"
 279 module_conf_bnep = "alias bt-proto-4 bnep"
 280 module_conf_hci_uart = "alias tty-ldisc-15 hci_uart"
 281 module_conf_l2cap = "alias bt-proto-0 l2cap"
 282 module_conf_sco = "alias bt-proto-2 sco"
 283 module_conf_rfcomm = "alias bt-proto-3 rfcomm"
 284
 285 python populate_packages_prepend () {
 286         def extract_modinfo(file):
 287                 import os, re
 288                 tmpfile = os.tmpnam()
 289                 cmd = "PATH=\"%s\" %sobjcopy -j .modinfo -O binary %s %s" % (bb.data.getVar("PATH", d, 1), bb.data.getVar("HOST_PREFIX", d, 1) or "", file, tmpfile)
 290                 os.system(cmd)
 291                 f = open(tmpfile)
 292                 l = f.read().split("\000")
 293                 f.close()
 294                 os.unlink(tmpfile)
 295                 exp = re.compile("([^=]+)=(.*)")
 296                 vals = {}
 297                 for i in l:
 298                         m = exp.match(i)
 299                         if not m:
 300                                 continue
 301                         vals[m.group(1)] = m.group(2)
 302                 return vals
 303
 304         def parse_depmod():
 305                 import os, re
 306
 307                 dvar = bb.data.getVar('D', d, 1)
 308                 if not dvar:
 309                         bb.error("D not defined")
 310                         return
 311
 312                 kernelver = bb.data.getVar('KERNEL_VERSION', d, 1)
 313                 kernelver_stripped = kernelver
 314                 m = re.match('^(.*-hh.*)[\.\+].*$', kernelver)
 315                 if m:
 316                         kernelver_stripped = m.group(1)
 317                 path = bb.data.getVar("PATH", d, 1)
 318                 host_prefix = bb.data.getVar("HOST_PREFIX", d, 1) or ""
 319                 major_version = bb.data.getVar('KERNEL_MAJOR_VERSION', d, 1)
 320
 321                 cmd = "PATH=\"%s\" %sdepmod-%s -n -a -r -b %s -F %s/boot/System.map-%s %s" % (path, host_prefix, major_version, dvar, dvar, kernelver, kernelver_stripped)
 322                 f = os.popen(cmd, 'r')
 323
 324                 deps = {}
 325                 pattern0 = "^(.*\.k?o):..*$"
 326                 pattern1 = "^(.*\.k?o):\s*(.*\.k?o)\s*$"
 327                 pattern2 = "^(.*\.k?o):\s*(.*\.k?o)\s*\\\$"
 328                 pattern3 = "^\t(.*\.k?o)\s*\\\$"
 329                 pattern4 = "^\t(.*\.k?o)\s*$"
 330
 331                 line = f.readline()
 332                 while line:
 333                         if not re.match(pattern0, line):
 334                                 line = f.readline()
 335                                 continue
 336                         m1 = re.match(pattern1, line)
 337                         if m1:
 338                                 deps[m1.group(1)] = m1.group(2).split()
 339                         else:
 340                                 m2 = re.match(pattern2, line)
 341                                 if m2:
 342                                         deps[m2.group(1)] = m2.group(2).split()
 343                                         line = f.readline()
 344                                         m3 = re.match(pattern3, line)
 345                                         while m3:
 346                                                 deps[m2.group(1)].extend(m3.group(1).split())
 347                                                 line = f.readline()
 348                                                 m3 = re.match(pattern3, line)
 349                                         m4 = re.match(pattern4, line)
 350                                         deps[m2.group(1)].extend(m4.group(1).split())
 351                         line = f.readline()
 352                 f.close()
 353                 return deps
 354
 355         def get_dependencies(file, pattern, format):
 356                 file = file.replace(bb.data.getVar('D', d, 1) or '', '', 1)
 357
 358                 if module_deps.has_key(file):
 359                         import os.path, re
 360                         dependencies = []
 361                         for i in module_deps[file]:
 362                                 m = re.match(pattern, os.path.basename(i))
 363                                 if not m:
 364                                         continue
 365                                 on = legitimize_package_name(m.group(1))
 366                                 dependency_pkg = format % on
 367                                 dependencies.append(dependency_pkg)
 368                         return dependencies
 369                 return []
 370
 371         def frob_metadata(file, pkg, pattern, format, basename):
 372                 import re
 373                 vals = extract_modinfo(file)
 374
 375                 dvar = bb.data.getVar('D', d, 1)
 376
 377                 # If autoloading is requested, output /etc/modutils/<name> and append
 378                 # appropriate modprobe commands to the postinst
 379                 autoload = bb.data.getVar('module_autoload_%s' % basename, d, 1)
 380                 if not autoload:
 381                     # Also, try canonical name with dashes
 382                     autoload = bb.data.getVar('module_autoload_%s' % basename.replace('_', '-'), d, 1)
 383                 if autoload:
 384                         name = '%s/etc/modutils/%s' % (dvar, basename)
 385                         f = open(name, 'w')
 386                         for m in autoload.split():
 387                                 f.write('%s\n' % m)
 388                         f.close()
 389                         postinst = bb.data.getVar('pkg_postinst_%s' % pkg, d, 1)
 390                         if not postinst:
 391                                 bb.fatal("pkg_postinst_%s not defined" % pkg)
 392                         postinst += bb.data.getVar('autoload_postinst_fragment', d, 1) % autoload
 393                         bb.data.setVar('pkg_postinst_%s' % pkg, postinst, d)
 394
 395                 # Write out any modconf fragment
 396                 modconf = bb.data.getVar('module_conf_%s' % basename, d, 1)
 397                 if modconf:
 398                         if bb.data.getVar("KERNEL_MAJOR_VERSION", d, 1) == "2.6":
 399                                 name = '%s/etc/modprobe.d/%s.conf' % (dvar, basename)
 400                         else:
 401                                 name = '%s/etc/modutils/%s.conf' % (dvar, basename)
 402                         f = open(name, 'w')
 403                         f.write("%s\n" % modconf)
 404                         f.close()
 405
 406                 files = bb.data.getVar('FILES_%s' % pkg, d, 1)
 407                 files = "%s /etc/modutils/%s /etc/modutils/%s.conf /etc/modprobe.d/%s.conf" % (files, basename, basename, basename)
 408                 bb.data.setVar('FILES_%s' % pkg, files, d)
 409
 410                 if vals.has_key("description"):
 411                         old_desc = bb.data.getVar('DESCRIPTION_' + pkg, d, 1) or ""
 412                         bb.data.setVar('DESCRIPTION_' + pkg, old_desc + "; " + vals["description"], d)
 413
 414                 rdepends_str = bb.data.getVar('RDEPENDS_' + pkg, d, 1)
 415                 if rdepends_str:
 416                         rdepends = rdepends_str.split()
 417                 else:
 418                         rdepends = []
 419                 rdepends.extend(get_dependencies(file, pattern, format))
 420                 bb.data.setVar('RDEPENDS_' + pkg, ' '.join(rdepends), d)
 421
 422         module_deps = parse_depmod()
 423         module_regex = '^(.*)\.k?o$'
 424         module_pattern = 'kernel-module-%s'
 425
 426         postinst = bb.data.getVar('pkg_postinst_modules', d, 1)
 427         postrm = bb.data.getVar('pkg_postrm_modules', d, 1)
 428         do_split_packages(d, root='/lib/modules', file_regex=module_regex, output_pattern=module_pattern, description='%s kernel module', postinst=postinst, postrm=postrm, recursive=True, hook=frob_metadata, extra_depends='update-modules kernel-%s' % bb.data.getVar("KERNEL_VERSION", d, 1))
 429
 430         import re, os
 431         metapkg = "kernel-modules"
 432         bb.data.setVar('ALLOW_EMPTY_' + metapkg, "1", d)
 433         bb.data.setVar('FILES_' + metapkg, "", d)
 434         blacklist = [ 'kernel-dev', 'kernel-image', 'kernel-base', 'kernel-vmlinux' ]
 435         for l in module_deps.values():
 436                 for i in l:
 437                         pkg = module_pattern % legitimize_package_name(re.match(module_regex, os.path.basename(i)).group(1))
 438                         blacklist.append(pkg)
 439         metapkg_rdepends = []
 440         packages = bb.data.getVar('PACKAGES', d, 1).split()
 441         for pkg in packages[1:]:
 442                 if not pkg in blacklist and not pkg in metapkg_rdepends:
 443                         metapkg_rdepends.append(pkg)
 444         bb.data.setVar('RDEPENDS_' + metapkg, ' '.join(metapkg_rdepends), d)
 445         bb.data.setVar('DESCRIPTION_' + metapkg, 'Kernel modules meta package', d)
 446         packages.append(metapkg)
 447         bb.data.setVar('PACKAGES', ' '.join(packages), d)
 448 }
 449
 450 # Support checking the kernel size since some kernels need to reside in partitions
 451 # with a fixed length or there is a limit in transferring the kernel to memory
 452 do_sizecheck() {
 453         if [ ! -z "${KERNEL_IMAGE_MAXSIZE}" -a -z "${DONT_CHECK_KERNELSIZE}"]; then
 454                 size=`ls -l arch/${ARCH}/boot/${KERNEL_IMAGETYPE} | awk '{ print $5}'`
 455                 if [ $size -ge ${KERNEL_IMAGE_MAXSIZE} ]; then
 456                         rm arch/${ARCH}/boot/${KERNEL_IMAGETYPE}
 457                         die  "This kernel (size=$size > ${KERNEL_IMAGE_MAXSIZE}) is too big for your device. Please reduce the size of the kernel by making more of it modular."
 458                 fi
 459         fi
 460 }
 461
 462 addtask sizecheck before do_install after do_compile
 463
 464 KERNEL_IMAGE_BASE_NAME ?= "${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}"
 465 KERNEL_IMAGE_SYMLINK_NAME ?= "${KERNEL_IMAGETYPE}-${MACHINE}"
 466
 467 do_deploy() {
 468         install -d ${DEPLOY_DIR_IMAGE}
 469         install -m 0644 arch/${ARCH}/boot/${KERNEL_IMAGETYPE} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 470         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 471
 472         if [ -d "${D}/lib" ]; then
 473         tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${PV}-${PR}-${MACHINE}.tgz -C ${D} lib
 474         fi
 475
 476         if test "x${KERNEL_IMAGETYPE}" = "xuImage" ; then
 477                 if test -e arch/${ARCH}/boot/compressed/vmlinux ; then
 478                         ${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
 479                         uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C none -a ${UBOOT_LOADADDRESS} -e ${UBOOT_ENTRYPOINT} -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 480                         rm -f linux.bin
 481                 else
 482                         ${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
 483                         rm -f linux.bin.gz
 484                         gzip -9 linux.bin
 485                         uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C gzip -a ${UBOOT_LOADADDRESS} -e ${UBOOT_ENTRYPOINT} -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 486                         rm -f linux.bin.gz
 487                 fi
 488                 package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_BASE_NAME}.bin
 489         fi
 490
 491         cd ${DEPLOY_DIR_IMAGE}
 492         rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 493         ln -sf ${KERNEL_IMAGE_BASE_NAME}.bin ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 494         package_stagefile_shell ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGE_SYMLINK_NAME}.bin
 495 }
 496
 497 do_deploy[dirs] = "${S}"
 498
 499 addtask deploy before do_package after do_install