code.vuplus.com Git - vuplus_openembedded/blob - glibc/glibc_2.3.2+cvs20040726.oe

   1 DESCRIPTION = "GNU C Library"
   2 HOMEPAGE = "http://www.gnu.org/software/libc/libc.html"
   3 LICENSE = "LGPL"
   4 SECTION = "libs"
   5 PRIORITY = "required"
   6 MAINTAINER = "Phil Blundell <pb@handhelds.org>"
   7
   8 FILESDIR = "${@os.path.dirname(oe.data.getVar('FILE',d,1))}/glibc-cvs"
   9 PR = "r13"
  10
  11 GLIBC_ADDONS ?= "linuxthreads"
  12 GLIBC_EXTRA_OECONF ?= ""
  13
  14 #
  15 # For now, we will skip building of a gcc package if it is a uclibc one
  16 # and our build is not a uclibc one, and we skip a glibc one if our build
  17 # is a uclibc build.
  18 #
  19 # See the note in gcc/gcc_3.4.0.oe
  20 #
  21
  22 python __anonymous () {
  23     import oe, re
  24     uc_os = (re.match('.*uclibc$', oe.data.getVar('TARGET_OS', d, 1)) != None)
  25     if uc_os:
  26         raise oe.parse.SkipPackage("incompatible with target %s" %
  27                                    oe.data.getVar('TARGET_OS', d, 1))
  28 }
  29
  30 PACKAGES = "glibc catchsegv sln nscd ldd localedef glibc-utils glibc-dev glibc-doc glibc-locale libsegfault glibc-extra-nss glibc-thread-db glibc-pcprofile"
  31
  32 # nptl needs unwind support in gcc, which can't be built without glibc.
  33 PROVIDES = "virtual/libc ${@['virtual/${TARGET_PREFIX}libc-for-gcc', '']['nptl' in '${GLIBC_ADDONS}']}"
  34 PROVIDES += "virtual/libintl virtual/libiconv"
  35 DEPENDS = "patcher-native ${@['virtual/${TARGET_PREFIX}gcc-initial', 'virtual/${TARGET_PREFIX}gcc']['nptl' in '${GLIBC_ADDONS}']} linux-libc-headers"
  36 INHIBIT_DEFAULT_DEPS = "1"
  37
  38 libc_baselibs = "/lib/libc* /lib/libm* /lib/ld* /lib/libpthread* /lib/libresolv* /lib/librt* /lib/libutil* /lib/libnsl* /lib/libnss_files* /lib/libnss_compat* /lib/libnss_dns* /lib/libdl* /lib/libanl* /lib/libBrokenLocale*"
  39
  40 FILES_${PN} = "${sysconfdir} ${libc_baselibs} /sbin/ldconfig ${libexecdir} ${datadir}/zoneinfo ${libdir}/locale"
  41 FILES_ldd = "${bindir}/ldd"
  42 FILES_libsegfault = "/lib/libSegFault*"
  43 FILES_glibc-extra-nss = "/lib/libnss*"
  44 FILES_sln = "/sbin/sln"
  45 FILES_glibc-dev_append = " ${libdir}/*.o ${bindir}/rpcgen"
  46 FILES_nscd = "${sbindir}/nscd*"
  47 FILES_glibc-utils = "${bindir} ${sbindir}"
  48 FILES_glibc-gconv = "${libdir}/gconv"
  49 FILES_catchsegv = "${bindir}/catchsegv"
  50 DEPENDS_catchsegv = "libsegfault"
  51 FILES_glibc-pcprofile = "/lib/libpcprofile.so"
  52 FILES_glibc-thread-db = "/lib/libthread_db*"
  53 FILES_localedef = "${bindir}/localedef"
  54 RPROVIDES_glibc-dev += "libc-dev"
  55
  56 #          file://noinfo.patch;patch=1
  57 #          file://ldconfig.patch;patch=1;pnum=0
  58 SRC_URI = "cvs://anoncvs@sources.redhat.com/cvs/glibc;module=libc;date=${@oe.data.getVar('PV', d, 1)[9:]} \
  59            file://arm-ioperm.patch;patch=1;pnum=0 \
  60            file://makeconfig.patch;patch=1;pnum=0 \
  61            file://ldd.patch;patch=1;pnum=0 \
  62            file://fhs-linux-paths.patch;patch=1 \
  63            file://arm-no-hwcap.patch;patch=1;pnum=0 \
  64            file://arm-memcpy.patch;patch=1;pnum=0 \
  65            file://arm-longlong.patch;patch=1;pnum=0 \
  66            file://arm-machine-gmon.patch;patch=1;pnum=0 \
  67            \
  68            file://etc/ld.so.conf \
  69            file://generate-supported.mk"
  70
  71 # seems to fail on tls platforms
  72 SRC_URI_append_arm = " file://dyn-ldconfig.patch;patch=1;pnum=0"
  73
  74 SRC_URI_append_ramses = " file://ldsocache-varrun.patch;patch=1"
  75
  76 S = "${WORKDIR}/libc"
  77 B = "${WORKDIR}/build-${TARGET_SYS}"
  78
  79 inherit autotools
  80
  81 EXTRA_OECONF = "--enable-kernel=${OLDEST_KERNEL} \
  82                 --without-cvs --disable-profile --disable-debug --without-gd \
  83                 --enable-clocale=gnu \
  84                 --enable-add-ons=${GLIBC_ADDONS} \
  85                 --with-headers=${CROSS_DIR}/${TARGET_SYS}/include \
  86                 ${GLIBC_EXTRA_OECONF}"
  87
  88 EXTRA_OECONF += "${@get_glibc_fpu_setting(oe, d)}"
  89
  90 def get_glibc_fpu_setting(oe, d):
  91         if oe.data.getVar('TARGET_FPU', d, 1) in [ 'soft' ]:
  92                 return "--without-fp"
  93         return ""
  94
  95 do_configure () {
  96 # override this function to avoid the autoconf/automake/aclocal/autoheader
  97 # calls for now
  98 # don't pass CPPFLAGS into configure, since it upsets the kernel-headers
  99 # version check and doesn't really help with anything
 100         if [ -z "`which rpcgen`" ]; then
 101                 echo "rpcgen not found.  Install glibc-devel."
 102                 exit 1
 103         fi
 104         (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
 105         CPPFLAGS="" oe_runconf
 106 }
 107
 108 rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
 109           yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
 110           rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
 111
 112 do_compile () {
 113         # this really is arm specific
 114         touch ${S}/sysdeps/arm/framestate.c
 115         # -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
 116         unset LDFLAGS
 117         base_do_compile
 118         (
 119                 cd ${S}/sunrpc/rpcsvc
 120                 for r in ${rpcsvc}; do
 121                         h=`echo $r|sed -e's,\.x$,.h,'`
 122                         rpcgen -h $r -o $h || oewarn "unable to generate header for $r"
 123                 done
 124         )
 125 }
 126
 127 do_stage() {
 128         rm -f ${STAGING_LIBDIR}/libc.so.6
 129         oe_runmake 'install_root=${STAGING_DIR}/${HOST_SYS}' \
 130                    'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
 131                    '${STAGING_LIBDIR}/libc.so.6' \
 132                    install-headers install-lib
 133
 134         install -d ${STAGING_INCDIR}/gnu \
 135                    ${STAGING_INCDIR}/bits \
 136                    ${STAGING_INCDIR}/rpcsvc
 137         install -m 0644 ${S}/include/gnu/stubs.h ${STAGING_INCDIR}/gnu/
 138         install -m 0644 ${B}/bits/stdio_lim.h ${STAGING_INCDIR}/bits/
 139         install -m 0644 misc/syscall-list.h ${STAGING_INCDIR}/bits/syscall.h
 140         for r in ${rpcsvc}; do
 141                 h=`echo $r|sed -e's,\.x$,.h,'`
 142                 install -m 0644 ${S}/sunrpc/rpcsvc/$h ${STAGING_INCDIR}/rpcsvc/
 143         done
 144         for i in libc.a libc_pic.a libc_nonshared.a; do
 145                 install -m 0644 ${B}/$i ${STAGING_LIBDIR}/ || die "failed to install $i"
 146         done
 147         echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${STAGING_LIBDIR}/libpthread.so
 148         echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${STAGING_LIBDIR}/libc.so
 149
 150         rm -f ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6
 151         oe_runmake 'install_root=${CROSS_DIR}/${TARGET_SYS}' \
 152                    'includedir=/include' 'libdir=/lib' 'slibdir=/lib' \
 153                    '${CROSS_DIR}/${TARGET_SYS}/lib/libc.so.6' \
 154                    install-headers install-lib
 155
 156         install -d ${CROSS_DIR}/${TARGET_SYS}/include/gnu \
 157                    ${CROSS_DIR}/${TARGET_SYS}/include/bits \
 158                    ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc
 159         install -m 0644 ${S}/include/gnu/stubs.h ${CROSS_DIR}/${TARGET_SYS}/include/gnu/
 160         install -m 0644 ${B}/bits/stdio_lim.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/
 161         install -m 0644 misc/syscall-list.h ${CROSS_DIR}/${TARGET_SYS}/include/bits/syscall.h
 162         for r in ${rpcsvc}; do
 163                 h=`echo $r|sed -e's,\.x$,.h,'`
 164                 install -m 0644 ${S}/sunrpc/rpcsvc/$h ${CROSS_DIR}/${TARGET_SYS}/include/rpcsvc/
 165         done
 166
 167         for i in libc.a libc_pic.a libc_nonshared.a; do
 168                 install -m 0644 ${B}/$i ${CROSS_DIR}/${TARGET_SYS}/lib/ || die "failed to install $i"
 169         done
 170         echo 'GROUP ( libpthread.so.0 libpthread_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libpthread.so
 171         echo 'GROUP ( libc.so.6 libc_nonshared.a )' > ${CROSS_DIR}/${TARGET_SYS}/lib/libc.so
 172 }
 173
 174 include glibc-package.oeclass