code.vuplus.com Git - vuplus_openembedded/blob - binutils/binutils_2.14.90.0.7.oe

   1 SECTION = "devel"
   2 inherit autotools gettext
   3
   4 DESCRIPTION = "A GNU collection of binary utilities"
   5 HOMEPAGE = "http://www.gnu.org/software/binutils/"
   6 LICENSE = "GPL"
   7 MAINTAINER = "Gerald Britton <gbritton@doomcom.org>"
   8 PR = "r3"
   9
  10 PACKAGES = "${PN} ${PN}-dev ${PN}-doc ${PN}-symlinks"
  11
  12 FILES_${PN} = " \
  13         ${bindir}/${TARGET_PREFIX}* \
  14         ${libdir}/lib*-*.so \
  15         ${prefix}/${TARGET_SYS}/bin/*"
  16
  17 FILES_${PN}-dev = " \
  18         ${includedir} \
  19         ${libdir}/*.a \
  20         ${libdir}/*.la \
  21         ${libdir}/libbfd.so \
  22         ${libdir}/libopcodes.so"
  23
  24 FILES_${PN}-symlinks = " \
  25         ${bindir}/addr2line \
  26         ${bindir}/ar \
  27         ${bindir}/as \
  28         ${bindir}/c++filt \
  29         ${bindir}/gprof \
  30         ${bindir}/ld \
  31         ${bindir}/nm \
  32         ${bindir}/objcopy \
  33         ${bindir}/objdump \
  34         ${bindir}/ranlib \
  35         ${bindir}/readelf \
  36         ${bindir}/size \
  37         ${bindir}/strings \
  38         ${bindir}/strip"
  39
  40 SRC_URI = \
  41     "http://ftp.kernel.org/pub/linux/devel/binutils/binutils-${PV}.tar.bz2 \
  42      file://ld_makefile.patch;patch=1 \
  43      file://better_file_error.patch;patch=1 \
  44      file://signed_char_fix.patch;patch=1 \
  45      file://binutils-uclibc-001-debian.patch;patch=1 \
  46      file://binutils-uclibc-100-conf.patch;patch=1 \
  47      file://binutils-uclibc-200-build_modules.patch;patch=1 \
  48      file://binutils-uclibc-210-cflags.patch;patch=1 \
  49      file://binutils-100_cflags_for_build.patch;patch=1 \
  50      file://plt32trunc.patch;patch=1 \
  51      file://600-arm-textrel.patch;patch=1"
  52
  53 S = "${WORKDIR}/binutils-${PV}"
  54 B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
  55
  56 EXTRA_OECONF = "--with-sysroot=${prefix} \
  57                 --program-prefix=${TARGET_PREFIX} \
  58                 --enable-shared"
  59
  60 # This is necessary due to a bug in the binutils Makefiles
  61 EXTRA_OEMAKE = "configure-build-libiberty all"
  62
  63 export AR = "${HOST_PREFIX}ar"
  64 export AS = "${HOST_PREFIX}as"
  65 export LD = "${HOST_PREFIX}ld"
  66 export NM = "${HOST_PREFIX}nm"
  67 export RANLIB = "${HOST_PREFIX}ranlib"
  68 export OBJCOPY = "${HOST_PREFIX}objcopy"
  69 export OBJDUMP = "${HOST_PREFIX}objdump"
  70
  71 export AR_FOR_TARGET = "${TARGET_PREFIX}ar"
  72 export AS_FOR_TARGET = "${TARGET_PREFIX}as"
  73 export LD_FOR_TARGET = "${TARGET_PREFIX}ld"
  74 export NM_FOR_TARGET = "${TARGET_PREFIX}nm"
  75 export RANLIB_FOR_TARGET = "${TARGET_PREFIX}ranlib"
  76
  77 export CC_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
  78 export CXX_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
  79
  80 export CC_FOR_BUILD = "${BUILD_CC}"
  81
  82 export CC = "${CCACHE} ${HOST_PREFIX}gcc"
  83
  84 do_configure () {
  85         (cd ${S}; gnu-configize) || die "Failed to run gnu-configize"
  86         oe_runconf
  87 }
  88
  89 do_stage () {
  90         oe_libinstall -so -a -C opcodes libopcodes ${STAGING_LIBDIR}/
  91         oe_libinstall -a -C libiberty libiberty ${STAGING_LIBDIR}/
  92         oe_libinstall -so -a -C bfd libbfd ${STAGING_LIBDIR}/
  93         install -m 0644 ${S}/include/dis-asm.h ${STAGING_INCDIR}/
  94         install -m 0644 ${S}/include/symcat.h ${STAGING_INCDIR}/
  95         install -m 0644 ${S}/include/libiberty.h ${STAGING_INCDIR}/
  96         install -m 0644 ${S}/include/ansidecl.h ${STAGING_INCDIR}/
  97         install -m 0644 ${S}/include/bfdlink.h ${STAGING_INCDIR}/
  98         install -m 0644 bfd/bfd.h ${STAGING_INCDIR}/
  99 }
 100
 101 do_install () {
 102         autotools_do_install
 103
 104         # We don't really need these, so we'll remove them...
 105         rm -rf ${D}/${libdir}/ldscripts
 106
 107         # Fix the /usr/${TARGET_SYS}/bin/* links
 108         for l in ${D}/${prefix}/${TARGET_SYS}/bin/*; do
 109                 rm -f $l
 110                 ln -sf `echo ${prefix}/${TARGET_SYS}/bin \
 111                         | tr -s / \
 112                         | sed -e 's,^/,,' -e 's,[^/]*,..,g'`${bindir}/${TARGET_PREFIX}`basename $l` $l
 113         done
 114
 115         # Install the libiberty header
 116         install -d ${D}/${includedir}
 117         install -m 644 ${S}/include/ansidecl.h ${D}/${includedir}
 118         install -m 644 ${S}/include/libiberty.h ${D}/${includedir}
 119
 120         cd ${D}/${bindir}
 121
 122         # Symlinks for ease of running these on the native target
 123         for p in ${TARGET_SYS}-* ; do
 124                 ln -sf $p `echo $p | sed -e s,${TARGET_SYS}-,,`
 125         done
 126 }