code.vuplus.com Git - vuplus_openembedded/blob - packages/qt/qt4-x11-free_4.1.2.bb

   1 DESCRIPTION = "Qt/X11 Version ${PV}"
   2 SECTION = "x11/libs"
   3 PRIORITY = "optional"
   4 HOMEPAGE = "http://www.trolltech.com"
   5 LICENSE = "GPL QPL"
   6 DEPENDS = "uicmoc4-native qmake2-native freetype jpeg virtual/libx11 xft libxext libxrender libxrandr libxcursor"
   7 PROVIDES = "qt4x11"
   8 PR = "r1"
   9
  10 SRC_URI = "ftp://ftp.trolltech.com/qt/source/qt-x11-opensource-src-${PV}.tar.gz \
  11            file://cross-compile.patch;patch=1 \
  12            file://fix-resinit-declaration.patch;patch=1 \
  13            file://no-tools.patch;patch=1 \
  14            file://no-qmake.patch;patch=1 \
  15            file://gcc4_1.patch;patch=1 \
  16            file://configurable-cpu-extensions.patch;patch=1 \
  17            file://fix-mkspecs.patch;patch=1 \
  18            file://fix-asm-constraints.patch;patch=1"
  19 S = "${WORKDIR}/qt-x11-opensource-src-${PV}"
  20
  21 PARALLEL_MAKE = ""
  22
  23 inherit qmake-base qt4x11 pkgconfig
  24
  25 export QTDIR = "${S}"
  26 STAGING_QT_DIR = "${STAGING_DIR}/${TARGET_SYS}/qt4"
  27 EXTRA_OEMAKE = "-e"
  28
  29 def qt_arch(d):
  30         import bb, re
  31         arch = bb.data.getVar('TARGET_ARCH', d, 1)
  32         if re.match("^i.86$", arch):
  33                 arch = "x86"
  34         elif re.match("^arm.*", arch):
  35                 arch = "arm"
  36         elif arch == "x86_64":
  37                 arch = "x86"
  38         elif arch == "mipsel":
  39                 arch = "mips"
  40         return arch
  41
  42 QT_ARCH := "${@qt_arch(d)}"
  43
  44 # FIXME:
  45 # * add missing options
  46 QT_CONFIG_FLAGS = "-release -shared -qt-zlib -system-libjpeg -no-nas-sound -no-sm -no-libmng -qt-libpng -no-gif -no-xinerama \
  47                    -no-tablet -no-xkb -no-nis -no-cups -no-opengl \
  48                    -nosse \
  49                    -no-sql-ibase -no-sql-mysql -no-sql-odbc -no-sql-psql -no-sql-sqlite -no-sql-sqlite2 \
  50                    -verbose -stl -no-accessibility"
  51
  52 EXTRA_ENV = 'QMAKE="${STAGING_BINDIR}/qmake2 -after DEFINES+=QT_NO_XIM INCPATH+=${STAGING_INCDIR} \
  53              INCPATH+=${STAGING_INCDIR}/freetype2 LIBS+=-L${STAGING_LIBDIR}" \
  54              QMAKESPEC="${QMAKESPEC}" LINK="${CXX} -Wl,-rpath-link,${STAGING_LIBDIR}" \
  55              AR="${TARGET_PREFIX}ar cqs" \
  56              MOC="${STAGING_BINDIR}/moc4" UIC="${STAGING_BINDIR}/uic4" MAKE="make -e"'
  57
  58 do_configure() {
  59         echo "DEFINES -= QT_NO_CAST_TO_ASCII" >>src/qbase.pri
  60         echo "DEFINES += QT_NO_XIM" >>src/qbase.pri
  61         unset QMAKESPEC
  62         ln -sf ${STAGING_BINDIR}/qmake2 bin/qmake
  63         ln -sf ./linux-g++ mkspecs/linux-gnueabi-g++
  64         #export QMAKESPEC="linux-oe-g++"
  65         #rm -rf ./mkspecs
  66         #ln -sf ${QMAKE_MKSPEC_PATH} ./mkspecs
  67         echo yes | ./configure -prefix / -platform ${TARGET_OS}-g++ -crossarch ${QT_ARCH} ${QT_CONFIG_FLAGS} -fast \
  68                 -L${STAGING_LIBDIR} -I${STAGING_INCDIR} -I${STAGING_INCDIR}/freetype2 -I${STAGING_INCDIR}/mysql
  69 }
  70
  71 # FIXME: Might want to compile the cross tools for the -dev packages as well...
  72 do_compile() {
  73         unset CFLAGS CXXFLAGS
  74         install -m 0755 ${STAGING_BINDIR}/rcc4 ${S}/bin/rcc
  75         install -m 0755 ${STAGING_BINDIR}/moc4 ${S}/bin/moc
  76         install -m 0755 ${STAGING_BINDIR}/uic4 ${S}/bin/uic
  77
  78         oe_runmake ${EXTRA_ENV}
  79 }
  80
  81 PARTS = "3Support Core Designer DesignerComponents Gui Network Sql Svg Test Xml"
  82
  83 do_stage() {
  84         oe_runmake install INSTALL_ROOT=/
  85         install -m 0755 ${STAGING_BINDIR}/rcc4 ${STAGING_QT_DIR}/bin/rcc
  86         install -m 0755 ${STAGING_BINDIR}/moc4 ${STAGING_QT_DIR}/bin/moc
  87         install -m 0755 ${STAGING_BINDIR}/uic4 ${STAGING_QT_DIR}/bin/uic
  88
  89 }
  90
  91 # FIXME: Might want to call oe_runmake install INSTALL_ROOT=${D}/${prefix} as well...
  92 # FIXME: Might want to install everything into ${libdir}/qt4/* to match the usual packing...
  93 do_install() {
  94         install -d ${D}${libdir}
  95         install -d ${D}${bindir}
  96         for part in ${PARTS}
  97         do
  98                 oe_libinstall -so -C lib libQt$part ${D}${libdir}
  99         done
 100         oe_libinstall -a -C lib libQtAssistantClient ${STAGING_QT_DIR}
 101         cp -pPR include/* ${D}${incdir}
 102         cp -pPR plugins ${D}${libdir}
 103         cp -pPR bin/* ${D}${bindir}
 104
 105         install -d ${D}${bindir}/qt4-examples
 106         for binary in `find examples -perm 0755 -type f`
 107         do
 108                 install -m 0755 $binary ${D}${bindir}/qt4-examples/
 109         done
 110         install -d ${D}${bindir}/qt4-demos
 111         for binary in `find demos -perm 0755 -type f`
 112         do
 113                 install -m 0755 $binary ${D}${bindir}/qt4-demos/
 114         done
 115 }
 116
 117 PACKAGES =+ "libqtcore4 libqtgui4 libqtnetwork4 libqtsql4 libqtsvg4 libqttest4 libqtxml4 \
 118              libqtdesigner4 libqtdesignercomponents4 libqt3support4 \
 119              qt4-assistant qt4-common qt4-designer qt4-demos qt4-examples qt4-linguist \
 120              qt4-plugins-accessible qt4-plugins-codecs qt4-plugins-designer qt4-plugins-imageformats qt4-plugins-sqldrivers"
 121
 122 ALLOW_EMPTY = "1"
 123 FILES_${PN} = ""
 124 RDEPENDS_${PN} = "${PACKAGES}"
 125
 126 FILES_libqtcore4               = "${libdir}/libQtCore.so*"
 127 FILES_libqtgui4                = "${libdir}/libQtGui.so*"
 128 FILES_libqtnetwork4            = "${libdir}/libQtNetwork.so*"
 129 FILES_libqtsql4                = "${libdir}/libQtSql.so*"
 130 FILES_libqtsvg4                = "${libdir}/libQtSvg.so*"
 131 FILES_libqttest4               = "${libdir}/libQtTest.so*"
 132 FILES_libqtxml4                = "${libdir}/libQtXml.so*"
 133 FILES_libqtdesigner4           = "${libdir}/libQtDesigner.so*"
 134 FILES_libqtdesignercomponents4 = "${libdir}/libQtDesignerComponents.so*"
 135 FILES_libqt3support4           = "${libdir}/libQt3Support.so*"
 136
 137 FILES_qt4-plugins-accessible   = "${libdir}/plugins/accessible/*.so"
 138 FILES_qt4-plugins-codecs       = "${libdir}/plugins/codecs/*.so"
 139 FILES_qt4-plugins-designer     = "${libdir}/plugins/designer/*.so"
 140 FILES_qt4-plugins-imageformats = "${libdir}/plugins/imageformats/*.so"
 141 FILES_qt4-plugins-sqldrivers   = "${libdir}/plugins/sqldrivers/*.so"
 142
 143 FILES_qt4-assistant            = "${bindir}/*assistant*"
 144 FILES_qt4-designer             = "${bindir}/*designer*"
 145 FILES_qt4-linguist             = "${bindir}/*linguist* ${bindir}/lrelease ${bindir}/lupdate ${bindir}/qm2ts"
 146
 147 FILES_qt4-common               = "${bindir}/qtconfig"
 148 FILES_qt4-examples             = "${bindir}/qt4-examples/*"
 149 FILES_qt4-demos                = "${bindir}/qtdemo ${bindir}/qt4-demos/*"
 150
 151 FILES_${PN}-dev               += "${bindir}/rcc ${bindir}/uic* ${bindir}/moc ${bindir}/qmake ${bindir}/syncqt \
 152                                   ${bindir}/qt3to4 ${bindir}/findtr"