code.vuplus.com Git - vuplus_xbmc/blob - system/shaders/convolution-6x6.glsl

   1 /*
   2  *      Copyright (C) 2010-2013 Team XBMC
   3  *      http://www.xbmc.org
   4  *
   5  *  This Program is free software; you can redistribute it and/or modify
   6  *  it under the terms of the GNU General Public License as published by
   7  *  the Free Software Foundation; either version 2, or (at your option)
   8  *  any later version.
   9  *
  10  *  This Program is distributed in the hope that it will be useful,
  11  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13  *  GNU General Public License for more details.
  14  *
  15  *  You should have received a copy of the GNU General Public License
  16  *  along with XBMC; see the file COPYING.  If not, write to
  17  *  the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  18  *  http://www.gnu.org/copyleft/gpl.html
  19  *
  20  */
  21
  22 uniform sampler2D img;
  23 uniform vec2      stepxy;
  24 uniform float     m_stretch;
  25 varying vec2      cord;
  26
  27 #if (USE1DTEXTURE)
  28   uniform sampler1D kernelTex;
  29 #else
  30   uniform sampler2D kernelTex;
  31 #endif
  32
  33 //nvidia's half is a 16 bit float and can bring some speed improvements
  34 //without affecting quality
  35 #ifndef __GLSL_CG_DATA_TYPES
  36   #define half float
  37   #define half3 vec3
  38   #define half4 vec4
  39 #endif
  40
  41 half3 weight(float pos)
  42 {
  43 #if (HAS_FLOAT_TEXTURE)
  44   #if (USE1DTEXTURE)
  45     return texture1D(kernelTex, pos).rgb;
  46   #else
  47     return texture2D(kernelTex, vec2(pos, 0.5)).rgb;
  48   #endif
  49 #else
  50   #if (USE1DTEXTURE)
  51     return texture1D(kernelTex, pos).rgb * 2.0 - 1.0;
  52   #else
  53     return texture2D(kernelTex, vec2(pos, 0.5)).rgb * 2.0 - 1.0;
  54   #endif
  55 #endif
  56 }
  57
  58 vec2 stretch(vec2 pos)
  59 {
  60 #if (XBMC_STRETCH)
  61   // our transform should map [0..1] to itself, with f(0) = 0, f(1) = 1, f(0.5) = 0.5, and f'(0.5) = b.
  62   // a simple curve to do this is g(x) = b(x-0.5) + (1-b)2^(n-1)(x-0.5)^n + 0.5
  63   // where the power preserves sign. n = 2 is the simplest non-linear case (required when b != 1)
  64   float x = pos.x - 0.5;
  65   return vec2(mix(x * abs(x) * 2.0, x, m_stretch) + 0.5, pos.y);
  66 #else
  67   return pos;
  68 #endif
  69 }
  70
  71 half3 pixel(float xpos, float ypos)
  72 {
  73   return texture2D(img, vec2(xpos, ypos)).rgb;
  74 }
  75
  76 half3 line (float ypos, vec3 xpos1, vec3 xpos2, half3 linetaps1, half3 linetaps2)
  77 {
  78   return
  79     pixel(xpos1.r, ypos) * linetaps1.r +
  80     pixel(xpos1.g, ypos) * linetaps2.r +
  81     pixel(xpos1.b, ypos) * linetaps1.g +
  82     pixel(xpos2.r, ypos) * linetaps2.g +
  83     pixel(xpos2.g, ypos) * linetaps1.b +
  84     pixel(xpos2.b, ypos) * linetaps2.b;
  85 }
  86
  87 void main()
  88 {
  89   vec2 pos = stretch(cord) + stepxy * 0.5;
  90   vec2 f = fract(pos / stepxy);
  91
  92   half3 linetaps1   = weight((1.0 - f.x) / 2.0);
  93   half3 linetaps2   = weight((1.0 - f.x) / 2.0 + 0.5);
  94   half3 columntaps1 = weight((1.0 - f.y) / 2.0);
  95   half3 columntaps2 = weight((1.0 - f.y) / 2.0 + 0.5);
  96
  97   //make sure all taps added together is exactly 1.0, otherwise some (very small) distortion can occur
  98   half sum = linetaps1.r + linetaps1.g + linetaps1.b + linetaps2.r + linetaps2.g + linetaps2.b;
  99   linetaps1 /= sum;
 100   linetaps2 /= sum;
 101   sum = columntaps1.r + columntaps1.g + columntaps1.b + columntaps2.r + columntaps2.g + columntaps2.b;
 102   columntaps1 /= sum;
 103   columntaps2 /= sum;
 104
 105   vec2 xystart = (-2.5 - f) * stepxy + pos;
 106   vec3 xpos1 = vec3(xystart.x, xystart.x + stepxy.x, xystart.x + stepxy.x * 2.0);
 107   vec3 xpos2 = vec3(xystart.x + stepxy.x * 3.0, xystart.x + stepxy.x * 4.0, xystart.x + stepxy.x * 5.0);
 108
 109   gl_FragColor.rgb =
 110    line(xystart.y                 , xpos1, xpos2, linetaps1, linetaps2) * columntaps1.r +
 111    line(xystart.y + stepxy.y      , xpos1, xpos2, linetaps1, linetaps2) * columntaps2.r +
 112    line(xystart.y + stepxy.y * 2.0, xpos1, xpos2, linetaps1, linetaps2) * columntaps1.g +
 113    line(xystart.y + stepxy.y * 3.0, xpos1, xpos2, linetaps1, linetaps2) * columntaps2.g +
 114    line(xystart.y + stepxy.y * 4.0, xpos1, xpos2, linetaps1, linetaps2) * columntaps1.b +
 115    line(xystart.y + stepxy.y * 5.0, xpos1, xpos2, linetaps1, linetaps2) * columntaps2.b;
 116
 117   gl_FragColor.a = gl_Color.a;
 118 }
 119