code.vuplus.com Git - vuplus_openembedded/blob - libqpe/libqpe-opie_1.1.7.oe

   1 DESCRIPTION = "Base library for the Qt Palmtop Environment"
   2 SECTION = "opie/libs"
   3 PRIORITY = "optional"
   4 MAINTAINER = "Michael 'Mickey' Lauer <mickey@Vanille.de>"
   5 LICENSE = "GPL"
   6 DEPENDS = "uicmoc-native qte-for-opie"
   7 PROVIDES = "virtual/libqpe"
   8 PR = "r2"
   9
  10 TAG = "${@'v' + oe.data.getVar('PV',d,1).replace('.', '_')}"
  11 SRC_URI = "${HANDHELDS_CVS};tag=${TAG};module=opie/library \
  12         file://nomax.patch;patch=1;pnum=2"
  13 S = "${WORKDIR}/library"
  14
  15 inherit qmake
  16
  17 QMAKE_PROFILES = "library.pro"
  18 EXTRA_QMAKEVARS_PRE  = "CONFIG+=LIBQPE_WITHROHFEEDBACK"
  19 EXTRA_QMAKEVARS_POST = "DESTDIR="
  20
  21 CXXFLAGS_append = " -DQWS -DOPIE_NO_ERASE_RECT_HACKFIX -DOPIE_NEW_MALLOC  -fno-rtti -fno-exceptions"
  22
  23 CXXFLAGS_append_husky = " -DOPIE_NO_WINDOWED "
  24 CXXFLAGS_append_corgi = " -DOPIE_NO_WINDOWED "
  25 CXXFLAGS_append_shepherd = " -DOPIE_NO_WINDOWED "
  26 CXXFLAGS_append_tosa = " -DOPIE_NO_WINDOWED "
  27
  28 do_compile() {
  29         mkdir -p ${STAGING_INCDIR}/qpe \
  30                  ${STAGING_INCDIR}/qtopia \
  31                  ${STAGING_INCDIR}/opie \
  32                  ${STAGING_INCDIR}/opie2 \
  33                  ${STAGING_INCDIR}/qtopia/private
  34         for i in ${S}/*.h
  35         do
  36                 install -m 0644 $i ${STAGING_INCDIR}/qpe/`basename $i`
  37                 install -m 0644 $i ${STAGING_INCDIR}/qtopia/`basename $i`
  38                 install -m 0644 $i ${STAGING_INCDIR}/qtopia/private/`basename $i`
  39         done
  40         for i in ${S}/backend/*.h
  41         do
  42                 install -m 0644 $i ${STAGING_INCDIR}/qpe/`basename $i`
  43                 install -m 0644 $i ${STAGING_INCDIR}/qtopia/`basename $i`
  44                 install -m 0644 $i ${STAGING_INCDIR}/qtopia/private/`basename $i`
  45         done
  46         rm -f ${STAGING_INCDIR}/qtopia/*_p.h # remove private stuff out of qtopia
  47         oe_runmake MOC=${STAGING_BINDIR}/moc UIC=${STAGING_BINDIR}/uic
  48 }
  49
  50 do_stage() {
  51         oe_libinstall -so libqpe ${STAGING_LIBDIR}
  52         # include files already done during do_compile
  53 }
  54
  55 do_install() {
  56         oe_libinstall -so libqpe ${D}/${palmtopdir}/lib
  57 }
  58
  59 PACKAGES = "libqpe1"
  60 FILES_libqpe1 = "${palmtopdir}/lib"