code.vuplus.com Git - vuplus_openvuplus_3.0/blob - meta-openvuplus/recipes-graphics/tslib/tslib_1.1.bb

   1 SUMMARY = "An abstraction layer for touchscreen panel events"
   2 DESCRIPTION = "Tslib is an abstraction layer for touchscreen panel \
   3 events, as well as a filter stack for the manipulation of those events. \
   4 Tslib is generally used on embedded devices to provide a common user \
   5 space interface to touchscreen functionality."
   6 HOMEPAGE = "http://tslib.berlios.de/"
   7
   8 AUTHOR = "Russell King w/ plugins by Chris Larson et. al."
   9 SECTION = "base"
  10 LICENSE = "LGPLv2"
  11 LIC_FILES_CHKSUM = "file://COPYING;md5=f30a9716ef3762e3467a2f62bf790f0a"
  12
  13 BBCLASSEXTEND = "native"
  14
  15 SRC_URI = "https://github.com/kergoth/tslib/releases/download/${PV}/tslib-${PV}.tar.xz;downloadfilename=tslib-${PV}.tar.xz \
  16            file://ts.conf \
  17            file://tslib.sh \
  18 "
  19
  20 SRC_URI[md5sum] = "14771f8607b341bb4b297819d37e837d"
  21 SRC_URI[sha256sum] = "fe35e5f710ea933b118f710e2ce4403ac076fe69926b570333867d4de082a51c"
  22
  23 inherit autotools pkgconfig
  24
  25 EXTRA_OECONF = "--enable-shared --disable-h3600 --enable-input --disable-corgi --disable-collie --disable-mk712 --disable-arctic2 --disable-ucb1x00"
  26
  27 do_install_prepend() {
  28         install -m 0644 ${WORKDIR}/ts.conf ${S}/etc/ts.conf
  29 }
  30
  31 do_install_append() {
  32         install -d ${D}${sysconfdir}/profile.d/
  33         install -m 0755 ${WORKDIR}/tslib.sh ${D}${sysconfdir}/profile.d/
  34 }
  35
  36 PACKAGES =+ "tslib-tests tslib-calibrate"
  37 DEBIAN_NOAUTONAME_tslib-tests = "1"
  38 DEBIAN_NOAUTONAME_tslib-calibrate = "1"
  39
  40 RRECOMMENDS_${PN} = "pointercal"
  41
  42 FILES_${PN}-dbg += "${libdir}/ts/.debug*"
  43 FILES_${PN}-dev += "${libdir}/ts/*.la"
  44 FILES_${PN} = "${libdir}/*.so.* ${libdir}/ts/*.so* ${sysconfdir}/ts.conf ${sysconfdir}/profile.d/tslib.sh ${datadir}/tslib"
  45 FILES_tslib-calibrate += "${bindir}/ts_calibrate"
  46 FILES_tslib-tests = "${bindir}/ts_harvest ${bindir}/ts_print ${bindir}/ts_print_raw ${bindir}/ts_test"