code.vuplus.com Git - vuplus_openembedded/blob - classes/image.bbclass

   1 inherit rootfs_${IMAGE_PKGTYPE}
   2
   3 LICENSE = "MIT"
   4 PACKAGES = ""
   5 RDEPENDS += "${IMAGE_INSTALL}"
   6
   7 # "export IMAGE_BASENAME" not supported at this time
   8 IMAGE_BASENAME[export] = "1"
   9 export PACKAGE_INSTALL ?= "${IMAGE_INSTALL}"
  10
  11 # We need to recursively follow RDEPENDS and RRECOMMENDS for images
  12 do_rootfs[recrdeptask] += "do_deploy do_populate_staging"
  13
  14 # Images are generally built explicitly, do not need to be part of world.
  15 EXCLUDE_FROM_WORLD = "1"
  16
  17 USE_DEVFS ?= "0"
  18
  19 PID = "${@os.getpid()}"
  20
  21 PACKAGE_ARCH = "${MACHINE_ARCH}"
  22
  23 do_rootfs[depends] += "makedevs-native:do_populate_staging fakeroot-native:do_populate_staging"
  24
  25 python () {
  26     import bb
  27
  28     deps = bb.data.getVarFlag('do_rootfs', 'depends', d) or ""
  29     for type in (bb.data.getVar('IMAGE_FSTYPES', d, True) or "").split():
  30         for dep in ((bb.data.getVar('IMAGE_DEPENDS_%s' % type, d) or "").split() or []):
  31             deps += " %s:do_populate_staging" % dep
  32     for dep in (bb.data.getVar('EXTRA_IMAGEDEPENDS', d, True) or "").split():
  33         deps += " %s:do_populate_staging" % dep
  34     bb.data.setVarFlag('do_rootfs', 'depends', deps, d)
  35 }
  36
  37 #
  38 # Get a list of files containing device tables to create.
  39 # * IMAGE_DEVICE_TABLE is the old name to an absolute path to a device table file
  40 # * IMAGE_DEVICE_TABLES is a new name for a file, or list of files, seached
  41 #   for in the BBPATH
  42 # If neither are specified then the default name of files/device_table-minimal.txt
  43 # is searched for in the BBPATH (same as the old version.)
  44 #
  45 def get_devtable_list(d):
  46         import bb
  47         devtable = bb.data.getVar('IMAGE_DEVICE_TABLE', d, 1)
  48         if devtable != None:
  49                 return devtable
  50         str = ""
  51         devtables = bb.data.getVar('IMAGE_DEVICE_TABLES', d, 1)
  52         if devtables == None:
  53                 devtables = 'files/device_table-minimal.txt'
  54         for devtable in devtables.split():
  55                 str += " %s" % bb.which(bb.data.getVar('BBPATH', d, 1), devtable)
  56         return str
  57
  58 IMAGE_POSTPROCESS_COMMAND ?= ""
  59 MACHINE_POSTPROCESS_COMMAND ?= ""
  60 ROOTFS_POSTPROCESS_COMMAND ?= ""
  61
  62 # some default locales
  63 IMAGE_LINGUAS ?= "de-de fr-fr en-gb"
  64
  65 LINGUAS_INSTALL = "${@" ".join(map(lambda s: "locale-base-%s" % s, bb.data.getVar('IMAGE_LINGUAS', d, 1).split()))}"
  66
  67 do_rootfs[nostamp] = "1"
  68 do_rootfs[dirs] = "${TOPDIR}"
  69 do_build[nostamp] = "1"
  70
  71 # Must call real_do_rootfs() from inside here, rather than as a separate
  72 # task, so that we have a single fakeroot context for the whole process.
  73 fakeroot do_rootfs () {
  74         set -x
  75         rm -rf ${IMAGE_ROOTFS}
  76         mkdir -p ${IMAGE_ROOTFS}
  77
  78         if [ "${USE_DEVFS}" != "1" ]; then
  79                 for devtable in ${@get_devtable_list(d)}; do
  80                         makedevs -r ${IMAGE_ROOTFS} -D $devtable
  81                 done
  82         fi
  83
  84         rootfs_${IMAGE_PKGTYPE}_do_rootfs
  85
  86         insert_feed_uris
  87
  88         rm -f ${IMAGE_ROOTFS}${libdir}/ipkg/lists/*
  89
  90         ${IMAGE_PREPROCESS_COMMAND}
  91
  92         export TOPDIR=${TOPDIR}
  93         export MACHINE=${MACHINE}
  94
  95         for type in ${IMAGE_FSTYPES}; do
  96                 if test -z "$FAKEROOTKEY"; then
  97                         fakeroot -i ${TMPDIR}/fakedb.image ${PYTHON} `which bbimage` -t $type -e ${FILE}
  98                 else
  99                         ${PYTHON} `which bbimage` -n "${IMAGE_NAME}" -t "$type" -e "${FILE}"
 100                 fi
 101
 102                 cd ${DEPLOY_DIR_IMAGE}/
 103                 rm -f ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.$type
 104                 ln -s ${IMAGE_NAME}.rootfs.$type ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.$type
 105         done
 106
 107         ${IMAGE_POSTPROCESS_COMMAND}
 108
 109         ${MACHINE_POSTPROCESS_COMMAND}
 110 }
 111
 112 insert_feed_uris () {
 113
 114         echo "Building feeds for [${DISTRO}].."
 115
 116         for line in ${FEED_URIS}
 117         do
 118                 # strip leading and trailing spaces/tabs, then split into name and uri
 119                 line_clean="`echo "$line"|sed 's/^[ \t]*//;s/[ \t]*$//'`"
 120                 feed_name="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\1/p'`"
 121                 feed_uri="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\2/p'`"
 122
 123                 echo "Added $feed_name feed with URL $feed_uri"
 124
 125                 # insert new feed-sources
 126                 echo "src/gz $feed_name $feed_uri" >> ${IMAGE_ROOTFS}/etc/ipkg/${feed_name}-feed.conf
 127         done
 128 }
 129
 130 log_check() {
 131         set +x
 132         for target in $*
 133         do
 134                 lf_path="${WORKDIR}/temp/log.do_$target.${PID}"
 135
 136                 echo "log_check: Using $lf_path as logfile"
 137
 138                 if test -e "$lf_path"
 139                 then
 140                         rootfs_${IMAGE_PKGTYPE}_log_check $target $lf_path
 141                 else
 142                         echo "Cannot find logfile [$lf_path]"
 143                 fi
 144                 echo "Logfile is clean"
 145         done
 146
 147         set -x
 148 }
 149
 150 # set '*' as the rootpassword so the images
 151 # can decide if they want it or not
 152
 153 zap_root_password () {
 154         sed 's%^root:[^:]*:%root:*:%' < ${IMAGE_ROOTFS}/etc/passwd >${IMAGE_ROOTFS}/etc/passwd.new
 155         mv ${IMAGE_ROOTFS}/etc/passwd.new ${IMAGE_ROOTFS}/etc/passwd
 156 }
 157
 158 create_etc_timestamp() {
 159         date +%2m%2d%2H%2M%Y >${IMAGE_ROOTFS}/etc/timestamp
 160 }
 161
 162 # Turn any symbolic /sbin/init link into a file
 163 remove_init_link () {
 164         if [ -h ${IMAGE_ROOTFS}/sbin/init ]; then
 165                 LINKFILE=${IMAGE_ROOTFS}`readlink ${IMAGE_ROOTFS}/sbin/init`
 166                 rm ${IMAGE_ROOTFS}/sbin/init
 167                 cp $LINKFILE ${IMAGE_ROOTFS}/sbin/init
 168         fi
 169 }
 170
 171 make_zimage_symlink_relative () {
 172         if [ -L ${IMAGE_ROOTFS}/boot/zImage ]; then
 173                 (cd ${IMAGE_ROOTFS}/boot/ && for i in `ls zImage-* | sort`; do ln -sf $i zImage; done)
 174         fi
 175 }
 176
 177 # Make login manager(s) enable automatic login.
 178 # Useful for devices where we do not want to log in at all (e.g. phones)
 179 set_image_autologin () {
 180         sed -i 's%^AUTOLOGIN=\"false"%AUTOLOGIN="true"%g' ${IMAGE_ROOTFS}/etc/sysconfig/gpelogin
 181 }
 182
 183 # Can be use to create /etc/timestamp during image construction to give a reasonably
 184 # sane default time setting
 185 rootfs_update_timestamp () {
 186         date "+%m%d%H%M%Y" >${IMAGE_ROOTFS}/etc/timestamp
 187 }
 188
 189 # export the zap_root_password, create_etc_timestamp and remote_init_link
 190 EXPORT_FUNCTIONS zap_root_password create_etc_timestamp remove_init_link do_rootfs make_zimage_symlink_relative set_image_autologin rootfs_update_timestamp
 191
 192 addtask rootfs before do_build after do_install