code.vuplus.com Git - vuplus_webkit/blob - Source/JavaScriptCore/jsc.pro

   1 TEMPLATE = app
   2 TARGET = jsc
   3 DESTDIR = .
   4 SOURCES = jsc.cpp
   5 QT -= gui
   6 CONFIG -= app_bundle
   7 CONFIG += building-libs
   8 win32-*: CONFIG += console
   9 win32-msvc*: CONFIG += exceptions_off stl_off
  10
  11 isEmpty(OUTPUT_DIR): OUTPUT_DIR= ..
  12 include($$PWD/../WebKit.pri)
  13
  14 unix:!mac:!symbian:CONFIG += link_pkgconfig
  15
  16 QMAKE_RPATHDIR += $$OUTPUT_DIR/lib
  17
  18 OBJECTS_DIR_WTR = $$OBJECTS_DIR$${QMAKE_DIR_SEP}
  19 include($$PWD/JavaScriptCore.pri)
  20 prependJavaScriptCoreLib(.)
  21
  22 symbian {
  23     TARGET.CAPABILITY = ReadUserData WriteUserData NetworkServices
  24 }
  25
  26 mac {
  27     LIBS_PRIVATE += -framework AppKit
  28 }
  29
  30 win* {
  31     LIBS += -ladvapi32
  32 }
  33
  34 wince* {
  35     LIBS += mmtimer.lib
  36 }
  37
  38 # Prevent warnings about difference in visibility on Mac OS X
  39 contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
  40 unix:contains(QT_CONFIG, reduce_relocations):CONFIG += bsymbolic_functions