code.vuplus.com Git - vuplus_webkit/blob - Source/WebKit2/WebProcess.pro

   1 TEMPLATE = app
   2 TARGET = QtWebProcess
   3 INSTALLS += target
   4
   5 isEmpty(INSTALL_BINS) {
   6     target.path = $$[QT_INSTALL_BINS]
   7 } else {
   8     target.path = $$INSTALL_BINS
   9 }
  10
  11 SOURCES += \
  12     qt/MainQt.cpp
  13
  14 isEmpty(OUTPUT_DIR): OUTPUT_DIR = ../..
  15 include($$PWD/../WebKit.pri)
  16
  17 DESTDIR = $$OUTPUT_DIR/bin
  18 !CONFIG(standalone_package): CONFIG -= app_bundle
  19
  20 QT += network
  21 macx:QT+=xml
  22
  23 linux-* {
  24     # From Creator's src/rpath.pri:
  25     # Do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
  26     # this expands to $ORIGIN (after qmake and make), it does NOT read a qmake var.
  27     QMAKE_RPATHDIR = \$\$ORIGIN/../lib $$QMAKE_RPATHDIR
  28     MY_RPATH = $$join(QMAKE_RPATHDIR, ":")
  29
  30     QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${MY_RPATH}\' -Wl,--no-undefined
  31     QMAKE_RPATHDIR =
  32 } else {
  33     QMAKE_RPATHDIR = $$OUTPUT_DIR/lib $$QMAKE_RPATHDIR
  34 }
  35
  36 contains(QT_CONFIG, opengl) {
  37     QT += opengl
  38     DEFINES += QT_CONFIGURED_WITH_OPENGL
  39 }