code.vuplus.com Git - vuplus_openvuplus_3.0/blob - meta-openvuplus/recipes-vuplus/e2openplugins/enigma2-plugin-extensions-openwebif.bb

   1 MODULE = "OpenWebif"
   2 DESCRIPTION = "Control your receiver with a browser"
   3 LICENSE = "GPLv2"
   4 LIC_FILES_CHKSUM = "file://README;firstline=10;lastline=12;md5=9c14f792d0aeb54e15490a28c89087f7"
   5
   6 DEPENDS = "python-cheetah-native"
   7 RDEPENDS_${PN} = "python-cheetah python-json python-unixadmin python-misc python-pyopenssl aio-grab"
   8
   9 inherit gitpkgv
  10 PV = "0.1+git${SRCPV}"
  11 PKGV = "0.1+git${GITPKGV}"
  12 PR = "r0.81"
  13
  14 require openplugins.inc
  15
  16 # Just a quick hack to "compile" it
  17 do_compile() {
  18         cheetah-compile -R --nobackup ${S}/plugin
  19         python -O -m compileall ${S}
  20 }
  21
  22 PLUGINPATH = "/usr/lib/enigma2/python/Plugins/Extensions/${MODULE}"
  23 do_install() {
  24         install -d ${D}${PLUGINPATH}
  25         cp -rp ${S}/plugin/* ${D}${PLUGINPATH}
  26 }
  27
  28 python do_package_prepend () {
  29         boxtypes = [
  30                 ('bm750', 'duo.jpg', 'vu_normal.png'),
  31                 ('vuduo2', 'duo2.jpg', 'vu_normal.png'),
  32                 ('vusolo', 'solo.jpg', 'vu_normal.png'),
  33                 ('vusolo2', 'solo2.jpg', 'vu_normal.png'),
  34                 ('vuultimo', 'ultimo.jpg', 'vu_ultimo.png'),
  35                 ('vuuno', 'uno.jpg', 'vu_normal.png'),
  36         ]
  37         import os
  38         top = '${D}${PLUGINPATH}/public/images/'
  39         target_box = 'unknown.jpg'
  40         target_remote = 'ow_remote.png'
  41         for x in boxtypes:
  42                 if x[0] == '${MACHINE}':
  43                         target_box = x[1]
  44                         target_remote = x[2]
  45                         break
  46         for root, dirs, files in os.walk(top + 'boxes', topdown=False):
  47                 for name in files:
  48                         if target_box != name and name != 'unknown.jpg':
  49                                 os.remove(os.path.join(root, name))
  50         for root, dirs, files in os.walk(top + 'remotes', topdown=False):
  51                 for name in files:
  52                         if target_remote != name and name != 'ow_remote.png':
  53                                 os.remove(os.path.join(root, name))
  54 }
  55
  56 FILES_${PN} = "${PLUGINPATH}"
  57 PACKAGES = "${PN}"