code.vuplus.com Git - vuplus_openvuplus_3.0/blob - meta-openvuplus/recipes-multimedia/gstreamer/gstreamer_0.10.36.1.bb

   1 SUMMARY = "GStreamer multimedia framework"
   2 DESCRIPTION = "GStreamer is a multimedia framework for encoding and decoding video and sound. \
   3 It supports a wide range of formats including mp3, ogg, avi, mpeg and quicktime."
   4 HOMEPAGE = "http://gstreamer.freedesktop.org/"
   5 BUGTRACKER = "https://bugzilla.gnome.org/enter_bug.cgi?product=Gstreamer"
   6 SECTION = "multimedia"
   7 LICENSE = "LGPLv2+"
   8 LIC_FILES_CHKSUM = "file://COPYING;md5=55ca817ccb7d5b5b66355690e9abc605 \
   9                     file://gst/gst.h;beginline=1;endline=21;md5=8e5fe5e87d33a04479fde862e238eaa4"
  10 DEPENDS = "glib-2.0 libxml2 bison-native flex-native"
  11
  12 PR = "r0"
  13 GIT_PV = ""
  14
  15 SRCREV = "935db833e236959c973e6c8ef59586d30f81a26c"
  16
  17 RRECOMMENDS_${PN}_qemux86    += "kernel-module-snd-ens1370 kernel-module-snd-rawmidi"
  18 RRECOMMENDS_${PN}_qemux86-64 += "kernel-module-snd-ens1370 kernel-module-snd-rawmidi"
  19
  20 FILES_${PN} += " ${libdir}/gstreamer-0.10/*.so"
  21 FILES_${PN}-dev += " ${libdir}/gstreamer-0.10/*.la ${libdir}/gstreamer-0.10/*.a"
  22 FILES_${PN}-dbg += " ${libdir}/gstreamer-0.10/.debug/ ${libexecdir}/gstreamer-0.10/.debug/"
  23
  24 GSTREAMER_DEBUG ?= "--disable-debug"
  25 EXTRA_OECONF = "--disable-docs-build --disable-dependency-tracking --with-check=no --disable-examples --disable-tests --disable-valgrind ${GSTREAMER_DEBUG}"
  26
  27 inherit autotools pkgconfig gettext git-project
  28
  29 SRC_URI = "git://anongit.freedesktop.org/gstreamer/${PN}"
  30
  31 SRC_URI += " \
  32         file://check_fix.patch \
  33         file://gst-inspect-check-error.patch \
  34 "
  35
  36 do_common_update() {
  37         cd ${S}
  38         # Make sure we have common
  39         if test ! -f common/gst-autogen.sh;
  40         then
  41           echo "+ Setting up common submodule"
  42           git submodule init
  43         fi
  44         git submodule update
  45
  46         # source helper functions
  47         if test ! -f common/gst-autogen.sh;
  48         then
  49           echo There is something wrong with your source tree.
  50           echo You are missing common/gst-autogen.sh
  51           exit 1
  52         fi
  53         . common/gst-autogen.sh
  54         # install pre-commit hook for doing clean commits
  55         if test ! \( -x .git/hooks/pre-commit -a -L .git/hooks/pre-commit \);
  56         then
  57             rm -f .git/hooks/pre-commit
  58             ln -s ../../common/hooks/pre-commit.hook .git/hooks/pre-commit
  59         fi
  60
  61         # GNU gettext automake support doesn't get along with git.
  62         # https://bugzilla.gnome.org/show_bug.cgi?id=661128
  63         autopoint || touch config.rpath
  64         touch -t 200001010000 po/gst-plugins-base-0.10.pot
  65 }
  66 addtask common_update after do_unpack before do_patch
  67
  68 do_configure_prepend() {
  69         # This m4 file contains nastiness which conflicts with libtool 2.2.2
  70         rm ${S}/m4/lib-link.m4 || true
  71 }
  72
  73 require mips-only.inc