code.vuplus.com Git - vuplus_xbmc/blob - project/Win32BuildSetup/XBMC for Windows.nsi

   1 ;XBMC for Windows install script
   2 ;Copyright (C) 2005-2013 Team XBMC
   3 ;http://xbmc.org
   4
   5 ;Script by chadoe
   6
   7 ;--------------------------------
   8 ;Include Modern UI
   9
  10   !include "MUI2.nsh"
  11   !include "nsDialogs.nsh"
  12   !include "LogicLib.nsh"
  13   !include "WinVer.nsh"
  14
  15 ;--------------------------------
  16 ;define global used name
  17   !define APP_NAME "XBMC"
  18
  19 ;--------------------------------
  20 ;General
  21
  22   ;Name and file
  23   Name "${APP_NAME}"
  24   OutFile "${APP_NAME}Setup-${xbmc_revision}-${xbmc_branch}.exe"
  25
  26   XPStyle on
  27
  28   ;Default installation folder
  29   InstallDir "$PROGRAMFILES\${APP_NAME}"
  30
  31   ;Get installation folder from registry if available
  32   InstallDirRegKey HKCU "Software\${APP_NAME}" ""
  33
  34   ;Request application privileges for Windows Vista
  35   RequestExecutionLevel admin
  36
  37 ;--------------------------------
  38 ;Variables
  39
  40   Var StartMenuFolder
  41   Var PageProfileState
  42   Var DirectXSetupError
  43   Var VSRedistSetupError
  44
  45 ;--------------------------------
  46 ;Interface Settings
  47
  48   !define MUI_HEADERIMAGE
  49   !define MUI_ICON "..\..\xbmc\win32\xbmc.ico"
  50   !define MUI_WELCOMEFINISHPAGE_BITMAP "xbmc-left.bmp"
  51   !define MUI_COMPONENTSPAGE_SMALLDESC
  52   !define MUI_FINISHPAGE_LINK "Please visit http://xbmc.org for more information."
  53   !define MUI_FINISHPAGE_LINK_LOCATION "http://xbmc.org"
  54   !define MUI_FINISHPAGE_RUN "$INSTDIR\${APP_NAME}.exe"
  55   !define MUI_FINISHPAGE_RUN_NOTCHECKED
  56   !define MUI_ABORTWARNING
  57 ;--------------------------------
  58 ;Pages
  59
  60   !insertmacro MUI_PAGE_WELCOME
  61   !insertmacro MUI_PAGE_LICENSE "..\..\LICENSE.GPL"
  62   !insertmacro MUI_PAGE_COMPONENTS
  63   !insertmacro MUI_PAGE_DIRECTORY
  64
  65   ;Start Menu Folder Page Configuration
  66   !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKCU"
  67   !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\${APP_NAME}"
  68   !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
  69   !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
  70
  71   !insertmacro MUI_PAGE_INSTFILES
  72   !insertmacro MUI_PAGE_FINISH
  73
  74   !insertmacro MUI_UNPAGE_WELCOME
  75   !insertmacro MUI_UNPAGE_CONFIRM
  76   UninstPage custom un.UnPageProfile un.UnPageProfileLeave
  77   !insertmacro MUI_UNPAGE_INSTFILES
  78   !insertmacro MUI_UNPAGE_FINISH
  79
  80 ;--------------------------------
  81 ;Languages
  82
  83   !insertmacro MUI_LANGUAGE "English"
  84
  85 ;--------------------------------
  86 ;Install levels
  87
  88 InstType "Full"    ; 1.
  89 InstType "Normal"  ; 2.
  90 InstType "Minimal" ; 3.
  91
  92 ;--------------------------------
  93 ;Installer Sections
  94
  95 Section "XBMC" SecXBMC
  96   SetShellVarContext current
  97   SectionIn RO
  98   SectionIn 1 2 3 #section is in install type Normal/Full/Minimal
  99   ;ADD YOUR OWN FILES HERE...
 100   SetOutPath "$INSTDIR"
 101   File "${xbmc_root}\Xbmc\XBMC.exe"
 102   File "${xbmc_root}\Xbmc\copying.txt"
 103   File "${xbmc_root}\Xbmc\LICENSE.GPL"
 104   File "${xbmc_root}\Xbmc\*.dll"
 105   SetOutPath "$INSTDIR\language"
 106   File /r /x *.so "${xbmc_root}\Xbmc\language\*.*"
 107   SetOutPath "$INSTDIR\media"
 108   File /r /x *.so "${xbmc_root}\Xbmc\media\*.*"
 109   SetOutPath "$INSTDIR\sounds"
 110   File /r /x *.so "${xbmc_root}\Xbmc\sounds\*.*"
 111
 112   RMDir /r $INSTDIR\addons
 113   SetOutPath "$INSTDIR\addons"
 114   File /r /x skin.touched ${xbmc_root}\Xbmc\addons\*.*
 115
 116   ; delete system/python if its there
 117   SetOutPath "$INSTDIR\system"
 118   IfFileExists $INSTDIR\system\python 0 +2
 119     RMDir /r $INSTDIR\system\python
 120
 121   File /r /x *.so /x *_d.* /x tcl85g.dll /x tclpip85g.dll /x tk85g.dll "${xbmc_root}\Xbmc\system\*.*"
 122
 123   ; delete  msvc?90.dll's in INSTDIR, we use the vcredist installer later
 124   Delete "$INSTDIR\msvcr90.dll"
 125   Delete "$INSTDIR\msvcp90.dll"
 126
 127   ;Turn off overwrite to prevent files in xbmc\userdata\ from being overwritten
 128   SetOverwrite off
 129
 130   SetOutPath "$INSTDIR\userdata"
 131   File /r /x *.so  "${xbmc_root}\Xbmc\userdata\*.*"
 132
 133   ;Turn on overwrite for rest of install
 134   SetOverwrite on
 135
 136   ;Store installation folder
 137   WriteRegStr HKCU "Software\${APP_NAME}" "" $INSTDIR
 138
 139   ;Create uninstaller
 140   WriteUninstaller "$INSTDIR\Uninstall.exe"
 141
 142   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
 143   ;Create shortcuts
 144   SetOutPath "$INSTDIR"
 145
 146   CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
 147   CreateShortCut "$SMPROGRAMS\$StartMenuFolder\${APP_NAME}.lnk" "$INSTDIR\${APP_NAME}.exe" \
 148     "" "$INSTDIR\${APP_NAME}.exe" 0 SW_SHOWNORMAL \
 149     "" "Start ${APP_NAME}."
 150   CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Uninstall ${APP_NAME}.lnk" "$INSTDIR\Uninstall.exe" \
 151     "" "$INSTDIR\Uninstall.exe" 0 SW_SHOWNORMAL \
 152     "" "Uninstall ${APP_NAME}."
 153
 154   WriteINIStr "$SMPROGRAMS\$StartMenuFolder\Visit ${APP_NAME} Online.url" "InternetShortcut" "URL" "http://xbmc.org"
 155   !insertmacro MUI_STARTMENU_WRITE_END
 156
 157   ;add entry to add/remove programs
 158   WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}" \
 159                  "DisplayName" "${APP_NAME}"
 160   WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}" \
 161                  "UninstallString" "$INSTDIR\uninstall.exe"
 162   WriteRegDWORD HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}" \
 163                  "NoModify" 1
 164   WriteRegDWORD HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}" \
 165                  "NoRepair" 1
 166   WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}" \
 167                  "InstallLocation" "$INSTDIR"
 168   WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}" \
 169                  "DisplayIcon" "$INSTDIR\${APP_NAME}.exe,0"
 170   WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}" \
 171                  "Publisher" "Team XBMC"
 172   WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}" \
 173                  "HelpLink" "http://xbmc.org/support"
 174   WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}" \
 175                  "URLInfoAbout" "http://xbmc.org"
 176
 177 SectionEnd
 178
 179 SectionGroup "Skins" SecSkins
 180 Section "Confluence" SecSkinConfluence
 181   SectionIn 1 2 3 #section is in install type Full/Normal/Minimal
 182   SectionIn RO
 183   SetOutPath "$INSTDIR\addons\skin.confluence\"
 184   File /r "${xbmc_root}\Xbmc\addons\skin.confluence\*.*"
 185 SectionEnd
 186 ;skins.nsi is generated by genNsisIncludes.bat
 187 !include /nonfatal "skins.nsi"
 188 SectionGroupEnd
 189
 190 SectionGroup "PVR Addons" SecPvrAddons
 191 ;xbmc-pvr-addons.nsi is generated by genNsisIncludes.bat
 192 !include /nonfatal "xbmc-pvr-addons.nsi"
 193 SectionGroupEnd
 194
 195 ;--------------------------------
 196 ;Descriptions
 197
 198   ;Language strings
 199   LangString DESC_SecXBMC ${LANG_ENGLISH} "${APP_NAME}"
 200
 201   ;Assign language strings to sections
 202   !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 203   !insertmacro MUI_DESCRIPTION_TEXT ${SecXBMC} $(DESC_SecXBMC)
 204   !insertmacro MUI_FUNCTION_DESCRIPTION_END
 205
 206 ;--------------------------------
 207 ;Uninstaller Section
 208
 209 Var UnPageProfileDialog
 210 Var UnPageProfileCheckbox
 211 Var UnPageProfileCheckbox_State
 212 Var UnPageProfileEditBox
 213
 214 Function un.UnPageProfile
 215     !insertmacro MUI_HEADER_TEXT "Uninstall ${APP_NAME}" "Remove ${APP_NAME}'s profile folder from your computer."
 216   nsDialogs::Create /NOUNLOAD 1018
 217   Pop $UnPageProfileDialog
 218
 219   ${If} $UnPageProfileDialog == error
 220     Abort
 221   ${EndIf}
 222
 223   ${NSD_CreateLabel} 0 0 100% 12u "Do you want to delete the profile folder?"
 224   Pop $0
 225
 226   ${NSD_CreateText} 0 13u 100% 12u "$APPDATA\${APP_NAME}\"
 227   Pop $UnPageProfileEditBox
 228     SendMessage $UnPageProfileEditBox ${EM_SETREADONLY} 1 0
 229
 230   ${NSD_CreateLabel} 0 46u 100% 24u "Leave unchecked to keep the profile folder for later use or check to delete the profile folder."
 231   Pop $0
 232
 233   ${NSD_CreateCheckbox} 0 71u 100% 8u "Yes, also delete the profile folder."
 234   Pop $UnPageProfileCheckbox
 235
 236
 237   nsDialogs::Show
 238 FunctionEnd
 239
 240 Function un.UnPageProfileLeave
 241 ${NSD_GetState} $UnPageProfileCheckbox $UnPageProfileCheckbox_State
 242 FunctionEnd
 243
 244 Section "Uninstall"
 245
 246   SetShellVarContext current
 247
 248   ;ADD YOUR OWN FILES HERE...
 249   Delete "$INSTDIR\${APP_NAME}.exe"
 250   Delete "$INSTDIR\copying.txt"
 251   Delete "$INSTDIR\known_issues.txt"
 252   Delete "$INSTDIR\LICENSE.GPL"
 253   Delete "$INSTDIR\glew32.dll"
 254   Delete "$INSTDIR\SDL.dll"
 255   Delete "$INSTDIR\zlib1.dll"
 256   Delete "$INSTDIR\xbmc.log"
 257   Delete "$INSTDIR\xbmc.old.log"
 258   Delete "$INSTDIR\python26.dll"
 259   Delete "$INSTDIR\python27.dll"
 260   Delete "$INSTDIR\libcdio-*.dll"
 261   Delete "$INSTDIR\libiconv-2.dll"
 262   RMDir /r "$INSTDIR\language"
 263   RMDir /r "$INSTDIR\media"
 264   RMDir /r "$INSTDIR\plugins"
 265   RMDir /r "$INSTDIR\scripts"
 266   RMDir /r "$INSTDIR\skin"
 267   RMDir /r "$INSTDIR\sounds"
 268   RMDir /r "$INSTDIR\system"
 269   RMDir /r "$INSTDIR\visualisations"
 270   RMDir /r "$INSTDIR\addons"
 271   RMDir /r "$INSTDIR\web"
 272   RMDir /r "$INSTDIR\cache"
 273
 274   Delete "$INSTDIR\Uninstall.exe"
 275
 276 ;Uninstall User Data if option is checked, otherwise skip
 277   ${If} $UnPageProfileCheckbox_State == ${BST_CHECKED}
 278     RMDir /r "$INSTDIR\userdata"
 279     RMDir "$INSTDIR"
 280     RMDir /r "$APPDATA\${APP_NAME}\"
 281   ${Else}
 282 ;Even if userdata is kept in %appdata%\xbmc\userdata, the $INSTDIR\userdata should be cleaned up on uninstall if not used
 283 ;If guisettings.xml exists in the XBMC\userdata directory, do not delete XBMC\userdata directory
 284 ;If that file does not exists, then delete that folder and $INSTDIR
 285     IfFileExists $INSTDIR\userdata\guisettings.xml +3
 286       RMDir /r "$INSTDIR\userdata"
 287       RMDir "$INSTDIR"
 288   ${EndIf}
 289
 290
 291   !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
 292   Delete "$SMPROGRAMS\$StartMenuFolder\${APP_NAME}.lnk"
 293   Delete "$SMPROGRAMS\$StartMenuFolder\Uninstall ${APP_NAME}.lnk"
 294   Delete "$SMPROGRAMS\$StartMenuFolder\Visit ${APP_NAME} Online.url"
 295   RMDir "$SMPROGRAMS\$StartMenuFolder"
 296   DeleteRegKey HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APP_NAME}"
 297
 298   DeleteRegKey /ifempty HKCU "Software\${APP_NAME}"
 299
 300 SectionEnd
 301
 302 ;--------------------------------
 303 ;vs redist installer Section
 304
 305 Section "Microsoft Visual C++ 2008/2010 Redistributable Package (x86)" SEC_VCREDIST
 306
 307   SectionIn 1 2 #section is in install type Full/Normal and when not installed
 308
 309   DetailPrint "Running VS Redist Setup..."
 310
 311   ;vc90 for python
 312   SetOutPath "$TEMP\vc2008"
 313   File "${xbmc_root}\..\dependencies\vcredist\2008\vcredist_x86.exe"
 314   ExecWait '"$TEMP\vc2008\vcredist_x86.exe" /q' $VSRedistSetupError
 315   RMDir /r "$TEMP\vc2008"
 316
 317   ;vc100
 318   SetOutPath "$TEMP\vc2010"
 319   File "${xbmc_root}\..\dependencies\vcredist\2010\vcredist_x86.exe"
 320   DetailPrint "Running VS Redist Setup..."
 321   ExecWait '"$TEMP\vc2010\vcredist_x86.exe" /q' $VSRedistSetupError
 322   RMDir /r "$TEMP\vc2010"
 323
 324   DetailPrint "Finished VS Redist Setup"
 325   SetOutPath "$INSTDIR"
 326 SectionEnd
 327
 328 ;--------------------------------
 329 ;DirectX webinstaller Section
 330
 331 !if "${xbmc_target}" == "dx"
 332 !define DXVERSIONDLL "$SYSDIR\D3DX9_43.dll"
 333
 334 Section "DirectX Install" SEC_DIRECTX
 335
 336   SectionIn 1 2 #section is in install type Full/Normal and when not installed
 337
 338   DetailPrint "Running DirectX Setup..."
 339
 340   SetOutPath "$TEMP\dxsetup"
 341   File "${xbmc_root}\..\dependencies\dxsetup\dsetup32.dll"
 342   File "${xbmc_root}\..\dependencies\dxsetup\DSETUP.dll"
 343   File "${xbmc_root}\..\dependencies\dxsetup\dxdllreg_x86.cab"
 344   File "${xbmc_root}\..\dependencies\dxsetup\DXSETUP.exe"
 345   File "${xbmc_root}\..\dependencies\dxsetup\dxupdate.cab"
 346   File "${xbmc_root}\..\dependencies\dxsetup\Jun2010_D3DCompiler_43_x86.cab"
 347   File "${xbmc_root}\..\dependencies\dxsetup\Jun2010_d3dx9_43_x86.cab"
 348   ExecWait '"$TEMP\dxsetup\dxsetup.exe" /silent' $DirectXSetupError
 349   RMDir /r "$TEMP\dxsetup"
 350   SetOutPath "$INSTDIR"
 351
 352   DetailPrint "Finished DirectX Setup"
 353
 354 SectionEnd
 355
 356 Section "-Check DirectX installation" SEC_DIRECTXCHECK
 357
 358   IfFileExists ${DXVERSIONDLL} +2 0
 359     MessageBox MB_OK|MB_ICONSTOP|MB_TOPMOST|MB_SETFOREGROUND "DirectX9 wasn't installed properly.$\nPlease download the DirectX End-User Runtime from Microsoft and install it again."
 360
 361 SectionEnd
 362
 363 Function .onInit
 364   ${IfNot} ${AtLeastWinVista}
 365     MessageBox MB_OK|MB_ICONSTOP|MB_TOPMOST|MB_SETFOREGROUND "Windows Vista or above required.$\nThis program can not be run on Windows XP"
 366     Quit
 367   ${EndIf}
 368   # set section 'SEC_DIRECTX' as selected and read-only if required dx version not found
 369   IfFileExists ${DXVERSIONDLL} +3 0
 370   IntOp $0 ${SF_SELECTED} | ${SF_RO}
 371   SectionSetFlags ${SEC_DIRECTX} $0
 372 FunctionEnd
 373 !endif