code.vuplus.com Git - vuplus_xbmc/blob - project/Win32BuildSetup/buildpvraddons.bat

   1 @ECHO OFF
   2
   3 REM Batch file to download and build xbmc-pvr-addons and place them in xbmc's addons folder
   4
   5 SET CUR_DIR=%CD%
   6 SET EXITCODE=0
   7
   8 SET DEPS_DIR=..\BuildDependencies
   9 SET TMP_DIR=%DEPS_DIR%\tmp
  10
  11 SET LIBNAME=xbmc-pvr-addons
  12 SET VERSION=eaefeffaee16216fd12fc3178c33d850dd6305ea
  13 SET SOURCE=%LIBNAME%
  14 SET GIT_URL=git://github.com/opdenkamp/%LIBNAME%.git
  15 SET SOURCE_DIR=%TMP_DIR%\%SOURCE%
  16 SET BUILT_ADDONS_DIR=%SOURCE_DIR%\addons
  17
  18 REM check if MSBuild.exe is used because it requires different command line switches
  19 IF "%msbuildemitsolution%" == "1" (
  20   set OPTS_EXE=%SOURCE_DIR%\project\VS2010Express\xbmc-pvr-addons.sln /m:4 /t:Build /p:Configuration="Release"
  21 ) ELSE (
  22   set OPTS_EXE=%SOURCE_DIR%\project\VS2010Express\xbmc-pvr-addons.sln /build Release
  23 )
  24
  25 REM Try wrapped msysgit - must be in the path
  26 SET GITEXE=git.cmd
  27 CALL %GITEXE% --help > NUL 2>&1
  28 IF errorlevel 1 GOTO nowrapmsysgit
  29 GOTO work
  30
  31 :nowrapmsysgit
  32
  33 REM Fallback on regular msysgit - must be in the path
  34 SET GITEXE=git.exe
  35 %GITEXE% --help > NUL
  36 IF errorlevel 9009 IF NOT errorlevel 9010 GOTO nomsysgit
  37 GOTO work
  38
  39 :nomsysgit
  40
  41 REM Fallback on tgit.exe of TortoiseGit if available
  42 SET GITEXE=tgit.exe
  43 %GITEXE% --version > NUL 2>&1
  44 IF errorlevel 9009 IF NOT errorlevel 9010 GOTO error
  45 GOTO work
  46
  47
  48 :work
  49 IF NOT EXIST "%TMP_DIR%" MD "%TMP_DIR%"
  50
  51 REM clone the git repository into SOURCE_DIR
  52 CALL %GITEXE% clone %GIT_URL% "%SOURCE_DIR%" > NUL 2>&1
  53 CD "%SOURCE_DIR%"
  54 REM get the proper revision
  55 CALL %GITEXE% checkout %VERSION% > NUL 2>&1
  56
  57 :build
  58 REM run DownloadBuildDeps.bat of xbmc-pvr-addons
  59 CD "project\BuildDependencies"
  60 CALL DownloadBuildDeps.bat > NUL 2>&1
  61 CD "%CUR_DIR%"
  62
  63 REM build xbmc-pvr-addons.sln
  64 ECHO Building PVR addons
  65 %1 %OPTS_EXE%
  66
  67 REM copy the built pvr addons into ADDONS_DIR
  68 CD "%BUILT_ADDONS_DIR%"
  69 SET ADDONS_DIR=..\..\..\..\Win32BuildSetup\BUILD_WIN32\Xbmc\xbmc-pvr-addons
  70
  71 REM exclude some files
  72 ECHO addon.xml.in >  exclude.txt
  73 ECHO _win32.exp   >> exclude.txt
  74 ECHO _win32.lib   >> exclude.txt
  75 ECHO _win32.pdb   >> exclude.txt
  76 FOR /D %%A IN ("pvr.*") DO (
  77   IF EXIST "%%A\addon" (
  78     ECHO Installing %%A
  79     XCOPY "%%A\addon\*" "%ADDONS_DIR%\%%A" /E /Q /I /Y /EXCLUDE:exclude.txt > NUL
  80   )
  81 )
  82 DEL exclude.txt > NUL
  83 CD "%CUR_DIR%"
  84
  85 REM cleanup temporary directories
  86 RMDIR "%TMP_DIR%" /S /Q > NUL
  87
  88 GOTO done
  89
  90 :error
  91 ECHO No git command available. Unable to fetch and build xbmc-pvr-addons.
  92 SET EXITCODE=1
  93
  94 :done
  95 SET GITEXE=
  96 EXIT /B %EXITCODE%