code.vuplus.com Git - vuplus_webkit/blob - Source/WebKit2/WebKit2.pri

   1 # WebKit2 - Qt4 build info
   2
   3 SOURCE_DIR = $$replace(PWD, /WebKit2, "")
   4
   5 # Use a config-specific target to prevent parallel builds file clashes on Mac
   6 mac: CONFIG(debug, debug|release): WEBKIT2_TARGET = webkit2d
   7 else: WEBKIT2_TARGET = webkit2
   8
   9 # Output in WebKit2/<config>
  10 CONFIG(debug, debug|release) : WEBKIT2_DESTDIR = debug
  11 else: WEBKIT2_DESTDIR = release
  12
  13 CONFIG(standalone_package) {
  14     isEmpty(WEBKIT2_GENERATED_SOURCES_DIR):WEBKIT2_GENERATED_SOURCES_DIR = $$PWD/generated
  15 } else {
  16     isEmpty(WEBKIT2_GENERATED_SOURCES_DIR):WEBKIT2_GENERATED_SOURCES_DIR = $$OUTPUT_DIR/WebKit2/generated
  17 }
  18
  19 WEBKIT2_INCLUDEPATH = \
  20     $$SOURCE_DIR/WebKit2 \
  21     $$SOURCE_DIR/WebKit2/Platform \
  22     $$SOURCE_DIR/WebKit2/Platform/CoreIPC \
  23     $$SOURCE_DIR/WebKit2/Platform/qt \
  24     $$SOURCE_DIR/WebKit2/Shared \
  25     $$SOURCE_DIR/WebKit2/Shared/API/c \
  26     $$SOURCE_DIR/WebKit2/Shared/CoreIPCSupport \
  27     $$SOURCE_DIR/WebKit2/Shared/Plugins \
  28     $$SOURCE_DIR/WebKit2/Shared/Plugins/Netscape \
  29     $$SOURCE_DIR/WebKit2/Shared/qt \
  30     $$SOURCE_DIR/WebKit2/UIProcess \
  31     $$SOURCE_DIR/WebKit2/UIProcess/API/C \
  32     $$SOURCE_DIR/WebKit2/UIProcess/API/cpp \
  33     $$SOURCE_DIR/WebKit2/UIProcess/API/cpp/qt \
  34     $$SOURCE_DIR/WebKit2/UIProcess/API/qt \
  35     $$SOURCE_DIR/WebKit2/UIProcess/Authentication \
  36     $$SOURCE_DIR/WebKit2/UIProcess/Downloads \
  37     $$SOURCE_DIR/WebKit2/UIProcess/Launcher \
  38     $$SOURCE_DIR/WebKit2/UIProcess/Plugins \
  39     $$SOURCE_DIR/WebKit2/UIProcess/qt \
  40     $$SOURCE_DIR/WebKit2/WebProcess \
  41     $$SOURCE_DIR/WebKit2/WebProcess/ApplicationCache \
  42     $$SOURCE_DIR/WebKit2/WebProcess/Authentication \
  43     $$SOURCE_DIR/WebKit2/WebProcess/Cookies \
  44     $$SOURCE_DIR/WebKit2/WebProcess/Cookies/qt \
  45     $$SOURCE_DIR/WebKit2/WebProcess/Downloads \
  46     $$SOURCE_DIR/WebKit2/WebProcess/Downloads/qt \
  47     $$SOURCE_DIR/WebKit2/WebProcess/FullScreen \
  48     $$SOURCE_DIR/WebKit2/WebProcess/Geolocation \
  49     $$SOURCE_DIR/WebKit2/WebProcess/IconDatabase \
  50     $$SOURCE_DIR/WebKit2/WebProcess/InjectedBundle \
  51     $$SOURCE_DIR/WebKit2/WebProcess/InjectedBundle/DOM \
  52     $$SOURCE_DIR/WebKit2/WebProcess/InjectedBundle/API/c \
  53     $$SOURCE_DIR/WebKit2/WebProcess/KeyValueStorage \
  54     $$SOURCE_DIR/WebKit2/WebProcess/MediaCache \
  55     $$SOURCE_DIR/WebKit2/WebProcess/Plugins \
  56     $$SOURCE_DIR/WebKit2/WebProcess/Plugins/Netscape \
  57     $$SOURCE_DIR/WebKit2/WebProcess/ResourceCache \
  58     $$SOURCE_DIR/WebKit2/WebProcess/WebCoreSupport \
  59     $$SOURCE_DIR/WebKit2/WebProcess/WebCoreSupport/qt \
  60     $$SOURCE_DIR/WebKit2/WebProcess/WebPage \
  61     $$SOURCE_DIR/WebKit2/WebProcess/qt \
  62     $$SOURCE_DIR/WebKit2/PluginProcess
  63
  64 INCLUDEPATH = $$WEBKIT2_INCLUDEPATH $$WEBKIT2_GENERATED_SOURCES_DIR $$INCLUDEPATH
  65
  66 defineTest(prependWebKit2Lib) {
  67     pathToWebKit2Output = $$ARGS/$$WEBKIT2_DESTDIR
  68
  69     win32-msvc*|wince*|win32-icc {
  70         LIBS = -l$$WEBKIT2_TARGET $$LIBS
  71         LIBS = -L$$pathToWebKit2Output $$LIBS
  72         POST_TARGETDEPS += $${pathToWebKit2Output}$${QMAKE_DIR_SEP}$${WEBKIT2_TARGET}.lib
  73     } else {
  74         QMAKE_LIBDIR = $$pathToWebKit2Output $$QMAKE_LIBDIR
  75         LIBS = -l$$WEBKIT2_TARGET $$LIBS
  76         POST_TARGETDEPS += $${pathToWebKit2Output}$${QMAKE_DIR_SEP}lib$${WEBKIT2_TARGET}.a
  77     }
  78
  79     # The following line is to prevent qmake from adding webkit2 to libQtWebKit's prl dependencies.
  80     CONFIG -= explicitlib
  81     CONFIG -= staticlib
  82
  83     export(QMAKE_LIBDIR)
  84     export(POST_TARGETDEPS)
  85     export(CONFIG)
  86     export(LIBS)
  87
  88     return(true)
  89 }