code.vuplus.com Git - vuplus_openvuplus_3.0/blob - meta-openvuplus/recipes-support/libgcrypt/libgcrypt.inc

   1 SUMMARY = "General purpose cryptographic library based on the code from GnuPG"
   2 HOMEPAGE = "http://directory.fsf.org/project/libgcrypt/"
   3 BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
   4 SECTION = "libs"
   5
   6 # helper program gcryptrnd and getrandom are under GPL, rest LGPL
   7 LICENSE = "GPLv2+ & LGPLv2.1+"
   8 LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
   9                     file://COPYING.LIB;md5=bbb461211a33b134d42ed5ee802b37ff"
  10
  11 DEPENDS = "libgpg-error libcap"
  12
  13 SRC_URI = "ftp://ftp.gnupg.org/gcrypt/libgcrypt/libgcrypt-${PV}.tar.gz \
  14            file://add-pkgconfig-support.patch \
  15            file://libgcrypt-fix-building-error-with-O2-in-sysroot-path.patch \
  16            file://fix-ICE-failure-on-mips-with-option-O-and-g.patch \
  17 "
  18
  19 BINCONFIG = "${bindir}/libgcrypt-config"
  20
  21 PR = "r1"
  22
  23 inherit autotools texinfo binconfig pkgconfig
  24
  25 EXTRA_OECONF = "--disable-asm --with-capabilities"
  26
  27 do_configure_prepend () {
  28         # Else this could be used in preference to the one in aclocal-copy
  29         rm -f ${S}/m4/gpg-error.m4
  30 }
  31
  32 # libgcrypt.pc is added locally and thus installed here
  33 do_install_append() {
  34         install -d ${D}/${libdir}/pkgconfig
  35         install -m 0644 ${B}/src/libgcrypt.pc ${D}/${libdir}/pkgconfig/
  36 }
  37
  38 FILES_${PN}-dev += "${bindir}/dumpsexp ${bindir}/hmac256"
  39
  40 ARM_INSTRUCTION_SET = "arm"
  41
  42 BBCLASSEXTEND = "native"