code.vuplus.com Git - vuplus_openvuplus_3.0/blob - meta-openvuplus/recipes-kernel/linux-libc-headers/linux-libc-headers_2.6.31.bb

   1 DESCRIPTION = "Sanitized set of 2.6 kernel headers for the C library's use."
   2 SECTION = "devel"
   3 LICENSE = "GPLv2"
   4 LIC_FILES_CHKSUM = "file://COPYING;md5=d7810fab7487fb0aad327b76f1be7cd7"
   5
   6 PR = "r1"
   7
   8 PACKAGE_ARCH = "${MACHINE_ARCH}"
   9
  10 DEPENDS += "unifdef-native"
  11 RDEPENDS_${PN}-dev = ""
  12 RRECOMMENDS_${PN}-dbg = "${PN}-dev (= ${EXTENDPV})"
  13
  14 INHIBIT_DEFAULT_DEPS = "1"
  15 DEFAULT_PREFERENCE = "-1"
  16
  17 SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${PV}.tar.bz2 \
  18            file://0001-implement-TIF_RESTORE_SIGMASK-support-and-enable-the.patch;patch=1 \
  19            file://dvbapi-5.3.patch;patch=1;pnum=1 \
  20 "
  21
  22 SRC_URI[md5sum] = "84c077a37684e4cbfa67b18154390d8a"
  23 SRC_URI[sha256sum] = "0acd83f7b85db7ee18c2b0b7505e1ba6fd722c36f49a8870a831c851660e3512"
  24
  25 S = "${WORKDIR}/linux-${PV}"
  26
  27 set_arch() {
  28         case ${TARGET_ARCH} in
  29                 alpha*)   ARCH=alpha ;;
  30                 arm*)     ARCH=arm ;;
  31                 cris*)    ARCH=cris ;;
  32                 hppa*)    ARCH=parisc ;;
  33                 i*86*)    ARCH=i386 ;;
  34                 ia64*)    ARCH=ia64 ;;
  35                 mips*)    ARCH=mips ;;
  36                 m68k*)    ARCH=m68k ;;
  37                 powerpc*) ARCH=powerpc ;;
  38                 s390*)    ARCH=s390 ;;
  39                 sh*)      ARCH=sh ;;
  40                 sparc64*) ARCH=sparc64 ;;
  41                 sparc*)   ARCH=sparc ;;
  42                 x86_64*)  ARCH=x86_64 ;;
  43                 avr32*)   ARCH=avr32 ;;
  44                 bfin*)    ARCH=blackfin ;;
  45         esac
  46 }
  47
  48 do_configure() {
  49         set_arch
  50         oe_runmake allnoconfig ARCH=$ARCH
  51 }
  52
  53 do_compile () {
  54 }
  55
  56 do_install() {
  57         set_arch
  58         oe_runmake headers_install INSTALL_HDR_PATH=${D}${exec_prefix} ARCH=$ARCH
  59         # Kernel should not be exporting this header
  60         rm -rf ${D}${includedir}/scsi
  61
  62         # The ..install.cmd conflicts between various configure runs
  63         #find ${D}${includedir} -name ..install.cmd | xargs rm -f
  64 }
  65
  66 BBCLASSEXTEND = "nativesdk"