code.vuplus.com Git - vuplus_webkit/blob - Source/WebCore/css/make-css-file-arrays.pl

   1 #!/usr/bin/perl -w
   2 #
   3 #  Copyright (C) 2006 Apple Computer, Inc.
   4 #
   5 #  This library is free software; you can redistribute it and/or
   6 #  modify it under the terms of the GNU Library General Public
   7 #  License as published by the Free Software Foundation; either
   8 #  version 2 of the License, or (at your option) any later version.
   9 #
  10 #  This library is distributed in the hope that it will be useful,
  11 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 #  Library General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU Library General Public License
  16 #  along with this library; see the file COPYING.LIB.  If not, write to
  17 #  the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  18 #  Boston, MA 02110-1301, USA.
  19 #
  20
  21 # Usage: make-css-file-arrays.pl <header> <output> <input> ...
  22
  23 use strict;
  24 use Getopt::Long;
  25
  26 my $defines;
  27 my $preprocessor;
  28 GetOptions('defines=s' => \$defines,
  29            'preprocessor=s' => \$preprocessor);
  30
  31 my $header = $ARGV[0];
  32 shift;
  33
  34 my $out = $ARGV[0];
  35 shift;
  36
  37 open HEADER, ">", $header or die;
  38 open OUT, ">", $out or die;
  39
  40 print HEADER "namespace WebCore {\n";
  41 print OUT "namespace WebCore {\n";
  42
  43 for my $in (@ARGV) {
  44     $in =~ /(\w+)\.css$/ or die;
  45     my $name = $1;
  46
  47     # Slurp in the CSS file.
  48     my $text;
  49     # We should not set --defines option and run "moc" preprocessor on Qt.
  50     # See http://webkit.org/b/37296.
  51     if (!$defines) {
  52         open IN, "<", $in or die;
  53         { local $/; $text = <IN>; }
  54         close IN;
  55         # Remove preprocessor directives.
  56         $text =~ s|^#.*?$||mg;
  57     } else {
  58         require preprocessor;
  59         $text = join('', applyPreprocessor($in, $defines, $preprocessor));
  60     }
  61
  62     # Remove comments in a simple-minded way that will work fine for our files.
  63     # Could do this a fancier way if we were worried about arbitrary CSS source.
  64     $text =~ s|/\*.*?\*/||gs;
  65
  66     # Crunch whitespace just to make it a little smaller.
  67     # Could do work to avoid doing this inside quote marks but our files don't have runs of spaces in quotes.
  68     # Could crunch further based on places where whitespace is optional.
  69     $text =~ s|\s+| |gs;
  70     $text =~ s|^ ||;
  71     $text =~ s| $||;
  72
  73     # Write out a C array of the characters.
  74     my $length = length $text;
  75     print HEADER "extern const char ${name}UserAgentStyleSheet[${length}];\n";
  76     print OUT "extern const char ${name}UserAgentStyleSheet[${length}] = {\n";
  77     my $i = 0;
  78     while ($i < $length) {
  79         print OUT "    ";
  80         my $j = 0;
  81         while ($j < 16 && $i < $length) {
  82             print OUT ", " unless $j == 0;
  83             print OUT ord substr $text, $i, 1;
  84             ++$i;
  85             ++$j;
  86         }
  87         print OUT "," unless $i == $length;
  88         print OUT "\n";
  89     }
  90     print OUT "};\n";
  91
  92 }
  93
  94 print HEADER "}\n";
  95 print OUT "}\n";