code.vuplus.com Git - vuplus_openvuplus_3.0/blob - meta-openvuplus/recipes-support/libtinyxml/libtinyxml_2.6.2.bb

   1 # (c) Copyright 2012  Hewlett-Packard Development Company, L.P.
   2
   3 DESCRIPTION = "a simple, small, minimal, C++ XML parser"
   4 HOMEPAGE = "http://www.sourceforge.net/projects/tinyxml"
   5 LICENSE = "Zlib"
   6 LIC_FILES_CHKSUM = "file://readme.txt;md5=f8f366f3370dda889f60faa7db162cf4"
   7 SECTION = "libs"
   8
   9 PR = "r5"
  10
  11 SRC_URI = "${SOURCEFORGE_MIRROR}/tinyxml/tinyxml_${@'${PV}'.replace('.', '_')}.tar.gz \
  12            file://enforce-use-stl.patch \
  13            file://entity-encoding.patch"
  14 SRC_URI[md5sum] = "c1b864c96804a10526540c664ade67f0"
  15 SRC_URI[sha256sum] = "15bdfdcec58a7da30adc87ac2b078e4417dbe5392f3afb719f9ba6d062645593"
  16
  17 S = "${WORKDIR}/tinyxml"
  18
  19 CXXFLAGS += "-fPIC"
  20
  21 do_compile() {
  22     ${CXX} ${CXXFLAGS} -I${S} -c -o ${S}/tinyxml.o ${S}/tinyxml.cpp
  23     ${CXX} ${CXXFLAGS} -I${S} -c -o ${S}/tinyxmlerror.o ${S}/tinyxmlerror.cpp
  24     ${CXX} ${CXXFLAGS} -I${S} -c -o ${S}/tinyxmlparser.o ${S}/tinyxmlparser.cpp
  25     ${CXX} ${CXXFLAGS} \
  26             -shared \
  27             -Wl,-soname,libtinyxml.so.${PV} \
  28             -o ${S}/libtinyxml.so.${PV} \
  29             ${LDFLAGS} \
  30             ${S}/tinyxml.o \
  31             ${S}/tinyxmlparser.o \
  32             ${S}/tinyxmlerror.o
  33 }
  34
  35 do_install() {
  36     install -d ${D}${libdir}
  37     install -m 0755 ${S}/libtinyxml.so.${PV} ${D}${libdir}
  38     ln -sf libtinyxml.so.${PV} ${D}${libdir}/libtinyxml.so
  39
  40     install -d ${D}${includedir}
  41     install -m 0644 ${S}/tinyxml.h ${D}${includedir}
  42 }
  43