code.vuplus.com Git - vuplus_xbmc/blob - project/cmake/scripts/common/xbmc-addon-helpers.cmake

   1 # Workaround for the fact that cpack's filenames are not customizable.
   2 # Each add-on is added as a separate component to facilitate zip/tgz packaging.
   3 # The filenames are always of the form basename-component, which is
   4 # incompatible with the addonid-version scheme we want. This hack renames
   5 # the files from the file names generated by the 'package' target.
   6 # Sadly we cannot extend the 'package' target, as it is a builtin target, see
   7 # http://public.kitware.com/Bug/view.php?id=8438
   8 # Thus, we have to add an 'addon-package' target.
   9 add_custom_target(addon-package
  10                   COMMAND cmake --build ${CMAKE_BINARY_DIR} --target package)
  11
  12 macro(add_cpack_workaround target version ext)
  13   add_custom_command(TARGET addon-package PRE_BUILD
  14                      COMMAND cmake -E rename addon-${target}-${version}.${ext} ${target}-${version}.${ext})
  15 endmacro()
  16
  17 # Grab the version from a given add-on's addon.xml
  18 macro (addon_version dir prefix)
  19   FILE(READ ${dir}/addon.xml ADDONXML)
  20   STRING(REGEX MATCH "<addon[^>]*version.?=.?.[0-9\\.]+" VERSION_STRING ${ADDONXML})
  21   STRING(REGEX REPLACE ".*version=.([0-9\\.]+).*" "\\1" ${prefix}_VERSION ${VERSION_STRING})
  22   message(STATUS ${prefix}_VERSION=${${prefix}_VERSION})
  23 endmacro()
  24
  25 # Build, link and optionally package an add-on
  26 macro (build_addon target prefix libs)
  27   ADD_LIBRARY(${target} ${${prefix}_SOURCES})
  28   TARGET_LINK_LIBRARIES(${target} ${${libs}})
  29   addon_version(${target} ${prefix})
  30   SET_TARGET_PROPERTIES(${target} PROPERTIES VERSION ${${prefix}_VERSION}
  31                                              SOVERSION ${APP_VERSION_MAJOR}.${APP_VERSION_MINOR}
  32                                              PREFIX "")
  33   IF(OS STREQUAL "android")
  34     SET_TARGET_PROPERTIES(${target} PROPERTIES PREFIX "lib")
  35   ENDIF(OS STREQUAL "android")
  36
  37   # set zip as default if addon-package is called without PACKAGE_XXX
  38   SET(CPACK_GENERATOR "ZIP")
  39   SET(ext "zip")
  40   IF(PACKAGE_ZIP OR PACKAGE_TGZ)
  41     IF(PACKAGE_TGZ)
  42       SET(CPACK_GENERATOR "TGZ")
  43       SET(ext "tar.gz")
  44     ENDIF(PACKAGE_TGZ)
  45     SET(CPACK_INCLUDE_TOPLEVEL_DIRECTORY OFF)
  46     set(CPACK_PACKAGE_FILE_NAME addon)
  47     IF(CMAKE_BUILD_TYPE STREQUAL "Release")
  48       SET(CPACK_STRIP_FILES TRUE)
  49     ENDIF(CMAKE_BUILD_TYPE STREQUAL "Release")
  50     set(CPACK_ARCHIVE_COMPONENT_INSTALL ON)
  51     set(CPACK_COMPONENTS_IGNORE_GROUPS 1)
  52     list(APPEND CPACK_COMPONENTS_ALL ${target}-${${prefix}_VERSION})
  53     # Pack files together to create an archive
  54     INSTALL(DIRECTORY ${target} DESTINATION ./ COMPONENT ${target}-${${prefix}_VERSION})
  55     IF(WIN32)
  56       INSTALL(PROGRAMS ${CMAKE_BINARY_DIR}/${target}.dll
  57               DESTINATION ${target}
  58               COMPONENT ${target}-${${prefix}_VERSION})
  59     ELSE(WIN32)
  60       INSTALL(TARGETS ${target} DESTINATION ${target}
  61               COMPONENT ${target}-${${prefix}_VERSION})
  62     ENDIF(WIN32)
  63     add_cpack_workaround(${target} ${${prefix}_VERSION} ${ext})
  64   ELSE(PACKAGE_ZIP OR PACKAGE_TGZ)
  65     INSTALL(TARGETS ${target} DESTINATION lib/xbmc/addons/${target})
  66     INSTALL(DIRECTORY ${target} DESTINATION share/xbmc/addons)
  67   ENDIF(PACKAGE_ZIP OR PACKAGE_TGZ)
  68 endmacro()
  69
  70 # finds a path to a given file (recursive)
  71 function (xbmc_find_path var_name filename search_path strip_file)
  72   file(GLOB_RECURSE PATH_TO_FILE ${search_path} ${filename})
  73   if(strip_file)
  74     string(REPLACE ${filename} "" PATH_TO_FILE ${PATH_TO_FILE})
  75   endif(strip_file)
  76   set (${var_name} ${PATH_TO_FILE} PARENT_SCOPE)
  77 endfunction()
  78
  79 # Cmake build options
  80 include(addoptions)
  81 include(TestCXXAcceptsFlag)
  82 OPTION(PACKAGE_ZIP "Package Zip file?" OFF)
  83 OPTION(PACKAGE_TGZ "Package TGZ file?" OFF)
  84 OPTION(BUILD_SHARED_LIBS "Build shared libs?" ON)
  85
  86 # LTO support?
  87 CHECK_CXX_ACCEPTS_FLAG("-flto" HAVE_LTO)
  88 IF(HAVE_LTO)
  89   OPTION(USE_LTO "use link time optimization" OFF)
  90   IF(USE_LTO)
  91     add_options(ALL_LANGUAGES ALL_BUILDS "-flto")
  92   ENDIF(USE_LTO)
  93 ENDIF(HAVE_LTO)
  94
  95 # set this to try linking dependencies as static as possible
  96 IF(ADDONS_PREFER_STATIC_LIBS)
  97   SET(CMAKE_FIND_LIBRARY_SUFFIXES .lib .a ${CMAKE_FIND_LIBRARY_SUFFIXES})
  98 ENDIF(ADDONS_PREFER_STATIC_LIBS)
  99