code.vuplus.com Git - vuplus_openembedded/blob - classes/binconfig.bbclass

   1 inherit base
   2
   3 # The namespaces can clash here hence the two step replace
   4 def get_binconfig_mangle(d):
   5         import bb.data
   6         s = "-e ''"
   7         if not bb.data.inherits_class('native', d):
   8                 optional_quote = r"\(\"\?\)"
   9                 s += " -e 's:=%s${libdir}:=\\1OELIBDIR:;'" % optional_quote
  10                 s += " -e 's:=%s${includedir}:=\\1OEINCDIR:;'" % optional_quote
  11                 s += " -e 's:=%s${datadir}:=\\1OEDATADIR:'" % optional_quote
  12                 s += " -e 's:=%s${prefix}:=\\1OEPREFIX:'" % optional_quote
  13                 s += " -e 's:=%s${exec_prefix}:=\\1OEEXECPREFIX:'" % optional_quote
  14                 s += " -e 's:-L${libdir}:-LOELIBDIR:;'"
  15                 s += " -e 's:-I${includedir}:-IOEINCDIR:;'"
  16                 s += " -e 's:OELIBDIR:${STAGING_LIBDIR}:;'"
  17                 s += " -e 's:OEINCDIR:${STAGING_INCDIR}:;'"
  18                 s += " -e 's:OEDATADIR:${STAGING_DATADIR}:'"
  19                 s += " -e 's:OEPREFIX:${STAGING_LIBDIR}/..:'"
  20                 s += " -e 's:OEEXECPREFIX:${STAGING_LIBDIR}/..:'"
  21         return s
  22
  23 BINCONFIG_GLOB ?= "*-config"
  24
  25 do_install_append() {
  26
  27     #the 'if' protects native packages, since we can't easily check for bb.data.inherits_class('native', d) in shell
  28     if [ -e ${D}${bindir} ] ; then
  29         for config in `find ${S} -name '${BINCONFIG_GLOB}'`; do
  30                 cat $config | sed \
  31                 -e 's:${STAGING_LIBDIR}:${libdir}:g;' \
  32                 -e 's:${STAGING_INCDIR}:${includedir}:g;' \
  33                 -e 's:${STAGING_DATADIR}:${datadir}:' \
  34                 -e 's:${STAGING_LIBDIR}/..:${prefix}:' > ${D}${bindir}/`basename $config`
  35         done
  36     fi
  37
  38         for lafile in `find ${D} -name *.la` ; do
  39                 sed -i \
  40                     -e 's:${STAGING_LIBDIR}:${libdir}:g;' \
  41                     -e 's:${STAGING_INCDIR}:${includedir}:g;' \
  42                     -e 's:${STAGING_DATADIR}:${datadir}:' \
  43                     -e 's:${STAGING_LIBDIR}/..:${prefix}:' \
  44                     $lafile
  45         done
  46 }
  47
  48 do_stage_append() {
  49         for config in `find ${S} -name '${BINCONFIG_GLOB}'`; do
  50                 configname=`basename $config`
  51                 install -d ${STAGING_BINDIR_CROSS}
  52                 cat $config | sed ${@get_binconfig_mangle(d)} > ${STAGING_BINDIR_CROSS}/$configname
  53                 chmod u+x ${STAGING_BINDIR_CROSS}/$configname
  54         done
  55 }