code.vuplus.com Git - vuplus_openembedded/blob - packages/images/fso-image.bb

   1 #------------------------------------------------------
   2 # freesmartphone.org Image Recipe
   3 #------------------------------------------------------
   4
   5 IMAGE_LINGUAS = ""
   6
   7 # getting the base system up
   8 BASE_INSTALL = "\
   9   ${MACHINE_TASK_PROVIDER} \
  10   netbase \
  11   sysfsutils \
  12   module-init-tools-depmod \
  13   rsync \
  14   screen \
  15   fbset \
  16   fbset-modes \
  17 "
  18
  19 # getting an X window system up
  20 X_INSTALL = "\
  21   e-wm \
  22   illume \
  23   illume-theme-freesmartphone \
  24   ${XSERVER} \
  25   xserver-kdrive-common \
  26   xserver-nodm-init \
  27   xauth \
  28   xhost \
  29   xset \
  30   xrandr \
  31   \
  32   fontconfig-utils \
  33   \
  34   ttf-dejavu-common \
  35   ttf-dejavu-sans \
  36   ttf-dejavu-serif \
  37   \
  38 "
  39
  40 # useful command line tools
  41 TOOLS_INSTALL = "\
  42 #  bash \
  43   dosfstools \
  44   htop \
  45   iptables \
  46   lsof \
  47   mickeydbus \
  48   mickeyterm \
  49   mtd-utils \
  50   nano \
  51   powertop \
  52   s3c24xx-gpio \
  53 "
  54
  55 # audio
  56 AUDIO_INSTALL = "\
  57   alsa-oss \
  58   alsa-state \
  59   alsa-utils-aplay \
  60   alsa-utils-amixer \
  61   gst-meta-audio \
  62   gst-plugin-mad \
  63   gst-plugin-modplug \
  64   gst-plugin-sid \
  65   fso-sounds \
  66 "
  67
  68 GTK_INSTALL = "\
  69   openmoko-calculator2 \
  70   openmoko-terminal2 \
  71   gpe-scap \
  72   tangogps-fso \
  73 "
  74
  75 GAMES_INSTALL = "\
  76   numptyphysics \
  77 "
  78
  79 # FIXME these should rather be part of alsa-state,
  80 # once Om stabilizes them...
  81 AUDIO_INSTALL_append_om-gta01 = "\
  82   openmoko-alsa-scenarios \
  83 "
  84 AUDIO_INSTALL_append_om-gta02 = "\
  85   openmoko-alsa-scenarios \
  86 "
  87
  88 # python
  89 PYTHON_INSTALL = "\
  90   task-python-efl \
  91   python-codecs \
  92   python-gst \
  93 "
  94
  95 # zhone
  96 ZHONE_INSTALL = "\
  97   gsm0710muxd \
  98   frameworkd \
  99   zhone \
 100 "
 101
 102 IMAGE_INSTALL = "\
 103   ${BASE_INSTALL} \
 104   ${X_INSTALL} \
 105   ${GTK_INSTALL} \
 106   ${GAMES_INSTALL} \
 107   ${AUDIO_INSTALL} \
 108   ${TOOLS_INSTALL} \
 109   ${PYTHON_INSTALL} \
 110   ${ZHONE_INSTALL} \
 111 "
 112
 113 inherit image
 114
 115 # perform some convenience tweaks to the rootfs
 116 fso_rootfs_postprocess() {
 117     curdir=$PWD
 118     cd ${IMAGE_ROOTFS}
 119     # date/time
 120     date "+%m%d%H%M%Y" >./etc/timestamp
 121     # alias foo
 122     echo "alias pico=nano" >>./etc/profile
 123     echo "alias fso='cd /local/pkg/fso'" >>./etc/profile
 124     echo "alias ipkg='opkg'" >>./etc/profile
 125     # nfs
 126     mkdir -p ./local/pkg
 127     echo >>./etc/fstab
 128     echo "# NFS Host" >>./etc/fstab
 129     echo "192.168.0.200:/local/pkg /local/pkg nfs noauto,nolock,soft,rsize=32768,wsize=32768 0 0" >>./etc/fstab
 130     # fix .desktop files for illume
 131     desktop=`find ./usr/share/applications -name "*.desktop"`
 132     for file in $desktop; do
 133         echo "Categories=Office;" >>$file
 134     done
 135     # minimal gtk theme foo
 136     mkdir -p ./etc/gtk-2.0/
 137     echo 'gtk-font-name = "Sans 5"' >> ./etc/gtk-2.0/gtkrc
 138     cd $curdir
 139 }
 140
 141 ROOTFS_POSTPROCESS_COMMAND += "fso_rootfs_postprocess"