code.vuplus.com Git - vuplus_openvuplus_3.0/blob - meta-openvuplus/recipes-support/lzma/lzma.inc

   1 DESCRIPTION = "LZMA is a general compression method. LZMA provides high compression ratio and very fast decompression."
   2 HOMEPAGE = "http://www.7-zip.org/"
   3 LICENSE = "LGPL"
   4 LIC_FILES_CHKSUM = "file://lzma.txt;md5=20251cdc2e3793cceab11878d0aa11b1"
   5 INC_PR = "r6"
   6
   7 SRC_URI = "http://downloads.sourceforge.net/sevenzip/lzma${@bb.data.getVar('PV',d,1).replace('.','')}.tar.bz2;subdir=${BPN}-${PV} \
   8            file://001-large_files.patch \
   9            file://002-lzmp.patch \
  10            file://003-compile_fixes.patch \
  11            file://100-static_library.patch \
  12            file://makefile-cleanup.patch"
  13
  14 EXTRA_OEMAKE = "-f makefile.gcc"
  15
  16 do_unpack_append() {
  17     bb.process.run("find . -type f -print0 | xargs -0 sed 's/\r$//' -i", cwd=d.getVar("S", True))
  18 }
  19
  20 do_compile() {
  21     oe_runmake CFLAGS='${CFLAGS} -c' -C C/LzmaUtil
  22     oe_runmake CXX_C='${CC} ${CFLAGS}' CXX='${CXX} ${CXXFLAGS}' -C CPP/7zip/Compress/LZMA_Alone
  23 }
  24
  25 do_install() {
  26     install -d ${D}${bindir} ${D}${libdir}
  27     install -m 0755 CPP/7zip/Compress/LZMA_Alone/lzma ${D}${bindir}
  28     oe_libinstall -a -C C/LzmaUtil liblzma ${D}${libdir}
  29 }
  30
  31 do_populate_sysroot() {
  32 }
  33
  34 NATIVE_INSTALL_WORKS = "1"
  35 BBCLASSEXTEND = "native"