code.vuplus.com Git - vuplus_xbmc/blob - system/shaders/convolution-6x6.glsl

   1 /*
   2  *      Copyright (C) 2010-2013 Team XBMC
   3  *      http://xbmc.org
   4  *
   5  *  This Program is free software; you can redistribute it and/or modify
   6  *  it under the terms of the GNU General Public License as published by
   7  *  the Free Software Foundation; either version 2, or (at your option)
   8  *  any later version.
   9  *
  10  *  This Program is distributed in the hope that it will be useful,
  11  *  but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13  *  GNU General Public License for more details.
  14  *
  15  *  You should have received a copy of the GNU General Public License
  16  *  along with XBMC; see the file COPYING.  If not, see
  17  *  <http://www.gnu.org/licenses/>.
  18  *
  19  */
  20
  21 uniform sampler2D img;
  22 uniform vec2      stepxy;
  23 uniform float     m_stretch;
  24 varying vec2      cord;
  25
  26 #if (USE1DTEXTURE)
  27   uniform sampler1D kernelTex;
  28 #else
  29   uniform sampler2D kernelTex;
  30 #endif
  31
  32 //nvidia's half is a 16 bit float and can bring some speed improvements
  33 //without affecting quality
  34 #ifndef __GLSL_CG_DATA_TYPES
  35   #define half float
  36   #define half3 vec3
  37   #define half4 vec4
  38 #endif
  39
  40 half3 weight(float pos)
  41 {
  42 #if (HAS_FLOAT_TEXTURE)
  43   #if (USE1DTEXTURE)
  44     return texture1D(kernelTex, pos).rgb;
  45   #else
  46     return texture2D(kernelTex, vec2(pos, 0.5)).rgb;
  47   #endif
  48 #else
  49   #if (USE1DTEXTURE)
  50     return texture1D(kernelTex, pos).rgb * 2.0 - 1.0;
  51   #else
  52     return texture2D(kernelTex, vec2(pos, 0.5)).rgb * 2.0 - 1.0;
  53   #endif
  54 #endif
  55 }
  56
  57 vec2 stretch(vec2 pos)
  58 {
  59 #if (XBMC_STRETCH)
  60   // our transform should map [0..1] to itself, with f(0) = 0, f(1) = 1, f(0.5) = 0.5, and f'(0.5) = b.
  61   // a simple curve to do this is g(x) = b(x-0.5) + (1-b)2^(n-1)(x-0.5)^n + 0.5
  62   // where the power preserves sign. n = 2 is the simplest non-linear case (required when b != 1)
  63   float x = pos.x - 0.5;
  64   return vec2(mix(x * abs(x) * 2.0, x, m_stretch) + 0.5, pos.y);
  65 #else
  66   return pos;
  67 #endif
  68 }
  69
  70 half3 pixel(float xpos, float ypos)
  71 {
  72   return texture2D(img, vec2(xpos, ypos)).rgb;
  73 }
  74
  75 half3 line (float ypos, vec3 xpos1, vec3 xpos2, half3 linetaps1, half3 linetaps2)
  76 {
  77   return
  78     pixel(xpos1.r, ypos) * linetaps1.r +
  79     pixel(xpos1.g, ypos) * linetaps2.r +
  80     pixel(xpos1.b, ypos) * linetaps1.g +
  81     pixel(xpos2.r, ypos) * linetaps2.g +
  82     pixel(xpos2.g, ypos) * linetaps1.b +
  83     pixel(xpos2.b, ypos) * linetaps2.b;
  84 }
  85
  86 void main()
  87 {
  88   vec2 pos = stretch(cord) + stepxy * 0.5;
  89   vec2 f = fract(pos / stepxy);
  90
  91   half3 linetaps1   = weight((1.0 - f.x) / 2.0);
  92   half3 linetaps2   = weight((1.0 - f.x) / 2.0 + 0.5);
  93   half3 columntaps1 = weight((1.0 - f.y) / 2.0);
  94   half3 columntaps2 = weight((1.0 - f.y) / 2.0 + 0.5);
  95
  96   //make sure all taps added together is exactly 1.0, otherwise some (very small) distortion can occur
  97   half sum = linetaps1.r + linetaps1.g + linetaps1.b + linetaps2.r + linetaps2.g + linetaps2.b;
  98   linetaps1 /= sum;
  99   linetaps2 /= sum;
 100   sum = columntaps1.r + columntaps1.g + columntaps1.b + columntaps2.r + columntaps2.g + columntaps2.b;
 101   columntaps1 /= sum;
 102   columntaps2 /= sum;
 103
 104   vec2 xystart = (-2.5 - f) * stepxy + pos;
 105   vec3 xpos1 = vec3(xystart.x, xystart.x + stepxy.x, xystart.x + stepxy.x * 2.0);
 106   vec3 xpos2 = vec3(xystart.x + stepxy.x * 3.0, xystart.x + stepxy.x * 4.0, xystart.x + stepxy.x * 5.0);
 107
 108   gl_FragColor.rgb =
 109    line(xystart.y                 , xpos1, xpos2, linetaps1, linetaps2) * columntaps1.r +
 110    line(xystart.y + stepxy.y      , xpos1, xpos2, linetaps1, linetaps2) * columntaps2.r +
 111    line(xystart.y + stepxy.y * 2.0, xpos1, xpos2, linetaps1, linetaps2) * columntaps1.g +
 112    line(xystart.y + stepxy.y * 3.0, xpos1, xpos2, linetaps1, linetaps2) * columntaps2.g +
 113    line(xystart.y + stepxy.y * 4.0, xpos1, xpos2, linetaps1, linetaps2) * columntaps1.b +
 114    line(xystart.y + stepxy.y * 5.0, xpos1, xpos2, linetaps1, linetaps2) * columntaps2.b;
 115
 116   gl_FragColor.a = gl_Color.a;
 117 }
 118