code.vuplus.com Git - vuplus_openvuplus_3.0/blob - meta-openvuplus/recipes-vuplus/e2openplugins/enigma2-plugin-extensions-openwebif.bb

   1 MODULE = "OpenWebif"
   2 DESCRIPTION = "Control your receiver with a browser"
   3 LICENSE = "GPLv2"
   4 LIC_FILES_CHKSUM = "file://README;firstline=10;lastline=12;md5=9c14f792d0aeb54e15490a28c89087f7"
   5
   6 DEPENDS = "python-cheetah-native"
   7 RDEPENDS_${PN} = "python-cheetah python-json python-unixadmin python-misc python-pyopenssl \
   8                 python-shell aio-grab python-compression python-numbers python-zopeinterface \
   9 "
  10
  11 SRCREV_pn-${PN}="d84307958746e6a597b43defe5bd1cb78fd745c8"
  12 inherit gitpkgv
  13 PV = "1+git${SRCPV}"
  14 PKGV = "1+git${GITPKGV}"
  15 PR = "r9"
  16
  17 require openplugins-distutils.inc
  18
  19 SRC_URI = "git://github.com/E2OpenPlugins/e2openplugin-${MODULE}.git;protocol=https \
  20         file://openwebif_support_vumodels.patch \
  21         file://openwebif_block_in_qpip.patch \
  22         file://openwebif_vu_box_remote.patch \
  23         file://rc_brown.png \
  24         file://box_solo4k.png \
  25         file://box_uno4k.png \
  26         file://box_ultimo4k.png \
  27         file://box_uno4kse.png \
  28         file://box_zero4k.png \
  29         file://box_duo4k.png \
  30 "
  31
  32 # Just a quick hack to "compile" it
  33 do_compile() {
  34         cheetah-compile -R --nobackup ${S}/plugin
  35         python -O -m compileall ${S}
  36 }
  37
  38 PLUGINPATH = "/usr/lib/enigma2/python/Plugins/Extensions/${MODULE}"
  39 do_install_append() {
  40         install -d ${D}${PLUGINPATH}
  41         cp -rp ${S}/plugin/* ${D}${PLUGINPATH}
  42         install -m 0755 ${WORKDIR}/rc_brown.png ${D}${PLUGINPATH}/public/images/remotes/vu_brown.png
  43         install -m 0755 ${WORKDIR}/box_solo4k.png ${D}${PLUGINPATH}/public/images/boxes/solo4k.png
  44         install -m 0755 ${WORKDIR}/box_uno4k.png ${D}${PLUGINPATH}/public/images/boxes/uno4k.png
  45         install -m 0755 ${WORKDIR}/box_ultimo4k.png ${D}${PLUGINPATH}/public/images/boxes/ultimo4k.png
  46         install -m 0755 ${WORKDIR}/box_uno4kse.png ${D}${PLUGINPATH}/public/images/boxes/uno4kse.png
  47         install -m 0755 ${WORKDIR}/box_zero4k.png ${D}${PLUGINPATH}/public/images/boxes/zero4k.png
  48         install -m 0755 ${WORKDIR}/box_duo4k.png ${D}${PLUGINPATH}/public/images/boxes/duo4k.png
  49 }
  50
  51 python do_package_prepend () {
  52   boxtypes = [
  53   ('bm750', 'duo.jpg', 'vu_normal.png'),
  54   ('vuduo2', 'duo2.jpg', 'vu_duo2.png'),
  55   ('vusolo', 'solo.jpg', 'vu_normal.png'),
  56   ('vusolo2', 'solo2.jpg', 'vu_normal.png'),
  57   ('vusolose', 'solose.jpg', 'vu_normal.png'),
  58   ('vuzero', 'zero.jpg', 'vu_normal.png'),
  59   ('vuultimo', 'ultimo.jpg', 'vu_ultimo.png'),
  60   ('vuuno', 'uno.jpg', 'vu_normal.png'),
  61   ('vusolo4k', 'solo4k.png', 'vu_normal.png'),
  62   ('vuuno4k', 'uno4k.png', 'vu_normal.png'),
  63   ('vuultimo4k', 'ultimo4k.png', 'vu_normal.png'),
  64   ('vuuno4kse', 'uno4kse.png', 'vu_brown.png'),
  65   ('vuzero4k', 'zero4k.png', 'vu_brown.png'),
  66   ('vuduo4k', 'duo4k.png', 'vu_brown.png'),
  67   ('vuduo4kse', 'duo4kse.png', 'vu_brown.png'),
  68   ]
  69   import os
  70   top = '${D}${PLUGINPATH}/public/images/'
  71   target_box = 'unknown.jpg'
  72   target_remote = 'ow_remote.png'
  73   for x in boxtypes:
  74     if x[0] == '${MACHINE}':
  75       target_box = x[1]
  76       target_remote = x[2]
  77       break
  78   for root, dirs, files in os.walk(top + 'boxes', topdown=False):
  79     for name in files:
  80       if target_box != name and name != 'unknown.jpg':
  81         os.remove(os.path.join(root, name))
  82   for root, dirs, files in os.walk(top + 'remotes', topdown=False):
  83     for name in files:
  84       if target_remote != name and name != 'ow_remote.png':
  85         os.remove(os.path.join(root, name))
  86 }
  87
  88 FILES_${PN} = "${PLUGINPATH}"
  89
  90 do_populate_sysroot[noexec] = "1"
  91
  92 PACKAGE_ARCH = "${MACHINE_ARCH}"
  93