code.vuplus.com Git - vuplus_openvuplus/blob - meta-openvuplus/recipes-multimedia/dvbtools/dvb-apps_1.1.1.bb

   1 HOMEPAGE = "http://www.linuxtv.org"
   2 LICENSE = "GPLv2+"
   3 LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
   4
   5 SRC_URI = "http://linuxtv.org/downloads/linuxtv-dvb-apps-${PV}.tar.bz2 \
   6            file://update-to-trunk.diff \
   7            file://update-to-tip.diff"
   8
   9 PR = "r2"
  10
  11 S = "${WORKDIR}/linuxtv-dvb-apps-${PV}"
  12
  13 PACKAGES =+ "dvb-evtest dvb-evtest-dbg \
  14              dvbapp-tests dvbapp-tests-dbg \
  15              dvbdate dvbdate-dbg \
  16              dvbtraffic dvbtraffic-dbg \
  17              dvbnet dvbnet-dbg \
  18              dvb-scan dvb-scan-dbg dvb-scan-data \
  19              dvb-azap dvb-azap-dbg \
  20              dvb-czap dvb-czap-dbg \
  21              dvb-szap dvb-szap-dbg \
  22              dvb-tzap dvb-tzap-dbg \
  23              dvb-femon dvb-femon-dbg \
  24              dvb-zap-data"
  25
  26
  27 TARGET_CC_ARCH += "${LDFLAGS} -static"
  28
  29 FILES_${PN} = "${bindir} ${datadir}/dvb"
  30 FILES_${PN}-doc = ""
  31 FILES_${PN}-dev = "${includedir}"
  32
  33 FILES_dvb-evtest = "${bindir}/evtest"
  34 FILES_dvb-evtest-dbg = "${bindir}/.debug/evtest"
  35
  36 FILES_dvbapp-tests = "${bindir}/*test* "
  37 FILES_dvbapp-tests-dbg = "${bindir}/.debug/*test*"
  38
  39 FILES_dvbdate = "${bindir}/dvbdate"
  40 FILES_dvbdate-dbg = "${bindir}/.debug/dvbdate"
  41
  42 FILES_dvbtraffic = "${bindir}/dvbtraffic"
  43 FILES_dvbtraffic-dbg = "${bindir}/.debug/dvbtraffic"
  44
  45 FILES_dvbnet = "${bindir}/dvbnet"
  46 FILES_dvbnet-dbg = "${bindir}/.debug/dvbnet"
  47
  48 FILES_dvb-scan = "${bindir}/*scan "
  49 FILES_dvb-scan-dbg = "${bindir}/.debug/*scan"
  50 FILES_dvb-scan-data = "${docdir}/dvb-apps/scan"
  51
  52 FILES_dvb-azap = "${bindir}/azap"
  53 FILES_dvb-azap-dbg = "${bindir}/.debug/azap"
  54
  55 FILES_dvb-czap = "${bindir}/czap"
  56 FILES_dvb-czap-dbg = "${bindir}/.debug/czap"
  57
  58 FILES_dvb-szap = "${bindir}/szap"
  59 FILES_dvb-szap-dbg = "${bindir}/.debug/szap"
  60
  61 FILES_dvb-tzap = "${bindir}/tzap"
  62 FILES_dvb-tzap-dbg = "${bindir}/.debug/tzap"
  63
  64 FILES_dvb-femon = "${bindir}/femon"
  65 FILES_dvb-femon-dbg = "${bindir}/.debug/femon"
  66
  67 FILES_dvb-zap-data = "${docdir}/dvb-apps/szap"
  68
  69 do_configure() {
  70         sed -i -e s:/usr/include:${STAGING_INCDIR}:g util/av7110_loadkeys/generate-keynames.sh
  71 }
  72
  73 do_install() {
  74     make DESTDIR=${D} install
  75         install -d ${D}/${bindir}
  76     install -d ${D}/${docdir}/dvb-apps
  77     install -d ${D}/${docdir}/dvb-apps/scan
  78     install -d ${D}/${docdir}/dvb-apps/szap
  79         chmod a+rx ${D}/${libdir}/*.so*
  80
  81     # Install tests
  82     install -m 0755 ${S}/test/setvoltage      ${D}${bindir}/test_setvoltage
  83     install -m 0755 ${S}/test/set22k          ${D}${bindir}/test_set22k
  84     install -m 0755 ${S}/test/video           ${D}${bindir}/test_video
  85     install -m 0755 ${S}/test/sendburst       ${D}${bindir}/test_sendburst
  86     install -m 0755 ${S}/test/diseqc          ${D}${bindir}/test_diseqc
  87     install -m 0755 ${S}/test/test_sections   ${D}${bindir}/
  88     install -m 0755 ${S}/test/test_av_play    ${D}${bindir}/
  89     install -m 0755 ${S}/test/test_stillimage ${D}${bindir}/
  90     install -m 0755 ${S}/test/test_dvr_play   ${D}${bindir}/
  91     install -m 0755 ${S}/test/test_tt         ${D}${bindir}/
  92     install -m 0755 ${S}/test/test_sec_ne     ${D}${bindir}/
  93     install -m 0755 ${S}/test/test_stc        ${D}${bindir}/
  94     install -m 0755 ${S}/test/test_av         ${D}${bindir}/
  95     install -m 0755 ${S}/test/test_vevent     ${D}${bindir}/
  96     install -m 0755 ${S}/test/test_pes        ${D}${bindir}/
  97     install -m 0755 ${S}/test/test_dvr        ${D}${bindir}/
  98
  99     cp -pPR ${S}/util/szap/channels-conf* ${D}/${docdir}/dvb-apps/szap/
 100     cp -pPR ${S}/util/szap/README   ${D}/${docdir}/dvb-apps/szap/
 101 }
 102
 103 python populate_packages_prepend () {
 104         dvb_libdir = bb.data.expand('${libdir}', d)
 105         do_split_packages(d, dvb_libdir, '^lib(.*)\.so$', 'lib%s', 'DVB %s package', extra_depends='', allow_links=True)
 106         do_split_packages(d, dvb_libdir, '^lib(.*)\.la$', 'lib%s-dev', 'DVB %s development package', extra_depends='${PN}-dev')
 107         do_split_packages(d, dvb_libdir, '^lib(.*)\.a$', 'lib%s-dev', 'DVB %s development package', extra_depends='${PN}-dev')
 108         do_split_packages(d, dvb_libdir, '^lib(.*)\.so\.*', 'lib%s', 'DVB %s library', extra_depends='', allow_links=True)
 109 }
 110
 111 SRC_URI[md5sum] = "de958cdb8d00e74792dd69f3c945b037"
 112 SRC_URI[sha256sum] = "371f8133db705bde6c2f79cccb0b1a1f626a0d94bf41acceba5d76a69155f057"